Como executar a suavização de linhas SIA ou Bezier no PostGIS?

Alguém pode fornecer um exemplo de SQL para suavizar cadeias de linhas da tabela postgis usando curvas de Bezier ou o algoritmo de Média Iterativa ( SIA )?

Criei um script pequeno e ingênuo que converte LineStrings de entrada em CompoundCurves com base em algumas heurísticas.

O que faz:

• Corta cantos afiados para criar resultados visualmente mais atraentes do que os dados originais.
• Usa plpgsql. Não são necessárias extensões adicionais.
• Aceita um "fator de suavização" opcional entre 0 e 100, além de uma geometria.

O que não faz:

• Processa MultiLineStrings. Para qualquer outro tipo de geometria, ele simplesmente retorna a entrada.
• Usa os valores de Z e M. Simplesmente os deixa cair. Use isso apenas para fins cartográficos 2D.
• Cria resultados matematicamente corretos. Os resultados estão longe de estar corretos e podem até ser visualmente estéticos em alguns casos (por exemplo, cantos afiados). Eu não testei completamente. Sempre revise os resultados!
• Corre rápido. Tenho certeza de que pode ser reescrito para uma forma muito mais otimizada.
• Real alisamento. Existem algoritmos muito melhores (por exemplo, o Chaiken ou os mencionados na pergunta) para usar na suavização real. Essa resposta é direcionada a pessoas como eu, procurando uma abordagem PostGIS pura, criando automaticamente algum tipo de linha curva a partir de dados reais.

O script:

CREATE OR REPLACE FUNCTION CreateCurve(geom geometry, percent int DEFAULT 40)
    RETURNS geometry AS
$$
DECLARE
    result text;
    p0 geometry;
    p1 geometry;
    p2 geometry;
    intp geometry;
    tempp geometry;
    geomtype text := ST_GeometryType(geom);
    factor double precision := percent::double precision / 200;
    i integer;
BEGIN
    IF percent < 0 OR percent > 100 THEN
        RAISE EXCEPTION 'Smoothing factor must be between 0 and 100';
    END IF;
    IF geomtype != 'ST_LineString' OR factor = 0 THEN
        RETURN geom;
    END IF;
    result := 'COMPOUNDCURVE((';
    p0 := ST_PointN(geom, 1);
    IF ST_NPoints(geom) = 2 THEN
        p1:= ST_PointN(geom, 2);
        result := result || ST_X(p0) || ' ' || ST_Y(p0) || ',' || ST_X(p1) || ' ' || ST_Y(p1) || '))';
    ELSE
        FOR i IN 2..(ST_NPoints(geom) - 1) LOOP
            p1 := ST_PointN(geom, i);
            p2 := ST_PointN(geom, i + 1);
            result := result || ST_X(p0) || ' ' || ST_Y(p0) || ',';
            tempp := ST_Line_Interpolate_Point(ST_MakeLine(p1, p0), factor);
            p0 := ST_Line_Interpolate_Point(ST_MakeLine(p1, p2), factor);
            intp := ST_Line_Interpolate_Point(
                ST_MakeLine(
                    ST_Line_Interpolate_Point(ST_MakeLine(p0, p1), 0.5),
                    ST_Line_Interpolate_Point(ST_MakeLine(tempp, p1), 0.5)
                ), 0.5);
            result := result || ST_X(tempp) || ' ' || ST_Y(tempp) || '),CIRCULARSTRING(' || ST_X(tempp) || ' ' || ST_Y(tempp) || ',' || ST_X(intp) || ' ' ||
            ST_Y(intp) || ',' || ST_X(p0) || ' ' || ST_Y(p0) || '),(';
        END LOOP;
        result := result || ST_X(p0) || ' ' || ST_Y(p0) || ',' || ST_X(p2) || ' ' || ST_Y(p2) || '))';
    END IF;
    RETURN ST_SetSRID(result::geometry, ST_SRID(geom));
END;
$$
LANGUAGE 'plpgsql' IMMUTABLE;

Como ele retorna curvas em um tipo de geometria, se você deseja usá-lo em um GIS, como o QGIS, é necessário envolvê-lo nas funções do PostGIS, convertendo-as. A sintaxe de uso pretendida é:

SELECT ST_AsText(ST_CurveToLine(CreateCurve(geom))) AS geom FROM linestringtable;

Esta ainda é uma questão em aberto no PostGIS (e em outras ferramentas GIS), conforme declarado no livro "PostGIS in Action" no capítulo 2.2.6 "Geometrias curvas".

Aqui estão algumas referências a algoritmos e código:

• http://www.codeproject.com/Articles/31859/Draw-a-Smooth-Curve-through-a-Set-of-2D-Points-wit
• http://www.antigrain.com/research/bezier_interpolation/index.html (também usado pela função LineSmoother no JTS!)
• http://www.java2v.com/Code/Java/2D-Graphics-GUI/Interpolatesgivenpointsbyabeziercurve.htm
• http://www.ibiblio.org/e-notes/Splines/Bezier.java

Você pode tentar converter suas cadeias de linhas em curvas com ST_LineToCurve e depois voltar para cadeias de linhas com ST_CurveToLine .

Você pode definir o número de segmentos por quarto de círculo que deseja em ST_CurveToLine.