É possível adicionar modelos diferentes de # + BEGIN_ # + END_ ao org-structure-template-alist?

Percebi que a estrutura organizacional mudou de modelo (estou usando a versão 9.2 do modo organizacional) para expandir automaticamente para #+BEGIN_<some block tag> #+END_<some block tag>. Gostaria de saber se é possível adicionar diferentes tipos de modelos. Por exemplo, um :PROPERTIES:<some properties>:END:modelo.

É possível ou devo recorrer a outro pacote como o yasnippets?

ATUALIZAR:

Não notei que o Org Mode 9.2 mudou o mecanismo de expansão do modelo, onde org-structure-template-alisté apenas para os blocos definidos por "#+BEGIN_"e "#+END_". E a entrada como ("p" ":PROPERTIES:?:END:")não é mais aceita.

Como mencionado no link acima, outro modelo "complexo" pode ser definido por função tempo-define-templatee o org-tempo deve ser carregado ( (require 'org-tempo)). Na verdade, as entradas de org-structure-template-alist são convertidas em org-tempo-tagsvia tempo-define-templateby org-tempoe o org-tempo-tagspadrão é:

(("<i" . tempo-template-org-index)
 ("<A" . tempo-template-org-ascii)
 ("<H" . tempo-template-org-html)
 ("<L" . tempo-template-org-latex)
 ("<v" . tempo-template-org-verse)
 ("<s" . tempo-template-org-src)
 ("<q" . tempo-template-org-quote)
 ("<l" . tempo-template-org-export-latex)
 ("<h" . tempo-template-org-export-html)
 ("<E" . tempo-template-org-export)
 ("<e" . tempo-template-org-example)
 ("<C" . tempo-template-org-comment)
 ("<c" . tempo-template-org-center)
 ("<a" . tempo-template-org-export-ascii)
 ("<I" . tempo-template-org-include))

Para o seu caso, você pode definir um modelo:

(tempo-define-template "my-property"
               '(":PROPERTIES:" p ":END:" >)
               "<p"
               "Insert a property tempate")

A resposta abaixo funciona apenas para a versão do modo Org anterior à 9.2

Sim, você pode adicionar uma entrada assim:

(add-to-list 'org-structure-template-alist '("p" ":PROPERTIES:?:END:"))

Em seguida, no arquivo organizacional, você digita <pe TAB, ele será expandido para propriedade e deixará o ponto na posição de ?.

E você pode encontrar mais detalhes na documentação da variável digitando C-h v org-structure-template-alist RET.

A frequência com que eles introduzem alterações incompatíveis na personalização do modo organizacional é realmente uma pena.

O código a seguir fornece os modelos de estrutura antigos do modo organizacional anteriores à versão 9.2. A função org-complete-expand-structure-templateé uma cópia pura da versão 9.1 e org-try-structure-completioné uma versão ligeiramente modificada daquela da 9.1. (Adicionei uma verificação de tipo lá.)

Depois de instalar esse código, você pode simplesmente usar seu modelo antigo
(add-to-list 'org-structure-template-alist '("p" ":PROPERTIES:?:END:"))
novamente.

(defvar org-structure-template-alist)

(defun org+-avoid-old-structure-templates (fun &rest args)
  "Call FUN with ARGS with modified `org-structure-template-alist'.
Use a copy of `org-structure-template-alist' with all
old structure templates removed."
  (let ((org-structure-template-alist
     (cl-remove-if
      (lambda (template)
        (null (stringp (cdr template))))
      org-structure-template-alist)))
    (apply fun args)))

(eval-after-load "org"
  '(when (version<= "9.2" (org-version))
     (defun org-try-structure-completion ()
       "Try to complete a structure template before point.
This looks for strings like \"<e\" on an otherwise empty line and
expands them."
       (let ((l (buffer-substring (point-at-bol) (point)))
         a)
     (when (and (looking-at "[ \t]*$")
            (string-match "^[ \t]*<\\([a-zA-Z]+\\)$" l)
            (setq a (assoc (match-string 1 l) org-structure-template-alist))
            (null (stringp (cdr a))))
       (org-complete-expand-structure-template (+ -1 (point-at-bol)
                              (match-beginning 1)) a)
       t)))

     (defun org-complete-expand-structure-template (start cell)
       "Expand a structure template."
       (let ((rpl (nth 1 cell))
         (ind ""))
     (delete-region start (point))
     (when (string-match "\\`[ \t]*#\\+" rpl)
       (cond
        ((bolp))
        ((not (string-match "\\S-" (buffer-substring (point-at-bol) (point))))
         (setq ind (buffer-substring (point-at-bol) (point))))
        (t (newline))))
     (setq start (point))
     (when (string-match "%file" rpl)
       (setq rpl (replace-match
              (concat
               "\""
               (save-match-data
             (abbreviate-file-name (read-file-name "Include file: ")))
               "\"")
              t t rpl)))
     (setq rpl (mapconcat 'identity (split-string rpl "\n")
                  (concat "\n" ind)))
     (insert rpl)
     (when (re-search-backward "\\?" start t) (delete-char 1))))

     (advice-add 'org-tempo-add-templates :around #'org+-avoid-old-structure-templates)

     (add-hook 'org-tab-after-check-for-cycling-hook #'org-try-structure-completion)

     (require 'org-tempo)
     ))