Editando arquivos com uma frase por linha

Um pouco de fundo.

Estou tentando controlar meus documentos de látex com versão e a eficácia dessa iniciativa melhoraria bastante se eu adotasse uma abordagem de uma frase por linha .

Por exemplo, é a seguinte a aparência dos meus documentos.

Some text here.
New stencence on the same paragraph.
Some more text, still on the same paragraph.

This is another paragraph.

Minha pergunta é simples.
Quanto disso eu posso automatizar / melhorar com o Emacs?

Os dois pontos a seguir são o que tenho em mente.

1. Minhas frases são longas , então eu preciso quebrar as linhas sem preenchê-las. Ou seja, uma frase muito longa precisa ser exibida em várias linhas na minha tela, mas precisa ser uma única linha no arquivo ".tex" . Isso seria preferencialmente feito de uma maneira que não envolvesse equações.

   visual-line-modeenvolve a largura da janela, que é muito larga. Preciso de algo que envolva linhas e limite sua largura para 80 caracteres ou mais. Exatamente como fill-paragraphfaria normalmente, mas sem realmente quebrar as linhas no arquivo.

2. Posso quebrar manualmente a linha após cada frase, mas seria altamente preferível se eu pudesse configurar fill-paragraph(ou talvez até auto-fill-mode) colocar uma frase por linha também.

Se você quer apenas algo parecido, visual-line-modemas configurável, pode tentar longlines-modequal é o que eu uso na maior parte da minha prosa. longlines-modeagrupa seu texto de maneira semelhante à visual-line-modelargura configurada por fill-column.

Aqui está uma captura de tela com fill-columndefinido como 70(a janela na verdade se estende ainda mais para a direita).

A configuração fill-paragraphseria legal, mas não sei como fazê-lo. Em vez disso, aqui está um truque temporário razoável: torne seu .personagem elétrico no modo TeX, inserindo uma nova linha. Isso envolve apenas religá-lo em qualquer gancho de modo apropriado:

(defun my-electric-dot ()
  (interactive)
  (insert ".\n"))
(defun my-tex-hook ()
  (local-set-key (kbd ".") 'my-electric-dot))
(add-hook 'TeX-mode-hook 'my-tex-hook)

Para (1), eu usaria uma margem ampliada, de modo que visual-line-modeagrupe as linhas na desejada fill-column. Isso afetará as linhas e as equações do texto.

Quanto a (2), pode-se definir um comando de preenchimento personalizado a ser vinculado M-qe preencher corretamente os parágrafos. Ainda não consegui escrever um comando com o comportamento correto para o preenchimento automático.

Envolvendo tudo isso em um modo menor, pode parecer com o seguinte. Não é um código muito bonito, mas deve funcionar na maioria dos casos. (Eu exerço a unfill-paragraphfunção init.elhá algum tempo sem perceber problemas).

(define-minor-mode ospl-mode
  "One Sentence Per Line"
  :init-value nil
  :lighter " ospl"
  :keymap (let ((map (make-sparse-keymap)))
            (define-key map (kbd "M-q") 'ospl/fill-paragraph)
            map)

  (if ospl-mode
      (progn
        (visual-line-mode 1)
        (setq right-margin-width (- (window-body-width) fill-column)))
    (visual-line-mode -1)
    (setq right-margin-width 0))

  ;; Account for new margin width
  (set-window-buffer (selected-window) (current-buffer)))


(defun ospl/unfill-paragraph ()
  "Unfill the paragraph at point.

This repeatedly calls `join-line' until the whole paragraph does
not contain hard line breaks any more."
  (interactive)
  (forward-paragraph 1)
  (forward-paragraph -1)
  (while (looking-at paragraph-start)
    (forward-line 1))
  (let ((beg (point)))
    (forward-paragraph 1)
    (backward-char 1)
    (while (> (point) beg)
      (join-line)
      (beginning-of-line))))


(defun ospl/fill-paragraph ()
  "Fill the current paragraph until there is one sentence per line.

This unfills the paragraph, and places hard line breaks after each sentence."
  (interactive)
  (save-excursion
    (fill-paragraph)         ; takes care of putting 2 spaces if needed
    (ospl/unfill-paragraph)  ; remove hard line breaks

    ;; insert line breaks again
    (let ((end-of-paragraph (make-marker)))
      (save-excursion
        (forward-paragraph)
        (backward-sentence)
        (forward-sentence)
        (set-marker end-of-paragraph (point)))
      (forward-sentence) 
      (while (< (point) end-of-paragraph)
        (just-one-space)
        (delete-backward-char 1)
        (newline)
        (forward-sentence))
      (set-marker end-of-paragraph nil)))) 

Seus problemas de controle de versão seriam evitados / resolvidos se você usar git diff --color-words ou latexdiff? Então você pode olhar para as palavras alteradas.

Uma maneira de melhorar isso que eu tenho usado (às vezes) há vários anos é exibir frases com quebras de linha fluindo uma após a outra, dobrando as quebras de linha usando os recursos de tex-fold(uma parte do AUCTeX).

Isso significa que isso

Lorem ipsum dolor sit amet, consectetur adipiscing elit.
Mauris pellentesque fringilla justo, quis dapibus velit tincidunt quis?
Quisque varius ligula arcu, ut imperdiet risus maximus nec.

é dobrado para

Lorem ipsum dolor sit amet, consectetur adipiscing elit⁎ Mauris pellentesque fringilla justo, quis dapibus velit tincidunt quis❓  Quisque varius ligula arcu, ut imperdiet risus maximus nec⁎

Recentemente, coloquei isso como um modo secundário em um pacote. Talvez alguém também ache isso útil: https://github.com/andersjohansson/tex-fold-linebreaks