Eu principalmente uso esta função:
cf() {
cd "$(osascript -e 'tell app "Finder" to POSIX path of (insertion location as alias)')"
}
Você também pode atribuir um atalho a um script como os abaixo.
Reutilize uma guia existente ou crie uma nova janela (Terminal):
tell application "Finder" to set p to POSIX path of (insertion location as alias)
tell application "Terminal"
if (exists window 1) and not busy of window 1 then
do script "cd " & quoted form of p in window 1
else
do script "cd " & quoted form of p
end if
activate
end tell
Reutilize uma guia existente ou crie uma nova guia (Terminal):
tell application "Finder" to set p to POSIX path of (insertion location as alias)
tell application "Terminal"
if not (exists window 1) then reopen
activate
if busy of window 1 then
tell application "System Events" to keystroke "t" using command down
end if
do script "cd " & quoted form of p in window 1
end tell
Sempre crie uma nova guia (iTerm 2):
tell application "Finder" to set p to POSIX path of (insertion location as alias)
tell application "iTerm"
if exists current terminal then
current terminal
else
make new terminal
end if
tell (launch session "Default") of result to write text "cd " & quoted form of p
activate
end tell
Os dois primeiros scripts têm algumas vantagens em comparação com os serviços adicionados na versão 10.7:
- A partir da versão 10.9, existe um erro no qual os serviços que recebem pastas como entrada nunca são listados no menu de serviços na visualização de colunas. Se você atribuir um atalho de teclado ao serviço Nova Guia Terminal na Pasta, ele não funcionará na exibição de coluna.
- Eles usam a pasta na barra de título em vez de exigir que você selecione uma pasta primeiro.
- Eles reutilizam a guia mais à frente, se não estiver ocupada, por exemplo, executando um comando, exibindo uma página de manual ou executando o emacs.
Se você usa 10.7 ou 10.8, altere tell application "Finder" to set p to POSIX path of (insertion location as alias)para:
tell application "Finder"
if exists Finder window 1 then
set p to POSIX path of (target of Finder window 1 as alias)
else
set p to POSIX path of (path to desktop)
end if
end tell
Há um erro nas versões 10.7 e 10.8 (mas não nas 10.9 ou 10.6) em que o Finder ignora as janelas criadas após a última vez que o foco foi movido para outro aplicativo e retornado ao obter a insertion locationpropriedade.
