Resolver caminho absoluto a partir do caminho relativo e / ou nome do arquivo

Existe uma maneira em um script em lote do Windows retornar um caminho absoluto de um valor que contém um nome de arquivo e / ou caminho relativo?

Dado:

"..\"
"..\somefile.txt"

Eu preciso do caminho absoluto em relação ao arquivo em lotes.

Exemplo:

• "somefile.txt" está localizado em "C: \ Foo \"
• "test.bat" está localizado em "C: \ Foo \ Bar".
• O usuário abre uma janela de comando em "C: \ Foo" e chama Bar\test.bat ..\somefile.txt
• No arquivo em lotes "C: \ Foo \ somefile.txt" seria derivado de %1

Nos arquivos em lote, como nos programas C padrão, o argumento 0 contém o caminho para o script atualmente em execução. Você pode usar %~dp0para obter apenas a parte do caminho do argumento 0 (que é o script atual) - esse caminho é sempre um caminho totalmente qualificado.

Você também pode obter o caminho completo do seu primeiro argumento usando %~f1, mas isso fornece um caminho de acordo com o diretório de trabalho atual, que obviamente não é o que você deseja.

Pessoalmente, geralmente uso o %~dp0%~1idioma no meu arquivo em lotes, que interpreta o primeiro argumento em relação ao caminho do lote em execução. Porém, ele tem uma falha: falha miseravelmente se o primeiro argumento for totalmente qualificado.

Se você precisar oferecer suporte a caminhos relativos e absolutos, poderá usar a solução de Frédéric Ménez : altere temporariamente o diretório de trabalho atual.

Aqui está um exemplo que demonstrará cada uma dessas técnicas:

@echo off
echo %%~dp0 is "%~dp0"
echo %%0 is "%0"
echo %%~dpnx0 is "%~dpnx0"
echo %%~f1 is "%~f1"
echo %%~dp0%%~1 is "%~dp0%~1"

rem Temporarily change the current working directory, to retrieve a full path 
rem   to the first parameter
pushd .
cd %~dp0
echo batch-relative %%~f1 is "%~f1"
popd

Se você salvar isso como c: \ temp \ example.bat e executá-lo em c: \ Users \ Public como

c: \ Usuários \ Público> \ temp \ example.bat .. \ windows

... você observará a seguinte saída:

%~dp0 is "C:\temp\"
%0 is "\temp\example.bat"
%~dpnx0 is "C:\temp\example.bat"
%~f1 is "C:\Users\windows"
%~dp0%~1 is "C:\temp\..\windows"
batch-relative %~f1 is "C:\Windows"

a documentação para o conjunto de modificadores permitidos em um argumento em lote pode ser encontrada aqui: https://docs.microsoft.com/en-us/windows-server/administration/windows-commands/call

Me deparei com uma necessidade semelhante nesta manhã: como converter um caminho relativo em um caminho absoluto dentro de um script de comando do Windows.

O seguinte fez o truque:

@echo off

set REL_PATH=..\..\
set ABS_PATH=

rem // Save current directory and change to target directory
pushd %REL_PATH%

rem // Save value of CD variable (current directory)
set ABS_PATH=%CD%

rem // Restore original directory
popd

echo Relative path: %REL_PATH%
echo Maps to path: %ABS_PATH%

A maioria dessas respostas parece louca por complicados e super bugs, aqui está a minha - ela funciona em qualquer variável de ambiente, nenhuma %CD%ou PUSHD/ POPDou for /fbobagem - apenas funções simples de lote antigas. - O diretório e o arquivo nem precisam existir.

CALL :NORMALIZEPATH "..\..\..\foo\bar.txt"
SET BLAH=%RETVAL%

ECHO "%BLAH%"

:: ========== FUNCTIONS ==========
EXIT /B

:NORMALIZEPATH
  SET RETVAL=%~f1
  EXIT /B

Sem ter que ter outro arquivo em lote para transmitir argumentos (e usar os operadores de argumento), você pode usar FOR /F:

FOR /F %%i IN ("..\relativePath") DO echo absolute path: %%~fi

