Como posso escapar do * no modo organizacional para evitar fonte em negrito

Se eu escrever algo como *shrug*no modo organizacional, ele será automaticamente tipificado como texto em negrito . Como posso evitar isso, ou seja, na verdade, *shrug*aparecer literalmente quando exportado?

Editar:

Ainda quero usar a fonte em negrito (sem precisar alterar a sintaxe em estrela padrão do texto em negrito) e não deve importar para o formato de arquivo que meu arquivo organizacional é exportado, por exemplo, deve funcionar tanto para o Markdown quanto para o HTML exportação.

Isso é algo importante , é por isso que está escrito em negrito. Mas, para outra coisa, não tenho a idéia * encolher os ombros *.

Esta resposta é inspirada após sugestões coletivas na lista GNU do emacs-org-mode para usar os caracteres de espaço de larguraorg-entity ( C-h i g (org) Special symbols) em \ast{}vez de largura zero (o que eu sugeri na minha outra resposta aqui ).

Abaixo está uma solução genérica em que o usuário não precisa se lembrar das entidades orgânicas para vários símbolos. Ele insere a entidade organizacional (se disponível) quando o usuário o faz C-u SYMBOL; trabalha para C-u *, C-u /, C-u =, etc.

(defun modi/org-entity-get-name (char)
  "Return the entity name for CHAR. For example, return \"ast\" for *."
  (let ((ll (append org-entities-user
                    org-entities))
        e name utf8)
    (catch 'break
      (while ll
        (setq e (pop ll))
        (when (not (stringp e))
          (setq utf8 (nth 6 e))
          (when (string= char utf8)
            (setq name (car e))
            (throw 'break name)))))))

(defun modi/org-insert-org-entity-maybe (&rest args)
  "When the universal prefix C-u is used before entering any character,
    insert the character's `org-entity' name if available.

    If C-u prefix is not used and if `org-entity' name is not available, the
    returned value `entity-name' will be nil."
  ;; It would be fine to use just (this-command-keys) instead of
  ;; (substring (this-command-keys) -1) below in emacs 25+.
  ;; But if the user pressed "C-u *", then
  ;;  - in emacs 24.5, (this-command-keys) would return "^U*", and
  ;;  - in emacs 25.x, (this-command-keys) would return "*".
  ;; But in both versions, (substring (this-command-keys) -1) will return
  ;; "*", which is what we want.
  ;; http://thread.gmane.org/gmane.emacs.orgmode/106974/focus=106996
  (let ((pressed-key (substring (this-command-keys) -1))
        entity-name)
    (when (and (listp args) (eq 4 (car args)))
      (setq entity-name (modi/org-entity-get-name pressed-key))
      (when entity-name
        (setq entity-name (concat "\\" entity-name "{}"))
        (insert entity-name)
        (message (concat "Inserted `org-entity' "
                         (propertize entity-name
                                     'face 'font-lock-function-name-face)
                         " for the symbol "
                         (propertize pressed-key
                                     'face 'font-lock-function-name-face)
                         "."))))
    entity-name))

;; Run `org-self-insert-command' only if `modi/org-insert-org-entity-maybe'
;; returns nil.
(advice-add 'org-self-insert-command :before-until #'modi/org-insert-org-entity-maybe)

Portanto, quando o usuário digita C-u *, \ast{}é inserido e a mensagem abaixo é exibida na área de eco,

'Org-entity' \ ast {} inserida para o símbolo *.

Se org-pretty-entitiesestiver definido como tacima, o inserido \ast{}será exibido como *.

Se org-entitynão existe um caractere X e se o usuário faz C-u X , X é simplesmente inserido 4 vezes (como C-unormalmente faria).

Usando o caractere unicode ZERO WIDTH SPACE

Você pode falhar na análise de ênfase em negrito adicionando um caractere de espaço de largura zero (indicado por [ZWS] nos trechos abaixo) antes do primeiro asterisco ou após o segundo asterisco.

Ambos os trechos abaixo exportados para HTML nos meus testes:

• [ZWS] antes do primeiro asterisco

  This is some *bold* test and this is ​[ZWS]*not bold*.
  

• [ZWS] após o segundo asterisco

  This is some *bold* test and this is *not bold*​[ZWS].
  

Você pode inserir o ZERO WIDTH SPACE (nome do unicode) fazendo C-x 8 RET 200b RET.
Eu uso isso com muita frequência, por isso vinculei issoC-x 8 0 .

Atualizar

De acordo com a discussão na lista de correio do emacs-org-mode , não é recomendável usar caracteres não ASCII para escapar; em vez disso, org-entitiesdeve ser usado, se aplicável. Eu também concordei com isso e criei outra solução que facilita a inserção org-entities( C-u *neste caso).

Por literalmente, se você realmente quiser usar alguma marcação no LaTeX exportado, poderá usar =*shrug*=. No entanto, se você apenas deseja que ele seja exportado como *shrug*e deseja fazer isso o tempo todo, eu recomendaria filtros . Se, no entanto, você só precisar disso para algumas instâncias de *shrug*, deverá usar a alternativa sugerida por @wvxvw. Você pode fazer isso corretamente usando macros . Alguns exemplos a seguir.

Filtros

(defun my-bold (contents backend info)
  (when (org-export-derived-backend-p backend 'latex)
    (replace-regexp-in-string "\\`\\\\textbf{\\(.+\\)}"
                              "\\\\ast{}\\1\\\\ast{}" contents)))

(add-to-list 'org-export-filter-bold-functions 'my-bold)

Essencialmente, o filtro acima procura a \textbf{..}marcação na string transcodificada e a substitui por \ast{}..\ast{}, sem alterar o que foi colocado dentro {..}. Eu não testei a expressão regular e a sequência de substituição, portanto, pode haver erros, mas você entendeu. Da mesma forma, para cobrir outros back-ends, é possível incluir trechos extras como este:

(when (org-export-derived-backend-p backend 'html)
   (replace-regexp-in-string "<b>\\(.+\\)</b>" "\&#2a;\\1\&#2a;" contents))

A mesma ressalva vale para a expressão regular acima.

Macros

Origem da organização:

#+macro: nobold @@latex:\ast{}$1\ast{}@@ @@html:&#2a;$1&#2a;@@

This text is *bold* this is nobold{{{not}}}

exporta para o LaTeX como:

This text is \textbf{bold} this is \ast{}not\ast{}

e para HTML como:

This text is <b>bold</b> this is  &#2a;not&#2a;

Obviamente, você pode adicionar quantos backend quiser à macro.

Editar: como Kaushal aponta nos comentários, o snippet de exportação para o látex é opcional neste caso. No entanto, prefiro usá-los sempre que houver látex nu, pois acho bastante difícil acompanhar a lista org-entitiese as regras específicas por trás da identificação do látex na origem da organização.

Nota:

• os exemplos de filtro não foram testados,
• Eu não conheço nenhum HTML, então pode haver alguns erros nos respectivos bits.

Isso é controlado pela variável org-ênfase-alist e pode ser facilmente modificado.

• Coloque o ponto em negrito, use o comando what-cursor-position C-u C-x =para encontrar a face, observe que ela possui propriedade org-emphasis.
• Ligue customize-groupe procure por ênfase organizacional
• O org-enfat-alist deve aparecer, com várias opções para marcar o texto.
• Exclua a entrada correspondente a *
• Aplique alterações e reinicie o modo organizacional ou emacs