org: Como classificar os títulos por TODO e depois por prioridade?

Costumo ter uma lista como esta:

* Main heading
** TODO [#A] Make world better
** TODO [#B] Make Emacs better 
** TODO [#B] Customize emacs 
** DONE [#C] some task
** TODO [#A] Launch rocket to mars

Gostaria de classificá-lo de acordo com a palavra-chave 'TODO' primeiro. Em seguida, os itens dentro do TODO classificado que eu gostaria de classificar por prioridade. (seria bom classificar ainda mais por "Esforço").

No momento, posso clicar no cabeçalho principal e classificar os filhos já por prioridade ou por palavra-chave todo, mas não por ambos.

A classificação por ambos é possível como estratégia de classificação?

Atualmente eu tenho dois títulos

* Tasks
** TODO [#A] meh
** TODO [#B] meh2
* Completed.
** DONE [#B] meh3.

Mas o problema com essa abordagem é que tenho que embaralhar constantemente as tarefas quando concluí-las.

[EDIT]
Isso é meio parecido com isso, exceto que eu não conseguia entender a resposta dele para transferi-la para minhas necessidades?

Seria ótimo se houvesse algo assim org-agenda-sorting-stratagytrabalhado org-sort-entries, mas não parece haver. Podemos fingir, pois org-sort-entriespodemos usar um argumento especificando uma função que atribui uma tecla (string ou número) a cada cabeçalho, que será usada para classificar as entradas quando o ?ftipo de classificação for fornecido. Tudo o que precisamos fazer é obter uma string para as propriedades TODO e PRIORITY. O truque é que queremos classificar a propriedade TODO por sua posição org-todo-keywords, e não por ordem alfabética.

(require 'cl)
(require 'dash)

(defun todo-to-int (todo)
    (first (-non-nil
            (mapcar (lambda (keywords)
                      (let ((todo-seq
                             (-map (lambda (x) (first (split-string  x "(")))
                                   (rest keywords)))) 
                        (cl-position-if (lambda (x) (string= x todo)) todo-seq)))
                    org-todo-keywords))))

(defun my/org-sort-key ()
  (let* ((todo-max (apply #'max (mapcar #'length org-todo-keywords)))
         (todo (org-entry-get (point) "TODO"))
         (todo-int (if todo (todo-to-int todo) todo-max))
         (priority (org-entry-get (point) "PRIORITY"))
         (priority-int (if priority (string-to-char priority) org-default-priority)))
    (format "%03d %03d" todo-int priority-int)
    ))

(defun my/org-sort-entries ()
  (interactive)
  (org-sort-entries nil ?f #'my/org-sort-key))

M-x my/org-sort-entriesclassificará pela palavra-chave TODO e romperá os vínculos com PRIORITY (usando org-default-priorityquando nenhuma prioridade for dada). Isso será interrompido se você tiver mais de 1000 palavras-chave TODO, o que é um bom motivo para não fazer isso.

Adicione o seguinte ao seu arquivo:

#+ARCHIVE: :: * Completed.

E embaralhar se torna arquivamento

Em vez de classificar as entradas, que tal uma exibição classificada?

(setq org-agenda-custom-commands
      '(("cx" "TODOs sorted by state, priority, effort"
         todo "*"
         ((org-agenda-overriding-header "\nTODOs sorted by state, priority, effort")
          (org-agenda-sorting-strategy '(todo-state-down priority-down effort-up))))))

Restrinja-o ao arquivo atual com <. Você pode marcar Concluído e arquivar a partir da exibição classificada.

Você também pode definir uma org-agenda-cmp-user-definedfunção e adicioná-la org-agenda-sorting-strategy. Este é o que eu criei como exemplo.

(setq org-todo-sort-order '("WAIT" "TODO" "DOING" "CANCELED" "DONE"))

(defun my:user-todo-sort (a b)
  "Sort todo based on which I want to see first"
  (when-let ((state-a (get-text-property 14 'todo-state a))
             (state-b (get-text-property 14 'todo-state b))
             (cmp (--map (cl-position-if (lambda (x)
                                           (equal x it))
                                         org-todo-sort-order)
                         (list state-a state-b))))
    (cond ((apply '> cmp) 1)
          ((apply '< cmp) -1)
          (t nil))))
(setq org-agenda-cmp-user-defined 'my:user-todo-sort)

Você pode usar esta biblioteca criada por mim: https://github.com/felipelalli/org-sort-tasks

Ele usa o Merge Sort algo perguntando ao usuário se uma tarefa A é mais importante que B e, em seguida, cria uma lista classificada.