String.Format como funcionalidade em T-SQL?

89

Estou procurando uma função interna / função estendida em T-SQL para manipulação de string semelhante ao String.Formatmétodo em .NET.

tsql  string 
— Jeff
fonte

Respostas:

70

Se estiver usando o SQL Server 2012 e superior, você pode usar FORMATMESSAGE. por exemplo.

DECLARE @s NVARCHAR(50) = 'World';
DECLARE @d INT = 123;
SELECT FORMATMESSAGE('Hello %s, %d', @s, @d)
-- RETURNS 'Hello World, 123'

Mais exemplos do MSDN: FORMATMESSAGE

SELECT FORMATMESSAGE('Signed int %i, %d %i, %d, %+i, %+d, %+i, %+d', 5, -5, 50, -50, -11, -11, 11, 11);
SELECT FORMATMESSAGE('Signed int with leading zero %020i', 5);
SELECT FORMATMESSAGE('Signed int with leading zero 0 %020i', -55);
SELECT FORMATMESSAGE('Unsigned int %u, %u', 50, -50);
SELECT FORMATMESSAGE('Unsigned octal %o, %o', 50, -50);
SELECT FORMATMESSAGE('Unsigned hexadecimal %x, %X, %X, %X, %x', 11, 11, -11, 50, -50);
SELECT FORMATMESSAGE('Unsigned octal with prefix: %#o, %#o', 50, -50);
SELECT FORMATMESSAGE('Unsigned hexadecimal with prefix: %#x, %#X, %#X, %X, %x', 11, 11, -11, 50, -50);
SELECT FORMATMESSAGE('Hello %s!', 'TEST');
SELECT FORMATMESSAGE('Hello %20s!', 'TEST');
SELECT FORMATMESSAGE('Hello %-20s!', 'TEST');
SELECT FORMATMESSAGE('Hello %20s!', 'TEST');

NOTAS:

  • Indocumentado em 2012
  • Limitada a 2.044 caracteres
  • Para escapar do sinal%, você precisa dobrá-lo.
  • Se você estiver registrando erros em eventos estendidos, a chamada FORMATMESSAGEaparecerá como um erro (inofensivo)
— g2server
fonte
1
Se você estiver usando SQL 2012, você pode usar a função FORMAT sem todas as complicações acima :)
— Invertido Engenheiro
1
Isso deve ter muito mais votos! Awesome find sempre evitado porque assumiu que só funcionaria com built-in msg_number.
— Lankymart
1
@Lankymart, bata! Concordo que essa deve ser a resposta aceita: simples, embutida e funcionou esplendidamente.
— Robert Synoradzki
5
@bijayk ele só aceita nomes de placeholder específicos, por exemplo,% s para strings,% i para ints.
— g2server
2
@lostmylogin Não há string.Formatfuncionalidade de estilo no T-SQL, isso é o mais próximo que você obterá.
— Ian Kemp
53

dê uma olhada em xp_sprintf . exemplo abaixo.

DECLARE @ret_string varchar (255)
EXEC xp_sprintf @ret_string OUTPUT, 
    'INSERT INTO %s VALUES (%s, %s)', 'table1', '1', '2'
PRINT @ret_string

O resultado é assim:

INSERT INTO table1 VALUES (1, 2)

Acabei de encontrar um problema com o tamanho máximo (limite de 255 caracteres) da string com isso, então há uma função alternativa que você pode usar:

create function dbo.fnSprintf (@s varchar(MAX), 
                @params varchar(MAX), @separator char(1) = ',')
returns varchar(MAX)
as
begin
declare @p varchar(MAX)
declare @paramlen int

set @params = @params + @separator
set @paramlen = len(@params)
while not @params = ''
begin
    set @p = left(@params+@separator, charindex(@separator, @params)-1)
    set @s = STUFF(@s, charindex('%s', @s), 2, @p)
    set @params = substring(@params, len(@p)+2, @paramlen)
end
return @s
end

Para obter o mesmo resultado acima, você chama a função da seguinte maneira:

print dbo.fnSprintf('INSERT INTO %s VALUES (%s, %s)', 'table1,1,2', default)
— Josh
fonte
7
Apenas um FYI, se algum de seus parâmetros contiver uma vírgula, você está sem sorte. Se você passar por um por acidente, terá alguns problemas para descobrir o que deu errado.
— Kyle
15

Eu criei uma função definida pelo usuário para imitar a funcionalidade string.format. Você pode usar isso.

stringformat-in-sql

