Como alternar rapidamente entre um arquivo e um buffer * scratch * com o mesmo modo principal?

Às vezes, enquanto trabalhava em um código, é útil abrir rapidamente um buffer * scratch * para colar um trecho desse arquivo de código.

Se eu estiver trabalhando em um script Perl, gostaria de abrir rapidamente um buffer * scratch * com in cperl-mode. Também seria bom voltar rapidamente para o buffer de código em que estava trabalhando originalmente.

Será conveniente vincular a função abaixo a uma ligação de chave de sua escolha. Se você estiver atualmente trabalhando em um FILEbuffer, chamar a função abaixo alternará entre FILEo buffer * scratch * específico do modo principal chamado *scratch-MAJOR-MODE*e o FILEbuffer.

Dado o exemplo em questão, se eu estiver trabalhando em um script Perl chamado myperl.pl, chamar essa função alternará entre myperl.ple *scratch-cperl-mode*.

(defun modi/switch-to-scratch-and-back (&optional arg)
  "Toggle between *scratch-MODE* buffer and the current buffer.
If a scratch buffer does not exist, create it with the major mode set to that
of the buffer from where this function is called.

        COMMAND -> Open/switch to a scratch buffer in the current buffer's major mode
    C-0 COMMAND -> Open/switch to a scratch buffer in `fundamental-mode'
    C-u COMMAND -> Open/switch to a scratch buffer in `org-mode'
C-u C-u COMMAND -> Open/switch to a scratch buffer in `emacs-elisp-mode'

Even if the current major mode is a read-only mode (derived from `special-mode'
or `dired-mode'), we would want to be able to write in the scratch buffer. So
the scratch major mode is set to `org-mode' for such cases.

Return the scratch buffer opened."
  (interactive "p")
  (if (and (or (null arg)               ; no prefix
               (= arg 1))
           (string-match-p "\\*scratch" (buffer-name)))
      (switch-to-buffer (other-buffer))
    (let* ((mode-str (cl-case arg
                       (0  "fundamental-mode") ; C-0
                       (4  "org-mode") ; C-u
                       (16 "emacs-lisp-mode") ; C-u C-u
                       ;; If the major mode turns out to be a `special-mode'
                       ;; derived mode, a read-only mode like `help-mode', open
                       ;; an `org-mode' scratch buffer instead.
                       (t (if (or (derived-mode-p 'special-mode) ; no prefix
                                  (derived-mode-p 'dired-mode))
                              "org-mode"
                            (format "%s" major-mode)))))
           (buf (get-buffer-create (concat "*scratch-" mode-str "*"))))
      (switch-to-buffer buf)
      (funcall (intern mode-str))   ; http://stackoverflow.com/a/7539787/1219634
      buf)))