onde iin %%~fié a variável definida em /F %%i. por exemplo. se você mudou para /F %%aentão a última parte seria %%~fa.

Para fazer a mesma coisa no prompt de comando (e não em um arquivo em lotes), substitua %%por %...

Isso serve para ajudar a preencher as lacunas na resposta de Adrien Plisson (que deve ser votada assim que ele a editar ;-):

você também pode obter o caminho completo do seu primeiro argumento usando% ~ f1, mas isso fornece um caminho de acordo com o caminho atual, que obviamente não é o que você deseja.

infelizmente, eu não sei como misturar os 2 juntos ...

Pode-se lidar %0e da %1mesma forma:

• %~dpnx0para unidade qualificada + caminho + nome + extensão do próprio arquivo em lote,
  %~f0também é suficiente;
• %~dpnx1para drive totalmente qualificado + caminho + nome + extensão de seu primeiro argumento [se é que é um nome de arquivo],
  %~f1também é suficiente;

%~f1funcionará independentemente de como você especificou seu primeiro argumento: com caminhos relativos ou com caminhos absolutos (se você não especificar a extensão do arquivo ao nomear %1, ele não será adicionado, mesmo se você usar %~dpnx1- no entanto.

Mas como diabos você nomearia um arquivo em uma unidade diferente de qualquer maneira, se não desse essas informações de caminho completo na linha de comando?

No entanto, %~p0, %~n0, %~nx0e %~x0pode vir a calhar, você deve estar interessado no caminho (sem driveletter), nome do arquivo (sem extensão), nome completo com extensão ou apenas a extensão do nome de arquivo. Mas observe, while %~p1e %~n1trabalhará para descobrir o caminho ou o nome do primeiro argumento %~nx1e %~x1não adicionar + mostrar a extensão, a menos que você já o tenha usado na linha de comando.

Você também pode usar funções em lote para isso:

@echo off
setlocal 

goto MAIN
::-----------------------------------------------
:: "%~f2" get abs path of %~2. 
::"%~fs2" get abs path with short names of %~2.
:setAbsPath
  setlocal
  set __absPath=%~f2
  endlocal && set %1=%__absPath%
  goto :eof
::-----------------------------------------------

:MAIN
call :setAbsPath ABS_PATH ..\
echo %ABS_PATH%

endlocal

Pequena melhoria na excelente solução do BrainSlugs83 . Generalizado para permitir nomear a variável de ambiente de saída na chamada.

@echo off
setlocal EnableDelayedExpansion

rem Example input value.
set RelativePath=doc\build

rem Resolve path.
call :ResolvePath AbsolutePath %RelativePath%

rem Output result.
echo %AbsolutePath%

rem End.
exit /b

rem === Functions ===

rem Resolve path to absolute.
rem Param 1: Name of output variable.
rem Param 2: Path to resolve.
rem Return: Resolved absolute path.
:ResolvePath
    set %1=%~dpfn2
    exit /b

Se executar a partir da C:\projectsaída for:

C:\project\doc\build

Não vi muitas soluções para esse problema. Algumas soluções fazem uso de passagem de diretório usando CD e outras fazem uso de funções em lote. Minha preferência pessoal foi pelas funções em lote e, em particular, pela função MakeAbsolute , conforme fornecida pelo DosTips.

A função tem alguns benefícios reais, principalmente porque ela não altera seu diretório de trabalho atual e, em segundo lugar, que os caminhos que estão sendo avaliados nem precisam existir. Você pode encontrar algumas dicas úteis sobre como usar a função aqui também.

Aqui está um exemplo de script e suas saídas:

@echo off

set scriptpath=%~dp0
set siblingfile=sibling.bat
set siblingfolder=sibling\
set fnwsfolder=folder name with spaces\
set descendantfolder=sibling\descendant\
set ancestorfolder=..\..\
set cousinfolder=..\uncle\cousin

call:MakeAbsolute siblingfile      "%scriptpath%"
call:MakeAbsolute siblingfolder    "%scriptpath%"
call:MakeAbsolute fnwsfolder       "%scriptpath%"
call:MakeAbsolute descendantfolder "%scriptpath%"
call:MakeAbsolute ancestorfolder   "%scriptpath%"
call:MakeAbsolute cousinfolder     "%scriptpath%"

echo scriptpath:       %scriptpath%
echo siblingfile:      %siblingfile%
echo siblingfolder:    %siblingfolder%
echo fnwsfolder:       %fnwsfolder%
echo descendantfolder: %descendantfolder%
echo ancestorfolder:   %ancestorfolder%
echo cousinfolder:     %cousinfolder%
GOTO:EOF

::----------------------------------------------------------------------------------
:: Function declarations
:: Handy to read http://www.dostips.com/DtTutoFunctions.php for how dos functions
:: work.
::----------------------------------------------------------------------------------
:MakeAbsolute file base -- makes a file name absolute considering a base path
::                      -- file [in,out] - variable with file name to be converted, or file name itself for result in stdout
::                      -- base [in,opt] - base path, leave blank for current directory
:$created 20060101 :$changed 20080219 :$categories Path
:$source http://www.dostips.com
SETLOCAL ENABLEDELAYEDEXPANSION
set "src=%~1"
if defined %1 set "src=!%~1!"
set "bas=%~2"
if not defined bas set "bas=%cd%"
for /f "tokens=*" %%a in ("%bas%.\%src%") do set "src=%%~fa"
( ENDLOCAL & REM RETURN VALUES
    IF defined %1 (SET %~1=%src%) ELSE ECHO.%src%
)
EXIT /b

E a saída:

C:\Users\dayneo\Documents>myscript
scriptpath:       C:\Users\dayneo\Documents\
siblingfile:      C:\Users\dayneo\Documents\sibling.bat
siblingfolder:    C:\Users\dayneo\Documents\sibling\
fnwsfolder:       C:\Users\dayneo\Documents\folder name with spaces\
descendantfolder: C:\Users\dayneo\Documents\sibling\descendant\
ancestorfolder:   C:\Users\
cousinfolder:     C:\Users\dayneo\uncle\cousin

Espero que isso ajude ... Com certeza me ajudou :) PS Mais uma vez obrigado ao DosTips! Você é demais!