— Karthik DV
fonte
Gosto desta solução porque tenho reservas contra o uso de funções xp_ / SPs na produção. Usei seu código como base e permiti a passagem do delimitador, o que elimina qualquer preocupação com o uso de vírgulas nos dados.
— Tim Friesen
4

Existe um caminho, mas tem suas limitações. Você pode usar a FORMATMESSAGE()função. Ele permite que você formate uma string usando uma formatação semelhante à printf()função em C.

No entanto, a maior limitação é que ele funcionará apenas com mensagens na tabela sys.messages. Aqui está um artigo sobre isso: microsoft_library_ms186788

É uma pena que não haja uma maneira mais fácil de fazer isso, porque há momentos em que você deseja formatar uma string / varchar no banco de dados. Esperançosamente, você está apenas procurando formatar uma string de maneira padrão e pode usar a sys.messagestabela.

Coincidentemente, você também pode usar a RAISERROR()função com uma gravidade muito baixa, a documentação para raiseerror até menciona fazer isso, mas os resultados são apenas impressos. Então você não seria capaz de fazer nada com o valor resultante (pelo que entendi).

Boa sorte!

— jj.
fonte
1
Entenda que esta é uma resposta antiga, mas a suposição sobre FORMATMESSAGE()está incorreta, no entanto, compreensível porque não está documentada, mas aceitará qualquer string como um primeiro parâmetro, veja esta resposta por @ g2server .
— Lankymart
@Lankymart Você está correto - esta é uma resposta antiga. A capacidade de aceitar uma string não foi adicionada até o SQL 2012.
— jj.
3

O t-sql bruto é limitado a CHARINDEX (), PATINDEX (), REPLACE () e SUBSTRING () para manipulação de string. Mas com o sql server 2005 e posterior você pode configurar funções definidas pelo usuário que rodam em .Net, o que significa que configurar um string.format () UDF não deve ser muito difícil.

— Joel Coehoorn
fonte
2

Mais uma ideia.

Embora esta não seja uma solução universal - é simples e funciona, pelo menos para mim :)

Para um marcador de posição {0}:

create function dbo.Format1
(
    @String  nvarchar(4000),
    @Param0  sql_variant
)
returns nvarchar(4000)
as
begin
    declare @Null nvarchar(4) = N'NULL';

    return replace(@String, N'{0}', cast(isnull(@Param0, @Null) as nvarchar(4000)));    
end

Para dois marcadores de posição {0} e {1}:

create function dbo.Format2
(
    @String  nvarchar(4000),
    @Param0  sql_variant,
    @Param1  sql_variant
)
returns nvarchar(4000)
as
begin
    declare @Null nvarchar(4) = N'NULL';

    set @String = replace(@String, N'{0}', cast(isnull(@Param0, @Null) as nvarchar(4000)));
       return     replace(@String, N'{1}', cast(isnull(@Param1, @Null) as nvarchar(4000))); 
end

Para três marcadores de posição {0}, {1} e {2}:

create function dbo.Format3
(
    @String  nvarchar(4000),
    @Param0  sql_variant,
    @Param1  sql_variant,
    @Param2  sql_variant
)
returns nvarchar(4000)
as
begin
    declare @Null nvarchar(4) = N'NULL';

    set @String = replace(@String, N'{0}', cast(isnull(@Param0, @Null) as nvarchar(4000)));
    set @String = replace(@String, N'{1}', cast(isnull(@Param1, @Null) as nvarchar(4000))); 
       return     replace(@String, N'{2}', cast(isnull(@Param2, @Null) as nvarchar(4000)));
end

e assim por diante...

Tal abordagem nos permite usar essas funções na instrução SELECT e com parâmetros de tipos de dados nvarchar, number, bit e datetime.

Por exemplo:

declare @Param0 nvarchar(10) = N'IPSUM' ,
        @Param1 int          = 1234567  ,
        @Param2 datetime2(0) = getdate();

select dbo.Format3(N'Lorem {0} dolor, {1} elit at {2}', @Param0, @Param1, @Param2);
— Vadim Loboda
fonte
1

Acho que há uma pequena correção durante o cálculo da posição final.

Aqui está a função correta

