Emacs consultoria limitada

Gostaria de substituir temporariamente uma função em um pedaço de código.

Tome, por exemplo, o seguinte:

(defun nadvice/load-quiet (args)
  (cl-destructuring-bind
      (file &optional noerror nomessage nosuffix must-suffix)
      args
    (list file noerror t nosuffix must-suffix)))

(defun nadvice/idle-require-quiet (old-fun &rest args)
    (advice-add 'load :filter-args #'nadvice/load-quiet)
    (apply old-fun args)
    (advice-remove #'load #'nadvice/load-quiet))

(advice-add 'idle-require-load-next :around #'nadvice/idle-require-quiet)

O que não funciona:

• Este. Seria muito mais limpo se eu pudesse evitar ativar e desativar manualmente os conselhos e confiar na natureza de thread único do Emacs para cuidar das coisas.
• cl-letfnão me permitirá fazer referência à função original, então não posso implementar coisas que :filter-argsnormalmente fariam.
• cl-flet não pode substituir funções em outras funções.
• nofleté um pacote externo que eu gostaria de evitar. (Também faz muito mais do que eu preciso)

Você não poderia usar (cl-)letfenquanto fazia referência à função original?

Algo assim:

;; Original function
(defun my-fun (arg)
  (message "my-fun (%s)" arg))


;; Standard call
(my-fun "arg") ;; => my-fun (arg)


;; Temporary overriding (more or less like an around advice)
(let ((orig-fun (symbol-function 'my-fun)))
  (letf (((symbol-function 'my-fun)
          (lambda (arg)
            ;; filter arguments
            (funcall orig-fun (concat "modified-" arg)))))
    (my-fun "arg")))
;; => my-fun (modified-arg)


;; The overriding was only temporary
(my-fun "arg") ;; => my-fun (arg)

Você também pode agrupar isso em uma macro se planejar reutilizá-lo:

(defmacro with-advice (args &rest body)
  (declare (indent 1))
  (let ((fun-name (car args))
        (advice   (cadr args))
        (orig-sym (make-symbol "orig")))
    `(cl-letf* ((,orig-sym  (symbol-function ',fun-name))
                ((symbol-function ',fun-name)
                 (lambda (&rest args)
                   (apply ,advice ,orig-sym args))))
       ,@body)))

O exemplo acima pode ser reescrito da seguinte maneira:

(defun my-fun (arg)
  (message "my-fun (%s)" arg))


(my-fun "my-arg")

(with-advice (my-fun
              (lambda (orig-fun arg)
                (funcall orig-fun (concat "modified-" arg))))
  (my-fun "my-arg"))

(my-fun "my-arg")