código de máquina x86-64, 44 bytes
(O mesmo código de máquina também funciona no modo de 32 bits.)
A resposta de @Daniel Schepler foi um ponto de partida para isso, mas isso tem pelo menos uma nova ideia algorítmica (não apenas um melhor aproveitamento da mesma idéia): Os códigos ASCII para 'B'( 1000010) e 'X'( 1011000) fornecem 16 e 2 após mascarar0b0010010 .
Então, após excluir decimal (dígito inicial diferente de zero) e octal (char após '0'é menor que 'B'), podemos apenas definir base = c & 0b0010010e pular para o loop de dígitos.
Chamadas com x86-64 System V como unsigned __int128 parse_cxx14_int(int dummy, const char*rsi); Extrai o valor de retorno EDX da metade alta do unsigned __int128resultado com tmp>>64.
.globl parse_cxx14_int
## Input: pointer to 0-terminated string in RSI
## output: integer in EDX
## clobbers: RAX, RCX (base), RSI (points to terminator on return)
parse_cxx14_int:
xor %eax,%eax # initialize high bits of digit reader
cdq # also initialize result accumulator edx to 0
lea 10(%rax), %ecx # base 10 default
lodsb # fetch first character
cmp $'0', %al
jne .Lentry2
# leading zero. Legal 2nd characters are b/B (base 2), x/X (base 16)
# Or NUL terminator = 0 in base 10
# or any digit or ' separator (octal). These have ASCII codes below the alphabetic ranges
lodsb
mov $8, %cl # after '0' have either digit, apostrophe, or terminator,
cmp $'B', %al # or 'b'/'B' or 'x'/'X' (set a new base)
jb .Lentry2 # enter the parse loop with base=8 and an already-loaded character
# else hex or binary. The bit patterns for those letters are very convenient
and $0b0010010, %al # b/B -> 2, x/X -> 16
xchg %eax, %ecx
jmp .Lentry
.Lprocessdigit:
sub $'0' & (~32), %al
jb .Lentry # chars below '0' are treated as a separator, including '
cmp $10, %al
jb .Lnum
add $('0'&~32) - 'A' + 10, %al # digit value = c-'A' + 10. we have al = c - '0'&~32.
# c = al + '0'&~32. val = m+'0'&~32 - 'A' + 10
.Lnum:
imul %ecx, %edx
add %eax, %edx # accum = accum * base + newdigit
.Lentry:
lodsb # fetch next character
.Lentry2:
and $~32, %al # uppercase letters (and as side effect,
# digits are translated to N+16)
jnz .Lprocessdigit # space also counts as a terminator
.Lend:
ret
Os blocos alterados em relação à versão de Daniel são (principalmente) recuados menos do que outras instruções. Além disso, o loop principal tem sua ramificação condicional na parte inferior. Isso acabou sendo uma mudança neutra, porque nenhum dos caminhos poderia cair no topo, e odec ecx / loop .Lentry ideia de entrar no circuito acabou não sendo uma vitória depois de lidar com o octal de maneira diferente. Mas ele tem menos instruções dentro do loop com o loop na forma idiomática do {} while estrutura, então eu o mantive.
O equipamento de teste C ++ de Daniel funciona inalterado no modo de 64 bits com esse código, que usa a mesma convenção de chamada que sua resposta de 32 bits.
g++ -Og parse-cxx14.cpp parse-cxx14.s &&
./a.out < tests | diff -u -w - tests.good
Desmontagem, incluindo os bytes do código da máquina que são a resposta real
0000000000000000 <parse_cxx14_int>:
0: 31 c0 xor %eax,%eax
2: 99 cltd
3: 8d 48 0a lea 0xa(%rax),%ecx
6: ac lods %ds:(%rsi),%al
7: 3c 30 cmp $0x30,%al
9: 75 1c jne 27 <parse_cxx14_int+0x27>
b: ac lods %ds:(%rsi),%al
c: b1 08 mov $0x8,%cl
e: 3c 42 cmp $0x42,%al
10: 72 15 jb 27 <parse_cxx14_int+0x27>
12: 24 12 and $0x12,%al
14: 91 xchg %eax,%ecx
15: eb 0f jmp 26 <parse_cxx14_int+0x26>
17: 2c 10 sub $0x10,%al
19: 72 0b jb 26 <parse_cxx14_int+0x26>
1b: 3c 0a cmp $0xa,%al
1d: 72 02 jb 21 <parse_cxx14_int+0x21>
1f: 04 d9 add $0xd9,%al
21: 0f af d1 imul %ecx,%edx
24: 01 c2 add %eax,%edx
26: ac lods %ds:(%rsi),%al
27: 24 df and $0xdf,%al
29: 75 ec jne 17 <parse_cxx14_int+0x17>
2b: c3 retq
Outras alterações da versão de Daniel incluem salvar o sub $16, %alde dentro do loop de dígitos, usando maissub invés detest como parte da detecção de separadores e dígitos vs. caracteres alfabéticos.
Diferentemente de Daniel, todos os personagens abaixo '0'são tratados como separadores, não apenas '\''. (Exceto ' ': and $~32, %al/jnz em ambos os nossos loops trata o espaço como um terminador, o que é possivelmente conveniente para testar com um número inteiro no início de uma linha.)
Toda operação que modifica %aldentro do loop tem uma ramificação consumindo sinalizadores definidos pelo resultado e cada ramificação vai (ou cai) para um local diferente.
