Inserção automática dos últimos valores sub / sobrescritos usados ​​nas fórmulas matemáticas

Eu uso o AUCTeX para textos matemáticos de definição de tipo. Frequentemente, tenho que digitar equações com somas, integrais etc., todas com os mesmos sub ou sobrescritos. Gostaria de preencher automaticamente o atual sub / sobrescrito com o valor que ele possuía antes. Exemplo:

\sum_{i=1}^{\infty} a_i = \sum…

Quando pressiono _na equação acima, o Emacs deve escrever _{i=1}. Opcional, seria bom se o segundo sobrescrito também fosse preenchido.

Como isso pode ser realizado?

Adicione ao seu arquivo init:

(defvar mg-TeX-insert-subscript-history nil)
(defvar mg-TeX-insert-superscript-history nil)

(defun TeX-insert-sub-or-superscript (arg)
  "Insert typed key ARG times and possibly a pair of braces.
Brace insertion is only done if point is in a math construct and
`TeX-electric-sub-and-superscript' has a non-nil value."
  (interactive "*p")
  (self-insert-command arg)
  (when (and TeX-electric-sub-and-superscript (texmathp))
    (let* ((history (cond
             ((equal last-input-event ?_)
              'mg-TeX-insert-subscript-history)
             ((equal last-input-event ?^)
              'mg-TeX-insert-superscript-history)))
       (content (read-string "Content: " (car (symbol-value history)) history)))
      (insert (concat TeX-grop content TeX-grcl))
      (if (zerop (length content))
      (backward-char)))))

Verifique se TeX-electric-sub-and-superscriptestá definido como não nulo.

Aqui está uma versão que não interativamente insere o último sub / super script que ocorre para o token no ponto:

(defun my/electric-sub-super-script (arg)
  "Insert typed character ARG times and possibly a sub/super-script.
Sub/super-script insertion is done only in a (La)TeX math mode region.
The inserted sub/super-script is copied from the last occurence of a
sub/superscript for the token at point."
  (interactive "p")
  (self-insert-command arg)
  (when (texmathp)
    (insert
     (save-excursion
       (let ((current-token (let ((end (point)))
                              (backward-sexp 1)
                              (buffer-substring-no-properties (point) end))))
         (if (search-backward current-token nil t)
             (progn
               (search-forward current-token)
               (let ((begin (point)))
                 (forward-sexp 1)
                 (buffer-substring-no-properties begin (point))))
           ""))))))

(define-key TeX-mode-map (kbd "_") #'my/electric-sub-super-script)
(define-key TeX-mode-map (kbd "^") #'my/electric-sub-super-script)

Tomando o exemplo da pergunta, abaixo está a sequência de estados de buffer obtidos iniciando com a primeira linha e digitando _^SPCa_:

\sum_{i=1}^{\infty} a_i = \sum▮
\sum_{i=1}^{\infty} a_i = \sum_{i=1}▮
\sum_{i=1}^{\infty} a_i = \sum_{i=1}^{\infty}▮
\sum_{i=1}^{\infty} a_i = \sum_{i=1}^{\infty} a▮
\sum_{i=1}^{\infty} a_i = \sum_{i=1}^{\infty} a_i▮