Extraia o (s) arquivo (s) para o disco rígido do `modo de arquivo`

Estou procurando um meio de extrair arquivos individuais e marcados de arquivos (por exemplo, * .zip; * .gz, etc.) para o disco rígido (sem abri-los em um buffer) usando archive-mode. Uma modificação sugerida para o modo principal (que permitiria esse novo recurso) será muito apreciada.

http://www.gnu.org/software/emacs/manual/html_node/emacs/File-Archives.html

Aqui está um esboço de uma implementação.

O modo Arquivar armazena mapas dos tipos de arquivamento para comandos usados ​​para extrair dados em variáveis archive-TYPE-extract; podemos encontrar a variável correta usando (archive-name "extract").

Todos os comandos são personalizados para extrair para saída padrão; felizmente, ainda podemos usá-los se redirecionarmos stdoutpara um arquivo de nossa escolha.

(defun archive-extract-to-file (archive-name item-name command dir)
  "Extract ITEM-NAME from ARCHIVE-NAME using COMMAND. Save to
DIR."
  (unwind-protect
      ;; remove the leading / from the file name to force
      ;; expand-file-name to interpret its path as relative to dir
      (let* ((file-name (if (string-match "\\`/" item-name)
                            (substring item-name 1)
                          item-name))
             (output-file (expand-file-name file-name dir))
             (output-dir (file-name-directory output-file)))
        ;; create the output directory (and its parents) if it does
        ;; not exist yet
        (unless (file-directory-p output-dir)
          (make-directory output-dir t))
        ;; execute COMMAND, redirecting output to output-file
        (apply #'call-process
               (car command)            ;program
               nil                      ;infile
               `(:file ,output-file)    ;destination
               nil                      ;display
               (append (cdr command) (list archive-name item-name))))
    ;; FIXME: add unwind forms
    nil))

Eu modifiquei archive-extract-by-filepara conseguir isso.

(defun archive-extract-marked-to-file (output-dir)
  "Extract marked archive items to OUTPUT-DIR."
  (interactive "sOutput directory: ")
  (let ((command (symbol-value (archive-name "extract")))
        (archive (buffer-file-name))
        (items (archive-get-marked ?* t))) ; get marked items; t means
                                           ; get item under point if
                                           ; nothing is marked
    (mapc
     (lambda (item)
       (archive-extract-to-file archive
                                (aref item 0) ; get the name from the descriptor
                                command output-dir))
     items)))

Aqui eu uso mapcpara percorrer todos os arquivos marcados e extraí-los.

Agora só precisamos adicionar uma ligação de chave:

(require 'arc-mode)
(define-key archive-mode-map "F" #'archive-extract-marked-to-file)

Eu testei isso em um .ziparquivo fictício contendo um subdiretório, mas sua milhagem pode variar.

Note-se que archive-modesuportes Arc, Lzh, Zip, Zoo, Rar, e 7z. Ele não apoiar .tgz, .tbz, .tar.gze amigos, que são abertos usando tar-modee uncompress.el.