Posicionando ícones da área de trabalho à esquerda em vez de à direita

Qualquer maneira de criar alias ou ícones automaticamente para aparecer no lado esquerdo do Apple Desktop. Por padrão, eles vão para a direita.

Não há como forçar os ícones a irem automaticamente para a esquerda (e permanecer organizados pelo critério que você escolher).

Como solução alternativa, você pode alterar as Opções de exibição no Finder para não organizar itens por nenhum critério e colocar ícones manualmente à esquerda.

• Clique em um espaço vazio na área de trabalho.
• Pressione Cmd+ Jou use o mouse para ir para o menu Finder View> Show View Options .
• No menu suspenso Classificar por :, escolha Nenhum ou Ajustar à grade .
• Você poderá soltar arquivos em qualquer lugar da área de trabalho e eles permanecerão lá.

Consulte Noções básicas sobre Mac: modifique suas janelas para obter mais informações.

Acesse também as páginas Básicas do Mac para saber mais sobre o uso de um Mac.

Esta não é a melhor solução, mas pode funcionar se nada mais funcionar ...

1. Crie uma ação de pasta do Automator associada à área de trabalho.
2. Adicione o item: "run AppleScript"

3. Cole o seguinte código na caixa de texto AppleScript:

   -- https://gist.github.com/mrienstra/8330528
   -- Based on http://www.tuaw.com/2012/12/24/applescript-desktop-icon-race/
   -- Inspired by http://namesakecomic.com/comic/happy-new-year-from-namesake/#comment-1182035013
   
   -- Rearranges Desktop icons to flow from left to right, top to bottom.
   
   -- To have this run automatically every time files are added or removed from the Desktop, set this script to run as a Desktop "Folder Action". (See https://developer.apple.com/library/mac/documentation/applescript/conceptual/applescriptlangguide/reference/ASLR_folder_actions.html )
   
   -- This is currently a rough proof-of-concept. It has only been tested with OS X 10.8.5 (Mountain Lion).
   
   -- Current known limitations: Does not work with "Label position" set to "Right" (specifically, icons will overlap).
   
   
   
   -- Adjust these for different spacing
   property theSpacingFactor : 1.0
   property theGutterXFactor : 0.57
   property theGutterYFactor : 0.57
   
   
   
   on rearrangeDesktopIcons()
       tell application "Finder"
           tell icon view options of window of desktop
               set theArrangement to arrangement
               set theArrangementString to theArrangement as string
               if {"not arranged", "«constant ****narr»", "snap to grid", "«constant ****grda»"} does not contain theArrangementString then
                   display alert "\"Rearrange Desktop Icons\" AppleScript says:" message "Cannot rearrange Desktop items, please change Desktop \"Sort by\" to \"None\" or \"Snap to Grid\"." giving up after 10
                   return
               end if
               set theIconSize to icon size
               set theLabelSize to text size
           end tell
   
           set theDesktopBounds to bounds of window of desktop
           set theDesktopWidth to item 3 of theDesktopBounds
           set theDesktopHeight to item 4 of theDesktopBounds
   
           -- Retrieve a list of items on the desktop
           set theDesktopItems to every item of desktop
           set theContestantOffset to theIconSize / 2
   
           set theSpacing to (theIconSize + theLabelSize + theContestantOffset) * theSpacingFactor
           set theGuttersX to theSpacing * theGutterXFactor
           set theGuttersY to theSpacing * theGutterYFactor
           set theMaxColumns to ((theDesktopWidth - theGuttersX * 2) / theSpacing) as integer
           set theMaxRows to ((theDesktopHeight - theGuttersY * 2) / theSpacing) as integer
           set theMaxLocations to theMaxRows * theMaxColumns
   
           set y to 1
           repeat with a from 1 to length of theDesktopItems
               set x to a mod theMaxColumns
               if x is 0 then
                   set x to theMaxColumns
               end if
   
               if a is greater than theMaxLocations then
                   set desktop position of item a of theDesktopItems to {theGuttersX, theGuttersY}
               else
                   set desktop position of item a of theDesktopItems to {theGuttersX + (x - 1) * theSpacing, theGuttersY + (y - 1) * theSpacing}
               end if
   
               if a mod theMaxColumns is 0 then
                   set y to y + 1
               end if
           end repeat
       end tell
   end rearrangeDesktopIcons
   
   
   
   on adding folder items to alias after receiving listOfAlias
       rearrangeDesktopIcons()
   end adding folder items to
   
   on removing folder items from alias after losing listOfAliasOrText
       rearrangeDesktopIcons()
   end removing folder items from
   
   rearrangeDesktopIcons()
   

Portanto, sempre que um arquivo for adicionado à sua área de trabalho, todos os arquivos serão reorganizados em ordem alfabética ...

Organize todas as pastas na ordem que você deseja. Em Exibir, clique em 'limpar'. Isso alinhará tudo bem. Em seguida, você pode simplesmente destacar todas as pastas e posicioná-las exatamente onde deseja. Os Macs não organizam pastas à esquerda, apenas à direita, mas com algumas etapas fáceis, você pode organizar tudo à esquerda.

Acabei de destacar todas as pastas do lado direito, depois as agarrei e colei à esquerda.