Como altero partes de um tema personalizado?

21

Estou usando um dos temas personalizados predefinidos que acompanham o Spacemacs (zenburn).

Como posso modificar partes específicas do tema, por exemplo, basta alterar a cor da fonte usada nos comentários?

themes spacemacs

2

Tem certeza de que quer dizer tema de cores e não tema personalizado ? Se você não estiver usando terceiros color-theme.el, provavelmente quer dizer um tema personalizado. Nesse caso, edite sua pergunta de acordo. Consulte Cor e temas personalizados .

— Drew

13

Eu prefiro usar custom-theme-set-facespara redefinir como o tema exibe um rosto específico, por exemplo,

(custom-theme-set-faces
 'zenburn
 '(font-lock-comment-face ((t (:foreground "#DFAF8F"))))
 '(font-lock-comment-delimiter-face ((t (:foreground "#DFAF8F")))))

Para o caso específico de zenburn, o próprio tema define várias cores e uma macro na qual elas são vinculadas a nomes de variáveis, para que você possa escrever o seguinte como:

(zenburn-with-color-variables
  (custom-theme-set-faces
   'zenburn
   `(font-lock-comment-face ((t (:foreground ,zenburn-orange))))
   `(font-lock-comment-delimiter-face ((t (:foreground ,zenburn-orange))))))

— Aaron Harris
fonte

onde você deve escrever esse pedaço de código? em .spacemacs?

— ChiseledAbs

1

Não faço ideia, desculpe; Eu não uso Spacemacs. Em princípio, porém, tudo o que você precisa fazer é fazer com que o código seja avaliado algum tempo após o zenburncarregamento do tema.

— Aaron Harris

8

No spacemacs, instale a camada theming, consulte https://github.com/syl20bnr/spacemacs/tree/master/layers/%2Bthemes/theming

Por exemplo, eu tenho o seguinte cortou na dotspacemacs/user-initminha .spacemacspara ajustar a cor da gruvbox ea luz solarizados tema de fundo e linenumber:

  (setq theming-modifications '(
    ;; requires the theming layer
    (gruvbox
       (default :background "#1D2021" :foreground "#fdf4c1")
       (linum :background "#000000" :foreground "#878787")
       (fringe  :background "#000000")
       (linum-relative-current-face :inherit (shadow default) :background "#3C3836" :foreground "#ff0000")
       (font-lock-comment-face :slant italic)
    )
    (solarized-light
     (linum :background "#DBCDA7" :foreground "#40371F")
       (fringe :background "#DBCDA7")
       (font-lock-comment-face :slant italic)
       )
))

— Thorsten
fonte

4

Adicionei conselhos à função load-theme para substituir certas faces - dessa forma, você pode continuar usando o load-theme normalmente para selecionar um tema e aplicará as substituições automaticamente.

(defadvice load-theme (after theme-set-overrides activate)
  "Set override faces for different custom themes."
  (dolist (theme-settings theme-overrides)
    (let ((theme (car theme-settings))
          (faces (cadr theme-settings)))
      (if (member theme custom-enabled-themes)
          (dolist (face faces)
            (custom-theme-set-faces theme face))))))

(defcustom theme-overrides nil
  "Association list of override faces to set for different custom themes.")

(defun alist-set (alist-symbol key value)
  "Set VALUE of a KEY in ALIST-SYMBOL."
  (set alist-symbol
        (cons (list key value) (assq-delete-all key (eval alist-symbol)))))

; override some settings of the ample-flat theme
(alist-set 'theme-overrides 'ample-flat '(
                                          (default ((t (:background "gray12" :foreground "#bdbdb3"))))
                                          (mode-line ((t (:background "cornsilk4" :foreground "#222" :inherit 'variable-pitch))))
                                          (outline-2 ((t (:inherit font-lock-keyword-face)))) ; blueish
                                          (outline-3 ((t (:inherit font-lock-comment-face)))) ; brownish
                                          (outline-4 ((t (:inherit font-lock-string-face)))) ; orangeish
                                          (org-table ((t (:inherit fixed-pitch :height 0.7 :foreground "#887"))))
                                          (org-formula ((t (:inherit org-table :foreground nil))))
                                          ))

Funciona, e seria bom ter como parte da interface, mas provavelmente é mais simples criar uma função para cada tema que você usa e chamar um conjunto de temas personalizados após carregá-lo -

(defun ample-flat ()
  (interactive)
  (mapc #'disable-theme custom-enabled-themes) ; clear any existing themes
  (load-theme 'ample-flat t)
  (custom-theme-set-faces 'ample-flat 
                          '(default ((t (:background "gray12" :foreground "#bdbdb3"))))
                          '(mode-line ((t (:background "cornsilk4" :foreground "#222" :inherit 'variable-pitch))))
                          '(outline-2 ((t (:inherit font-lock-keyword-face)))) ; blueish
                          '(outline-3 ((t (:inherit font-lock-comment-face)))) ; brownish
                          '(outline-4 ((t (:inherit font-lock-string-face)))) ; orangeish
                          '(org-table ((t (:inherit fixed-pitch :height 0.7 :foreground "#887"))))
                          '(org-formula ((t (:inherit org-table :foreground nil))))
                          ))

(ample-flat)

— Brian Burns
fonte

0

Exemplo do que fiz para editar spacemacs-dark, removendo alguns negritos que não gosto:

  ;; on dotspacemacs/user-config:

  ;; configure spacemacs-dark theme, specifically removing bolds
  (let
      ((func "#d75fd7")
       (keyword "#4f97d7")
       (type "#ce537a"))

    (custom-theme-set-faces
     'spacemacs-dark
     `(font-lock-function-name-face ((t (:foreground ,func :inherit normal))))
     `(font-lock-keyword-face ((t (:foreground ,keyword :inherit normal))))
     `(font-lock-type-face ((t (:foreground ,type :inherit normal))))
     )
    )

— Yuri Ghensev
fonte

0

Pode ser mais fácil você usar SPC SPC custom-theme-visit-theme, encontrar gruvbox, fazer suas edições lá e apenas colocar (load-file "~/.emacs.d/gruvbox-theme.el")em sua dotspacemacs/user-configfunção.

— donnaworriaboutit
fonte