função para receber uma entrada de caracteres e formato de data de retorno (com entrada incorreta)

Preciso escrever uma função para receber um caractere de string e retornar o formato da data. Por exemplo, a entrada é 20120101 e eu preciso deste 01-01-2012. O problema é que pode haver algumas entradas incorretas como esta "2012ABCD". Nesse caso, desejo que a função retorne uma data fixa, como 01-01 2020. O que eu escrevi até agora é:

Create Function ReturnDate
(@date varchar(8))

Returns date

  as

    begin
       declare @result date

          set @result = (select convert(date , @date,111))
                if(@@ROWCOUNT>0) return @result
                 else return '2020-01-01'
       return @result
    end

Isso não funciona e eu simplesmente não sei como lidar com a segunda parte (quando a entrada está incorreta).

No SQL Server 2012 e posterior, você pode usar TRY_CONVERT para verificar se a entrada pode ser convertida. Se não puder, um valor NULL será retornado; portanto, você poderá executar um COALESCE para obter o valor convertido ou a data fixa.

begin
   declare @result date
   set @result = COALESCE(TRY_CONVERT(date, @date, 111), '2012-01-01')
   return @result
end

Você também pode usar um TRY CATCHbloco e retornar a data fixa no CATCHbloco, mas é uma prática recomendada usar TRY_CONVERT para que o SQL Server não precise manipular um erro, pois isso requer mais tempo e recursos.

Uma função para esse tipo de código acarretará mais sobrecarga do que simplesmente usar a mesma lógica na consulta; portanto, se ela for chamada muitas vezes a cada segundo, você poderá consumir recursos significativos usando uma função para ela. Eu entendo que isso pode ser chamado a partir de vários trechos de código, portanto, há um desejo de torná-lo uma função, caso a data padrão precise ser alterada - então não há alterações no código compilado e atualize essa função.

Se esse código for executado muito, considere outras opções que fornecerão melhor desempenho do que uma função definida pelo usuário. Consulte a resposta de Salomão para obter uma visão geral de suas opções e mais explicações sobre por que você pode escolher uma sobre a outra.

Por exemplo, o seguinte mostra a mesma lógica implementada como uma função com valor de tabela embutida, que precisa ser usada CROSS APPLYse não for fornecida com um valor estático, mas que tem um desempenho muito melhor que uma UDF escalar:

USE [tempdb];

GO
CREATE
OR ALTER -- comment out if using pre-SQL Server 2016 SP1
FUNCTION dbo.ReturnDate (@Date VARCHAR(8))
RETURNS TABLE
AS RETURN
  SELECT ISNULL(TRY_CONVERT(DATE, @Date, 111), '2020-01-01') AS [TheDate];
GO


SELECT *
FROM   (VALUES (1, '20120101'), (2, '2012ABCD')) tab(ID, Input)
CROSS APPLY dbo.ReturnDate(tab.[Input]) dt
/*
ID    Input       TheDate
1     20120101    2012-01-01
2     2012ABCD    2020-01-01
*/