**>>**IF OBJECT_ID( N'[dbo].[FormatString]', 'FN' ) IS NOT NULL
DROP FUNCTION [dbo].[FormatString]
GO
/***************************************************
Object Name : FormatString
Purpose : Returns the formatted string.
Original Author : Karthik D V http://stringformat-in-sql.blogspot.com/
Sample Call:
SELECT dbo.FormatString ( N'Format {0} {1} {2} {0}', N'1,2,3' )
*******************************************/
CREATE FUNCTION [dbo].[FormatString](
    @Format NVARCHAR(4000) ,
    @Parameters NVARCHAR(4000)
)
RETURNS NVARCHAR(4000)
AS
BEGIN
    --DECLARE @Format NVARCHAR(4000), @Parameters NVARCHAR(4000) select @format='{0}{1}', @Parameters='hello,world'
    DECLARE @Message NVARCHAR(400), @Delimiter CHAR(1)
    DECLARE @ParamTable TABLE ( ID INT IDENTITY(0,1), Parameter VARCHAR(1000) )
    Declare @startPos int, @endPos int
    SELECT @Message = @Format, @Delimiter = ','**>>**

    --handle first parameter
     set @endPos=CHARINDEX(@Delimiter,@Parameters)
    if (@endPos=0 and @Parameters is not null) --there is only one parameter
        insert into @ParamTable (Parameter) values(@Parameters)
    else begin
        insert into @ParamTable (Parameter) select substring(@Parameters,0,@endPos)
    end

    while @endPos>0
    Begin
        --insert a row for each parameter in the 
        set @startPos = @endPos + LEN(@Delimiter)
        set @endPos = CHARINDEX(@Delimiter,@Parameters, @startPos)
        if (@endPos>0)
            insert into @ParamTable (Parameter) 
                select substring(@Parameters,@startPos,@endPos - @startPos)
            else
                insert into @ParamTable (Parameter) 
                select substring(@Parameters,@startPos,4000)            
    End

    UPDATE @ParamTable SET @Message = 
        REPLACE ( @Message, '{'+CONVERT(VARCHAR,ID) + '}', Parameter )
    RETURN @Message
END
Go
grant execute,references on dbo.formatString to public
— SP007
fonte
1

Aqui está minha versão. Pode ser estendido para acomodar mais número de parâmetros e pode estender a formatação com base no tipo. Atualmente, apenas os tipos de data e data e hora são formatados.

Exemplo:

select dbo.FormatString('some string %s some int %s date %s','"abcd"',100,cast(getdate() as date),DEFAULT,DEFAULT)
select dbo.FormatString('some string %s some int %s date time %s','"abcd"',100,getdate(),DEFAULT,DEFAULT)

Resultado:

some string "abcd" some int 100 date 29-Apr-2017
some string "abcd" some int 100 date time 29-Apr-2017 19:40

Funções:

create function dbo.FormatValue(@param sql_variant)
returns nvarchar(100)
begin
/*
Tejasvi Hegde, 29-April-2017
Can extend formatting here.
*/
    declare @result nvarchar(100)

    if (SQL_VARIANT_PROPERTY(@param,'BaseType') in ('date'))
    begin
       select @result = REPLACE(CONVERT(CHAR(11), @param, 106), ' ', '-')
    end
    else  if (SQL_VARIANT_PROPERTY(@param,'BaseType') in ('datetime','datetime2'))
    begin
       select @result = REPLACE(CONVERT(CHAR(11), @param, 106), ' ', '-')+' '+CONVERT(VARCHAR(5),@param,108)
    end
    else
    begin
       select @result = cast(@param as nvarchar(100))
    end
    return @result

/*
BaseType:
bigint
binary
char
date
datetime
datetime2
datetimeoffset
decimal
float
int
money
nchar
numeric
nvarchar
real
smalldatetime
smallint
smallmoney
time
tinyint
uniqueidentifier
varbinary
varchar
*/   

end;


create function dbo.FormatString(
    @format nvarchar(4000)
    ,@param1 sql_variant = null
    ,@param2 sql_variant = null
    ,@param3 sql_variant = null
    ,@param4 sql_variant = null
    ,@param5 sql_variant = null
    )
returns nvarchar(4000)
begin
/*
Tejasvi Hegde, 29-April-2017

select dbo.FormatString('some string value %s some int %s date %s','"abcd"',100,cast(getdate() as date),DEFAULT,DEFAULT)
select dbo.FormatString('some string value %s some int %s date time %s','"abcd"',100,getdate(),DEFAULT,DEFAULT)
*/

    declare @result nvarchar(4000)

    select @param1 = dbo.formatValue(@param1)
    ,@param2 = dbo.formatValue(@param2)
    ,@param3 = dbo.formatValue(@param3)
    ,@param4 = dbo.formatValue(@param4)
    ,@param5 = dbo.formatValue(@param5)

    select @param2 = cast(@param2 as nvarchar)
    EXEC xp_sprintf @result OUTPUT,@format , @param1, @param2, @param3, @param4, @param5

    return @result

