Ao abrir um arquivo DMG, como faço para abrir na frente das janelas?

Sempre que eu baixa um .dmgarquivo e o abro (geralmente na barra de download do Chrome), ele é aberto em segundo plano. Existe alguma maneira de fazê-lo abrir na frente da minha janela?

Editar

Para esclarecer: eu quero que a janela do DMG apareça como a janela ativa.

Criei um script de ação de pasta no Applescript, que pode fazer exatamente o que você deseja. Copie e cole-o em um novo Applescript e salve-o como um Aplicativo (sem um diálogo inicial!) Em "/ Library / Scripts / Folder Action Scripts /". Você pode anexá-lo a qualquer pasta (provavelmente sua pasta ~ / Downloads /) clicando com o botão direito do mouse na pasta e selecionando "configurar ações da pasta" no menu suspenso de serviços. Ative as ações da pasta e deixe o script assistir a pasta.

O que o script basicamente faz é reagir aos itens descartados na pasta à qual está anexado e, se o item descartado for do tipo: "Imagem", ele anexa a Imagem como um volume através da ferramenta de linha de comando "hdiutil".

Você pode configurar seu comportamento definindo as propriedades openWindow e makeFrontmost no script; isso também pode ser feito clicando duas vezes no script depois de salvá-lo como um aplicativo - ele perguntará em dois diálogos qual deve ser o comportamento padrão.

Eu espero que isso ajude,

Asmus

 property openWindow : true
 property makeFrontmost : true

 on run

    display dialog "Do you want to bring the Finder to the front after new items are added?" buttons {"Don't Activate", "Activate"} default button 2
    if the button returned of the result is "Don't Activate" then
        set makeFrontmost to false
    else
        set makeFrontmost to true
    end if


    display dialog "Open Folder after adding new files?" buttons {"Don't Open", "Open"} default button 2
    if the button returned of the result is "Don't Open" then
        set openWindow to false
    else
        set openWindow to true
    end if


 end run

 on adding folder items to thisFolder after receiving addedItems

    repeat with i from 1 to number of items in addedItems
        set itemKind to the kind of (info for item i of addedItems) as string

        if itemKind is "Disk Image" then
            set itemPath to (quoted form of POSIX path of item i of addedItems)
            try
                showImage(itemPath)
            end try
        end if

    end repeat

 end adding folder items to


 on showImage(itemPath)

    set volumeMountpointInfo to do shell script "/usr/bin/hdiutil  attach " & itemPath & " | grep Volumes"


    if (openWindow is true) then
        if (makeFrontmost is true) then
            tell application "Finder" to activate
        end if

       set currentDelim to text item delimiters
       set text item delimiters to tab

       set volumeMountpoint to POSIX file (text item 3 of volumeMountpointInfo)

       set text item delimiters to currentDelim

       tell application "Finder" to open folder volumeMountpoint

    end if

 end showImage

====

segundo Applescript para determinar o tipo de arquivo colocado em uma pasta

On adding folder items to thisFolder after receiving addedItems
repeat with i from 1 to number of items in addedItems
    set itemKind to the kind of (info for item i of addedItems) as string
    display dialog itemKind
end repeat
end adding folder items to

Editado precisa ser "Imagem de disco" em vez de "Imagem"

Pelo que sei, o OS X somente exibirá automaticamente o conteúdo de uma imagem de disco se for somente leitura. Isso é indicado por um lápis com uma barra na parte inferior esquerda da janela do Finder ao visualizar o conteúdo da imagem.

Se você deseja alterar uma imagem de disco para fazer isso, é possível tornar uma imagem de disco existente somente leitura usando o Utilitário de Disco. Infelizmente, isso não altera o comportamento das imagens produzidas incorretamente que você pode baixar da Internet.

1. Monte a imagem do disco que você deseja abrir automaticamente.
2. Abra o Utilitário de Disco pesquisando-o com o Spotlight.
3. Selecione o ícone "Nova imagem" na barra de ferramentas.
4. Nomeie o arquivo e selecione "somente leitura" em "Formato da imagem".
5. Clique em "Salvar". Quando você monta essa nova imagem, ela abre automaticamente uma janela do Finder.

Provavelmente, isso também não responde suficientemente à pergunta, mas ...

Se você pressionar o comando e clicar no item na barra de download, ele mostrará o item no localizador. Nesse ponto, basta pressionar o comando-O (ou clicar duas vezes no arquivo dmg) para montá-lo e abri-lo em uma nova janela em primeiro plano.