Qual é a diferença entre .text, .value e .value2?

Não estou pedindo ajuda com nenhum script, mas minha pergunta é para esclarecimento. Ultimamente, tenho feito muitos scripts VB no Excel, então estou realmente me referindo ao Excel nesta questão. Qual é a diferença entre .text, .value e .value2? Como quando devo usar target.text, target.value e target.value2? Eu nunca usei a opção value2, mas ainda gostaria de saber para que ela é usada.

Às vezes, se eu uso .text, ocorre um erro e preciso usar .value quando estou apenas verificando ou manipulando o texto em uma célula. Às vezes, quando penso que devo usar .value, recebo um erro e preciso usar .text. Geralmente, ele aceita ou não um problema, mas às vezes faz diferença. Eu sei que tem que haver alguma lógica nisso, mas não consigo entender.

Também descobri que, se você o deixar como destino sem especificar .text ou .value, ele funcionará inicialmente, mas algo que alguém fará eventualmente causará um erro no script, por isso é sempre melhor usar algo. . Acho que o que estou perguntando é se alguém pode me dar algum tipo de orientação, regra geral, sobre como usar adequadamente cada um e quando ele precisa ser usado.

Obrigado pela explicação pessoal. Eu meio que entendo melhor. Ambas são boas explicações. Abaixo está um pequeno exemplo de alguns dos meus códigos que funcionam. Eu pensei que deveria ser target.text, mas seria um erro quando eu usei target.value funcionou.

If LCase(Target.Value) = LCase("HLO") And Target.Column = 15 Then
    Target.Value = "Higher Level Outage"
End If

Ainda estou um pouco confuso porque, quando penso em valor ou valor2, especialmente depois das respostas que você forneceu, acho que elas devem ser usadas apenas para números. No entanto, no meu exemplo, estou falando estritamente de texto, que é muito do que meu script se refere (texto nas células, mais do que números).

.Textfornece uma sequência que representa o que é exibido na tela da célula. Usar .Text geralmente é uma má ideia, pois você pode obter ####

.Value2 fornece o valor subjacente da célula (pode estar vazio, sequência, erro, número (duplo) ou booleano)

.Value fornece o mesmo que .Value2, exceto se a célula foi formatada como moeda ou data, fornece uma moeda VBA (que pode truncar casas decimais) ou uma data VBA.

Usar .Value ou .Text geralmente é uma má ideia, porque você pode não obter o valor real da célula e é mais lento que .Value2

Para uma discussão mais extensa, veja meu Texto x Valor x Valor2

Exceto o formulário de primeira resposta Bathsheba, exceto as informações do MSDN para:

.Value
.Value2
.Text

você pode analisar essas tabelas para entender melhor as diferenças entre as propriedades analisadas.

target.Valuevai te dar um Varianttipo

target.Value2também lhe dará um Varianttipo, mas um Dateé coagido a umDouble

target.Texttenta coagir a um Stringe falhará se o subjacente Variantnão for coercível a um Stringtipo

A coisa mais segura a fazer é algo como

Dim v As Variant
v = target.Value 'but if you don't want to handle date types use Value2

E verifique o tipo da variante usando VBA.VarType(v)antes de tentar uma coerção explícita.

Em relação às convenções em C #. Digamos que você esteja lendo uma célula que contenha uma data, por exemplo, 22/10/2014.

Ao usar:

.Text, você obterá a representação formatada da data, conforme visto na pasta de trabalho na tela:
22/10/2014 . O tipo desta propriedade é sempre, stringmas nem sempre pode retornar um resultado satisfatório.

.Value, o compilador tenta converter a data em um DateTimeobjeto: {2014-10-22 00:00:00} Provavelmente só é útil ao ler datas.

.Value2, fornece o valor real subjacente da célula. No caso de datas, é uma série de datas: 41934 . Esta propriedade pode ter um tipo diferente, dependendo do conteúdo da célula. Para os folhetins de data, o tipo é double.

Portanto, você pode recuperar e armazenar o valor de uma célula em qualquer um deles dynamic, varou objectobserve que o valor sempre terá algum tipo de tipo inato no qual você terá que agir.

dynamic x = ws.get_Range("A1").Value2;
object  y = ws.get_Range("A1").Value2;
var     z = ws.get_Range("A1").Value2;
double  d = ws.get_Range("A1").Value2;      // Value of a serial is always a double

.Text é o valor exibido da célula formatada; .Value é o valor da célula possivelmente aumentado com indicadores de data ou moeda; .Value2 é o valor subjacente bruto retirado de qualquer informação estranha.

range("A1") = Date
range("A1").numberformat = "yyyy-mm-dd"
debug.print range("A1").text
debug.print range("A1").value
debug.print range("A1").value2

'results from Immediate window
2018-06-14
6/14/2018 
43265 

range("A1") = "abc"
range("A1").numberformat = "_(_(_(@"
debug.print range("A1").text
debug.print range("A1").value
debug.print range("A1").value2

'results from Immediate window
   abc
abc
abc

range("A1") = 12
range("A1").numberformat = "0 \m\m"
debug.print range("A1").text
debug.print range("A1").value
debug.print range("A1").value2

'results from Immediate window
12 mm
12
12

Se você estiver processando o valor da célula, a leitura do .Value2 bruto é marginalmente mais rápida que .Value ou .Text. Se você estiver localizando erros, o .Text retornará algo como #N/Atexto e poderá ser comparado a uma string, enquanto .Value e .Value2 serão bloqueados comparando o valor retornado a uma string. Se você tiver alguma formatação de célula personalizada aplicada aos seus dados, o .Text pode ser a melhor opção ao criar um relatório.

Por curiosidade, eu queria ver como é o Valuedesempenho Value2. Após cerca de 12 tentativas de processos semelhantes, não pude ver nenhuma diferença significativa na velocidade, portanto sempre recomendo o uso Value. Usei o código abaixo para executar alguns testes com vários intervalos.

Se alguém vir algo contrário em relação ao desempenho, poste.

Sub Trial_RUN()
    For t = 0 To 5
        TestValueMethod (True)
        TestValueMethod (False)
    Next t

End Sub




Sub TestValueMethod(useValue2 As Boolean)
Dim beginTime As Date, aCell As Range, rngAddress As String, ResultsColumn As Long
ResultsColumn = 5

'have some values in your RngAddress. in my case i put =Rand() in the cells, and then set to values
rngAddress = "A2:A399999" 'I changed this around on my sets.



With ThisWorkbook.Sheets(1)
.Range(rngAddress).Offset(0, 1).ClearContents


beginTime = Now

For Each aCell In .Range(rngAddress).Cells
    If useValue2 Then
        aCell.Offset(0, 1).Value2 = aCell.Value2 + aCell.Offset(-1, 1).Value2
    Else
        aCell.Offset(0, 1).Value = aCell.Value + aCell.Offset(-1, 1).Value
    End If

Next aCell

Dim Answer As String
 If useValue2 Then Answer = " using Value2"

.Cells(Rows.Count, ResultsColumn).End(xlUp).Offset(1, 0) = DateDiff("S", beginTime, Now) & _
            " seconds. For " & .Range(rngAddress).Cells.Count & " cells, at " & Now & Answer


End With


End Sub