Como alinhar à direita região e / ou linha?

Podemos centralizar o texto com M-x center-regione M-o M-s. Existe algo semelhante para o alinhamento correto?

Exemplo antes:

Item 0: value                                                       |
Item 100: value                                                     |
Item 30: value                                                      |

depois de:

                                                       Item 0: value|
                                                     Item 100: value|
                                                      Item 30: value|
                                                       fill-column  ^

Qual é a maneira mais fácil de alinhar o texto à direita?

De acordo com o nó manual no Preenchimento , várias das funções de preenchimento usam um argumento JUSTIFY opcional que você pode usar. Assim, por exemplo, para preencher um parágrafo com justificativa correta, você pode usar (fill-paragraph 'right).

Você também pode usar (justify-current-line 'right)para uma única linha.

Se você planeja usar muito essas opções, poderá envolvê-las em funções, como a seguir, e vincular essas funções às chaves de sua escolha:

(defun right-justify-current-line ()
  "Right-justify this line."
  (interactive)
  (justify-current-line 'right))

(defun right-fill-paragraph ()
  "Fill paragraph with right justification."
  (interactive)
  (fill-paragraph 'right))

Aqui está uma função que você pode incluir como substituto fill-paragraph. Com vários prefixos, permite que você decida que tipo de justificativa usar no parágrafo que você está preenchendo:

(defun fill-paragraph-dwim (&optional arg)
  "Fills the paragraph as normal with no prefix. With C-u,
right-justify.  With C-u C-u, center-justify.  With C-u C-u C-u,
full-justify."
  (interactive "p")
  (fill-paragraph (cond ((= arg 4)  'right)
                        ((= arg 16) 'center)
                        ((= arg 64) 'full))))

Se você não desejar preencher quando estiver alinhando à direita, poderá usar a seguinte função, que é extraída diretamente da center-regionfunção com uma alteração de linha única para fazê-la alinhar corretamente:

(defun right-region (from to)
  "Right-justify each nonblank line starting in the region."
  (interactive "r")
  (if (> from to)
      (let ((tem to))
    (setq to from from tem)))
  (save-excursion
    (save-restriction
      (narrow-to-region from to)
      (goto-char from)
      (while (not (eobp))
    (or (save-excursion (skip-chars-forward " \t") (eolp))
        ;; (center-line))              ; this was the original code
        (justify-current-line 'right)) ; this is the new code
    (forward-line 1)))))