faça `delete-duplicate-lines` ignore linhas em branco e certas palavras

Estou editando um texto no modo organizacional, várias linhas são repetidas, pois parte de arquivos diferentes do mesmo tópico.

Eu quero usar delete-duplicate-linespara excluir as linhas repetidas, no entanto, o comando também remove as linhas em branco, o que é algo que eu não quero (caso contrário, não teria parágrafos!). Eu quero ignorar certas palavras que existem sozinhas nas linhas, por exemplo, "Continuar" , é repetida muitas vezes no texto, mas quero mantê-la, pois é necessária.

text-editing

— shackra
fonte

Ignorando linhas em branco

Você pode dizer delete-duplicate-linespara ignorar as linhas em branco ligando para

C-u C-u C-u M-x delete-duplicate-lines RET

Se você não precisar pressionar C-utantas vezes quando ligar delete-duplicate-lines, poderá agrupá-lo em um comando personalizado e vincular esse comando a uma sequência de teclas de sua escolha:

(defun delete-duplicate-lines-keep-blanks ()
  (interactive)
  (delete-duplicate-lines (region-beginning) (region-end) nil nil t))

(global-set-key (kbd "C-c d") 'delete-duplicate-lines-keep-blanks)

Ignorando linhas correspondentes à regexp

Quanto à segunda parte da sua pergunta, não acho que você pode conseguir o que deseja usando a versão interna do delete-duplicate-lines. No entanto, você pode usar uma versão modificada do comando (que também mantém as linhas em branco por padrão):

(defun delete-duplicate-lines
    (beg end keep &optional reverse adjacent keep-blanks interactive)
  (interactive
   (progn
     (barf-if-buffer-read-only)
     (list (region-beginning) (region-end)
           (read-string "Keep lines matching regexp: ") ; Prompt for regexp to keep
           (equal current-prefix-arg '(4))
           (equal current-prefix-arg '(16))
           t                                            ; Keep blanks by default
           t)))
  (let ((lines (unless adjacent (make-hash-table :test 'equal)))
        line prev-line
        (count 0)
        (beg (copy-marker beg))
        (end (copy-marker end)))
    (save-excursion
      (goto-char (if reverse end beg))
      (if (and reverse (bolp)) (forward-char -1))
      (while (if reverse
             (and (> (point) beg) (not (bobp)))
               (and (< (point) end) (not (eobp))))
        (setq line (buffer-substring-no-properties
                (line-beginning-position) (line-end-position)))
        (if (or (and keep-blanks (string= "" line))
                (string-match keep line))               ; Ignore line if it
                                                        ; matches regexp to keep
            (forward-line 1)
          (if (if adjacent (equal line prev-line) (gethash line lines))
              (progn
                (delete-region (progn (forward-line 0) (point))
                               (progn (forward-line 1) (point)))
                (if reverse (forward-line -1))
                (setq count (1+ count)))
            (if adjacent (setq prev-line line) (puthash line t lines))
            (forward-line (if reverse -1 1))))))
    (set-marker beg nil)
    (set-marker end nil)
    (when interactive
      (message "Deleted %d %sduplicate line%s%s"
               count
               (if adjacent "adjacent " "")
               (if (= count 1) "" "s")
               (if reverse " backward" "")))
    count))

Esta versão delete-duplicate-linessolicitará uma regexp e manterá todas as linhas correspondentes à regexp. Por exemplo, para manter todas as linhas que consistem na palavra que Resumevocê faria:

M-x delete-duplicate-lines RET ^Resume$ RET

— itsjeyd
fonte