Ocultar janela * compilação *

20

É irritante ver a janela de compilação aparecer quando for bem-sucedida. Como remover isso automaticamente?

Eu quero ver isso se não for bem sucedido.

window compilation

— Husain
fonte

11

anos atrás, no canal de IRC #emacs, recebi esse código que uso desde sempre. O valor "2 s" define a quantidade de tempo que a janela de compilação bem-sucedida permanece visível.

; from enberg on #emacs
(setq compilation-finish-function
  (lambda (buf str)
    (if (null (string-match ".*exited abnormally.*" str))
        ;;no errors, make the compilation window go away in a few seconds
        (progn
          (run-at-time
           "2 sec" nil 'delete-windows-on
           (get-buffer-create "*compilation*"))
          (message "No Compilation Errors!")))))

— shapr
fonte

14

Observando rapidamente o código (na biblioteca compile.el), você poderá matar ou ocultar o buffer exibido usando uma função no gancho compilation-finish-functions. Para fazer isso, use algo como isto:

 (add-hook 'compilation-finish-functions (lambda (buf strg) (kill-buffer buf))

Se você não deseja matar o buffer, use algo como isto:

 (add-hook 'compilation-finish-functions
           (lambda (buf strg)
             (let ((win  (get-buffer-window buf 'visible)))
               (when win (delete-window win)))))

Em geral, você pode imaginar que, para algo assim, provavelmente já existe um gancho, para que você possa anexar facilmente o código em um local tão significativo no processamento. Um pouco de navegação no código ou uso M-x aproposnormalmente o informará rapidamente. Os nomes dos ganchos geralmente terminam em -hookou -functions.

— Desenhou
fonte

2

Este tópico também é relevante, caso alguém esteja interessado:

/programming/11043004/emacs-compile-buffer-auto-close

O crédito vai para o autor original jpkotta . Aqui está a resposta dele:

Eu uso o seguinte para compilação. Ele mantém o buffer de compilação se houver avisos ou erros e o enterra de outra forma (após 1 segundo).

(defun bury-compile-buffer-if-successful (buffer string)
  "Bury a compilation buffer if succeeded without warnings "
  (if (and
       (string-match "compilation" (buffer-name buffer))
       (string-match "finished" string)
       (not
        (with-current-buffer buffer
          (search-forward "warning" nil t))))
      (run-with-timer 1 nil
                      (lambda (buf)
                        (bury-buffer buf)
                        (switch-to-prev-buffer (get-buffer-window buf) 'kill))
                      buffer)))
(add-hook 'compilation-finish-functions 'bury-compile-buffer-if-successful)

— Swarnendu Biswas
fonte

1

Por favor , não poste uma resposta que consista apenas em um link . Inclua as partes essenciais da resposta em sua postagem, para que ela responda à pergunta. Forneça o link como fonte e para mais informações. Para mais informações, leia nossas diretrizes sobre como escrever respostas .

— Gilles 'SO- stop be evil'

Atualizei minha resposta.

— Swarnendu Biswas

Observe que não há problema em citar a resposta de outra pessoa no Stack Exchange , mas você deve fornecer a atribuição adequada , incluindo o nome do autor.

— Gilles 'SO- stop be evil'

1

Eu tenho esse trecho no meu .emacs.d:

    (defcustom compilation-auto-quit-window-delay 1
      "Time in seconds before auto closing the window."
      :group 'compilation
      :type 'number)  

    (defun compilation-auto-quit-window-finish-function (buffer status)
      "Quit the *compilation* window if it went well."
      (let ((window (get-buffer-window buffer)))
        (when (and (equal status "finished\n")
                   (compilation-went-super-p))
          (run-with-timer
              (or compilation-auto-quit-window-delay 0) nil
            (lambda nil
              (when (and (window-live-p window)
                         (eq (window-buffer window)
                             buffer)
                         (not (eq (selected-window)
                                  window)))
                (save-selected-window
                  (quit-window nil window))))))))

    (define-minor-mode compilation-auto-quit-window
      "Automatically close the *compilation* window if it went well."
      :global t
      (cond (compilation-auto-quit-window
             (add-hook 'compilation-finish-functions
                       'compilation-auto-quit-window-finish-function))
            (t
             (remove-hook 'compilation-finish-functions
                          'compilation-auto-quit-window-finish-function))))

    (defun compilation-went-super-p (&optional buffer)
      "Return t, if no gotoable output appeared."
      (with-current-buffer (or buffer (current-buffer))
        (save-excursion
          (goto-char (point-min))
          (let (;; (compilation-skip-threshold 1)
                )
            (not (ignore-errors
                   (compilation-next-error 1)
                   t))))))

— politza
fonte