Você pode apenas concatená-los.

SET ABS_PATH=%~dp0 
SET REL_PATH=..\SomeFile.txt
SET COMBINED_PATH=%ABS_PATH%%REL_PATH%

parece estranho com \ .. \ no meio do seu caminho, mas funciona. Não há necessidade de fazer nada louco :)

No seu exemplo, em Bar \ test.bat, DIR / B / S .. \ somefile.txt retornaria o caminho completo.

Atualmente, o PowerShell é bastante comum, então eu o uso frequentemente como uma maneira rápida de invocar o C #, pois ele possui funções para praticamente tudo:

@echo off
set pathToResolve=%~dp0\..\SomeFile.txt
for /f "delims=" %%a in ('powershell -Command "[System.IO.Path]::GetFullPath( '%projectDirMc%' )"') do @set resolvedPath=%%a

echo Resolved path: %resolvedPath%

É um pouco lento, mas é difícil superar a funcionalidade obtida, a menos que seja necessário recorrer a uma linguagem de script real.

A solução da stijn trabalha com subpastas em C:\Program Files (86)\,

@echo off
set projectDirMc=test.txt

for /f "delims=" %%a in ('powershell -Command "[System.IO.Path]::GetFullPath( '%projectDirMc%' )"') do @set resolvedPath=%%a

echo full path:    %resolvedPath%

Arquivos Veja todas as outras respostas

Diretórios

Com ..sendo o seu caminho relativo, e supondo que você está atualmente em D:\Projects\EditorProject:

cd .. & cd & cd EditorProject (o caminho relativo)

retorna caminho absoluto, por exemplo

D:\Projects

SET CD=%~DP0

SET REL_PATH=%CD%..\..\build\

call :ABSOLUTE_PATH    ABS_PATH   %REL_PATH%

ECHO %REL_PATH%

ECHO %ABS_PATH%

pause

exit /b

:ABSOLUTE_PATH

SET %1=%~f2

exit /b