end;
— Tejasvi Hegde
fonte
A resposta mais simples para SQL Server 2008+. Mantém as entradas como parâmetros separados. Usa a função xp_sprintf e pode ser estendido facilmente. xp_sprintf - docs.microsoft.com/en-us/sql/relational-databases/…
— Jeff Lewis
0

aqui está o que descobri com meus experimentos usando o integrado

Função FORMATMESSAGE ()

sp_addmessage @msgnum=50001,@severity=1,@msgText='Hello %s you are #%d',@replace='replace'
SELECT FORMATMESSAGE(50001, 'Table1', 5)

quando você chama sp_addmessage, seu modelo de mensagem é armazenado na tabela de sistema master.dbo.sysmessages (verificado em SQLServer 2000).

Você mesmo deve gerenciar a adição e a remoção de strings de modelo da tabela, o que é estranho se tudo o que você realmente deseja é enviar uma mensagem rápida para a tela de resultados.

A solução fornecida por Kathik DV parece interessante, mas não funciona com o SQL Server 2000, então alterei um pouco, e esta versão deve funcionar com todas as versões do SQL Server:

IF OBJECT_ID( N'[dbo].[FormatString]', 'FN' ) IS NOT NULL
    DROP FUNCTION [dbo].[FormatString]
GO
/***************************************************
Object Name : FormatString
Purpose : Returns the formatted string.
Original Author : Karthik D V http://stringformat-in-sql.blogspot.com/
Sample Call:
SELECT dbo.FormatString ( N'Format {0} {1} {2} {0}', N'1,2,3' )
*******************************************/
CREATE FUNCTION [dbo].[FormatString](
@Format NVARCHAR(4000) ,
@Parameters NVARCHAR(4000)
)
RETURNS NVARCHAR(4000)
AS
BEGIN
    --DECLARE @Format NVARCHAR(4000), @Parameters NVARCHAR(4000) select @format='{0}{1}', @Parameters='hello,world'
    DECLARE @Message NVARCHAR(400), @Delimiter CHAR(1)
    DECLARE @ParamTable TABLE ( ID INT IDENTITY(0,1), Parameter VARCHAR(1000) )
    Declare @startPos int, @endPos int
    SELECT @Message = @Format, @Delimiter = ','

    --handle first parameter
     set @endPos=CHARINDEX(@Delimiter,@Parameters)
    if (@endPos=0 and @Parameters is not null) --there is only one parameter
        insert into @ParamTable (Parameter) values(@Parameters)
    else begin
        insert into @ParamTable (Parameter) select substring(@Parameters,0,@endPos)
    end

    while @endPos>0
    Begin
        --insert a row for each parameter in the 
        set @startPos = @endPos + LEN(@Delimiter)
        set @endPos = CHARINDEX(@Delimiter,@Parameters, @startPos)
        if (@endPos>0)
            insert into @ParamTable (Parameter) select substring(@Parameters,@startPos,@endPos)
        else
            insert into @ParamTable (Parameter) select substring(@Parameters,@startPos,4000)            
    End

    UPDATE @ParamTable SET @Message = REPLACE ( @Message, '{'+CONVERT(VARCHAR,ID) + '}', Parameter )
    RETURN @Message
END
Go
    grant execute,references on dbo.formatString to public

Uso:

print dbo.formatString('hello {0}... you are {1}','world,good')
--result: hello world... you are good
— BraveNewMath
fonte
-1

Na verdade, não há nenhuma função interna semelhante à string. A função de formato do .NET está disponível no servidor SQL.

Há uma função FORMATMESSAGE () no servidor SQL, mas ela imita a função printf () de C, não a função string.Format de .NET.

SELECT FORMATMESSAGE('This is the %s and this is the %s.', 'first variable', 'second variable') AS Result
— Brijesh Kumar Tripathi
fonte
-2

Não exatamente, mas gostaria de verificar alguns dos artigos sobre manipulação de strings (entre outras coisas) por "Phil Factor" (geddit?) No Simple Talk.

— Duncan Smart
fonte
-3

esta é uma abordagem ruim. você deve trabalhar com dll's assembly, nas quais fará o mesmo por você com melhor desempenho.

— pelegk1
fonte
Ao utilizar nosso site, você reconhece que leu e compreendeu nossa Política de Cookies e nossa Política de Privacidade.
Licensed under cc by-sa 3.0 with attribution required.