atalho para criar um mapa de uma lista no groovy?

Eu gostaria de algum tipo de mão para isso:

Map rowToMap(row) {
    def rowMap = [:];
    row.columns.each{ rowMap[it.name] = it.val }
    return rowMap;
}

dada a forma como as coisas do GDK são, espero ser capaz de fazer algo como:

Map rowToMap(row) {
    row.columns.collectMap{ [it.name,it.val] }
}

mas eu não vi nada nos documentos ... estou faltando alguma coisa? ou eu sou apenas preguiçoso?

Recentemente, descobri a necessidade de fazer exatamente isso: converter uma lista em um mapa. Esta questão foi postada antes do lançamento da versão 1.7.9 do Groovy, então o método collectEntriesainda não existia. Funciona exatamente como o collectMapmétodo proposto :

Map rowToMap(row) {
    row.columns.collectEntries{[it.name, it.val]}
}

Se por algum motivo você ficar preso a uma versão mais antiga do Groovy, o injectmétodo também pode ser usado (conforme proposto aqui ). Esta é uma versão ligeiramente modificada que leva apenas uma expressão dentro do encerramento (apenas para salvar caracteres!):

Map rowToMap(row) {
    row.columns.inject([:]) {map, col -> map << [(col.name): col.val]}
}

O +operador também pode ser usado no lugar do <<.

Confira "injetar". Os verdadeiros especialistas em programação funcional chamam isso de "dobrar".

columns.inject([:]) { memo, entry ->
    memo[entry.name] = entry.val
    return memo
}

E, enquanto você está nisso, provavelmente deseja definir métodos como categorias em vez de diretamente na metaClasse. Dessa forma, você pode defini-lo uma vez para todas as coleções:

class PropertyMapCategory {
    static Map mapProperty(Collection c, String keyParam, String valParam) {
        return c.inject([:]) { memo, entry ->
            memo[entry[keyParam]] = entry[valParam]
            return memo
        }
    }
}

Exemplo de uso:

use(PropertyMapCategory) {
    println columns.mapProperty('name', 'val')
}

O método groupBy não estava disponível quando esta pergunta foi feita?

Se você precisa de um par de valores-chave simples, o método collectEntriesdeve ser suficiente. Por exemplo

def names = ['Foo', 'Bar']
def firstAlphabetVsName = names.collectEntries {[it.charAt(0), it]} // [F:Foo, B:Bar]

Mas se você quiser uma estrutura semelhante a um multimapa, na qual existem vários valores por chave, você deve usar o groupBymétodo

def names = ['Foo', 'Bar', 'Fooey']
def firstAlphabetVsNames = names.groupBy { it.charAt(0) } // [F:[Foo, Fooey], B:[Bar]]

Além disso, se você usa coleções do Google ( http://code.google.com/p/google-collections/ ), pode fazer algo assim:

  map = Maps.uniqueIndex(list, Functions.identity());

ok ... brinquei um pouco mais com isso e acho que é um método bem legal ...

def collectMap = {Closure callback->
    def map = [:]
    delegate.each {
        def r = callback.call(it)
        map[r[0]] = r[1]
    }
    return map
}
ExpandoMetaClass.enableGlobally()
Collection.metaClass.collectMap = collectMap
Map.metaClass.collectMap = collectMap

agora qualquer subclasse de Mapa ou Coleção tem este método ...

aqui eu uso para reverter a chave / valor em um mapa

[1:2, 3:4].collectMap{[it.value, it.key]} == [2:1, 4:3]

e aqui eu uso para criar um mapa a partir de uma lista

[1,2].collectMap{[it,it]} == [1:1, 2:2]

agora eu apenas coloco isso em uma classe que é chamada quando meu aplicativo está iniciando e esse método está disponível em todo o meu código.

EDITAR:

para adicionar o método a todos os arrays ...

Object[].metaClass.collectMap = collectMap

Não consigo encontrar nada integrado ... mas usando ExpandoMetaClass posso fazer isso:

ArrayList.metaClass.collectMap = {Closure callback->
    def map = [:]
    delegate.each {
        def r = callback.call(it)
        map[r[0]] = r[1]
    }
    return map
}

isso adiciona o método collectMap a todos os ArrayLists ... Não tenho certeza por que adicioná-lo a List ou Collection não funcionou. Acho que é outra questão ... mas agora posso fazer isso ...

assert ["foo":"oof", "42":"24", "bar":"rab"] ==
            ["foo", "42", "bar"].collectMap { return [it, it.reverse()] }

da lista ao mapa calculado com um fechamento ... exatamente o que eu estava procurando.

Editar: o motivo pelo qual não consegui adicionar o método às interfaces Lista e Coleção foi porque não fiz isso:

List.metaClass.enableGlobally()

após essa chamada de método, você pode adicionar métodos a interfaces .. o que, neste caso, significa que meu método collectMap funcionará em intervalos como este:

(0..2).collectMap{[it, it*2]}

que produz o mapa: [0: 0, 1: 2, 2: 4]

Que tal algo assim?

// setup
class Pair { 
    String k; 
    String v; 
    public Pair(def k, def v) { this.k = k ; this.v = v; }
}
def list = [ new Pair('a', 'b'), new Pair('c', 'd') ]

// the idea
def map = [:]
list.each{ it -> map.putAt(it.k, it.v) }

// verify
println map['c']