Eu adicionei notepad++.exe ao meu caminho no ambiente variáveis.

Agora, no prompt de comando, notepad++.exe filename.txtabre o arquivo filename.txt. Mas eu quero fazer apenas np filename.txtpara abrir o arquivo.

Eu tentei usar DOSKEY np=notepad++. Mas ele está apenas trazendo à tona um bloco de notas já aberto ++ sem abrir o arquivo. Como faço para abrir o arquivo?

Obrigado.

Para adicionar à resposta de Josh,

você pode tornar os alias persistentes com as seguintes etapas,

1. Crie um arquivo .bat ou .cmd com seus DOSKEYcomandos.
2. Execute o regedit e vá para HKEY_CURRENT_USER\Software\Microsoft\Command Processor

3. Adicione a entrada Valor da string com o nome AutoRune o caminho completo do seu arquivo .bat / .cmd.

   Por exemplo, %USERPROFILE%\alias.cmdsubstituir o segmento inicial do caminho por %USERPROFILE%é útil para sincronizar entre várias máquinas.

Dessa forma, toda vez que o cmd é executado, os aliases são carregados.

No Windows 10 , adicione a entrada em HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Command Processorvez disso.

Para completar, aqui está um modelo para ilustrar o tipo de alias que pode ser útil.

@echo off

:: Temporary system path at cmd startup

set PATH=%PATH%;"C:\Program Files\Sublime Text 2\"

:: Add to path by command

DOSKEY add_python26=set PATH=%PATH%;"C:\Python26\"
DOSKEY add_python33=set PATH=%PATH%;"C:\Python33\"

:: Commands

DOSKEY ls=dir /B
DOSKEY sublime=sublime_text $*  
    ::sublime_text.exe is name of the executable. By adding a temporary entry to system path, we don't have to write the whole directory anymore.
DOSKEY gsp="C:\Program Files (x86)\Sketchpad5\GSP505en.exe"
DOSKEY alias=notepad %USERPROFILE%\Dropbox\alias.cmd

:: Common directories

DOSKEY dropbox=cd "%USERPROFILE%\Dropbox\$*"
DOSKEY research=cd %USERPROFILE%\Dropbox\Research\

• Observe que a $*sintaxe funciona após uma sequência de diretórios e um executável que recebe argumentos. Portanto, no exemplo acima, o comando definido pelo usuário dropbox researchaponta para o mesmo diretório que research.
• Como Rivenfall apontou, é uma boa ideia incluir um comando que permita a edição conveniente do alias.cmdarquivo. Veja aliasacima. Se você estiver em uma sessão do cmd, insira cmdpara reiniciar o cmd e recarregar o alias.cmdarquivo.

Quando procurei na Internet por uma resposta para a pergunta, de alguma forma as discussões foram focadas apenas na persistência ou apenas em algum uso do DOSKEY. Espero que alguém se beneficie desses dois aspectos aqui juntos!

Aqui está um .regarquivo para ajudá-lo a instalar o alias.cmd. Está definido agora como um exemplo para uma pasta da caixa de depósito, conforme sugerido acima.

Windows Registry Editor Version 5.00

[HKEY_CURRENT_USER\Software\Microsoft\Command Processor]
"AutoRun"="%USERPROFILE%\\alias.cmd"

Para aplicativos de usuário único, o que foi feito acima. No entanto, há situações em que é necessário verificar se alias.cmdexiste primeiro na chave do Registro. Veja o exemplo abaixo.

Em um C:\Users\Public\init.cmdarquivo que hospeda configurações potencialmente entre usuários:

@ECHO OFF
REM Add other configurations as needed
IF EXIST "%USERPROFILE%\alias.cmd" ( CALL "%USERPROFILE%\alias.cmd" )

A chave do registro deve ser atualizada correspondentemente a C:\Users\Public\init.cmdou, usando o .regarquivo:

Windows Registry Editor Version 5.00

[HKEY_CURRENT_USER\Software\Microsoft\Command Processor]
"AutoRun"="C:\\Users\\Public\\init.cmd"

Você precisa passar os parâmetros, tente o seguinte:

doskey np=notepad++.exe $*

Editar (respondendo ao comentário de Romonov) P: Existe alguma maneira de lembrar o prompt de comando para que eu não precise executar isso toda vez que abrir um novo prompt de comando?

doskey é um comando textual que é interpretado pelo processador de comando (por exemplo, cmd.exe), ele não pode saber modificar o estado em outro processo (especialmente um que ainda não foi iniciado).

As pessoas que usam doskeypara configurar seus ambientes iniciais do shell de comando geralmente usam o/K opção (geralmente por meio de um atalho) para executar um arquivo em lotes que executa toda a configuração comum (como o título da janela, as cores, etc.).

cmd.exe /K env.cmd

env.cmd:

title "Foo Bar"
doskey np=notepad++.exe $*
...

Se você deseja apenas alguns comandos simples, siga estas etapas:

1. Crie uma pasta chamada C: \ Aliases
2. Adicione C: \ Aliases ao seu caminho (para que todos os arquivos sejam encontrados sempre)
3. Crie um arquivo .bat em C: \ Aliases para cada um dos aliases que você deseja

Talvez exagere, mas diferente da resposta (de outra forma excelente) do @Argyll, isso resolve o problema desse carregamento todas as vezes.

Por exemplo, eu tenho um arquivo chamado dig2.bat com o seguinte:

@echo off
echo.
dig +noall +answer %1

Seu arquivo np teria apenas o seguinte:

@echo off
echo.
notepad++.exe %1

Em seguida, basta adicionar a pasta C: \ Aliases à sua variável de ambiente PATH. Se você já tiver o CMD ou o PowerShell aberto, precisará reiniciá-lo.

FWIW, tenho cerca de 20 aliases (arquivos .bat separados) no meu diretório C: \ Aliases - apenas crio novos conforme necessário. Talvez não seja o mais elegante, mas funciona bem.

ATUALIZAÇÃO : Por uma excelente sugestão do usuário @Mav, é ainda melhor usar % * em vez de % 1 , para que você possa passar vários arquivos para o comando, por exemplo:

@echo off
echo.
notepad++.exe %*

Dessa forma, você poderia fazer o seguinte:

np c:\temp\abc.txt c:\temp\def.txt c:\temp\ghi.txt

e abrirá todos os 3 arquivos.

Como alternativa, você pode usar o cmderque permite adicionar aliases como o linux:

alias subl="C:\Program Files\Sublime Text 3\subl.exe" $*

Dado que você adicionou o notepad ++. Exe à sua variável PATH, é extremamente simples. Crie um arquivo na pasta System32 chamado np.batcom o seguinte código:

@echo off
call notepad++.exe %*

Os %*passes ao longo de todos os argumentos que você dá o npcomando para o notepad++.execomando.

EDIT: Você precisará de acesso de administrador para salvar arquivos na pasta System32, que foi um pouco instável para mim. Acabei de criar o arquivo em outro lugar e o mudei para o System32 manualmente.

Além disso, você pode criar um alias.cmd no seu caminho (por exemplo, C: \ Windows) com o comando

@echo %2 %3 %4 %5 %6 > %windir%\%1.cmd

Depois de fazer isso, você pode fazer algo assim:

alias nameOfYourAlias commands to run 

E depois disso, você pode digitar linha comman

nameOfYourAlias 

isto irá executar

commands to run 

MAS a melhor maneira para mim é apenas adicionar o caminho de um programa.

setx PATH "%PATH%;%ProgramFiles%\Sublime Text 3" /M 

E agora eu corro sublime como

subl index.html

Aliases do console no Windows 10

Para definir um alias do console, use Doskey.exepara criar uma macro ou use a AddConsoleAliasfunção

doskey

doskey test=cd \a_very_long_path\test

Para também passar parâmetros, adicione $*no final:doskey short=longname $*

AddConsoleAlias

AddConsoleAlias( TEXT("test"), 
                 TEXT("cd \\<a_very_long_path>\\test"), 
                 TEXT("cmd.exe"));

Mais informações aqui Aliases do console , Doskey , Parâmetros

Você deseja criar um alias simplesmente digitando:

c:\>alias kgs kubectl get svc

Created alias for kgs=kubectl get svc

E use o alias da seguinte maneira:

c:\>kgs alfresco-svc

NAME           TYPE        CLUSTER-IP     EXTERNAL-IP   PORT(S)   AGE
alfresco-svc   ClusterIP   10.7.249.219   <none>        80/TCP    8d

Basta adicionar o seguinte alias.batarquivo ao seu caminho. Ele simplesmente cria arquivos em lote adicionais no mesmo diretório que ele.

  @echo off
  echo.
  for /f "tokens=1,* delims= " %%a in ("%*") do set ALL_BUT_FIRST=%%b
  echo @echo off > C:\Development\alias-script\%1.bat
  echo echo. >> C:\Development\alias-script\%1.bat
  echo %ALL_BUT_FIRST% %%* >> C:\Development\alias-script\%1.bat
  echo Created alias for %1=%ALL_BUT_FIRST%

Um exemplo do arquivo em lotes que ele criou chamado kgs.baté:

@echo off 
echo. 
kubectl get svc %* 

Na verdade, eu vou te mostrar um pouco melhor e mostrar uma pequena técnica que usei desde que costumava programar em um Amiga. Em qualquer novo sistema usado, pessoal ou profissional, a primeira etapa é criar duas pastas: C:\BINe C:\BATCH. Em seguida, modifique sua declaração de caminho para colocar ambos no início na ordemC:\BATCH;C:\BIN;[rest of path] .

Feito isso, se você tiver pouco utilitários fora do caminho que precisa acessar, basta copiá-los para a C:\BINpasta e eles estarão no seu caminho. Para substituir temporariamente essas atribuições, você pode adicionar um arquivo em lotes com o mesmo nome que o executável ao arquivoC:\BATCH pasta e o caminho o encontrará antes do arquivo em C: \ BIN. Deve abranger qualquer coisa que você possa precisar fazer.

É claro que hoje em dia a maneira correta canônica de fazer isso seria criar uma junção simbólica no arquivo, mas o mesmo princípio se aplica. Também há um pequeno bônus extra. Se você deseja colocar algo no sistema que entre em conflito com algo que já está no caminho, colocá-lo na pasta C:\BINou C:\Batchsimplesmente antecipará o original - permitindo que você substitua temporariamente ou permanentemente ou renomeie as coisas para nomes mais confortável com - sem realmente alterar o original.

Expandindo em roryhewitt resposta .

Uma vantagem do uso de arquivos .cmd sobre o DOSKEY é que esses "aliases" estão disponíveis em outros shells, como o PowerShell ou o WSL (subsistema Windows para Linux).

O único problema com o uso desses comandos no bash é que pode demorar um pouco mais de configuração, pois você pode precisar fazer alguma manipulação de caminho antes de chamar seu "alias".

por exemplo, tenho vs.cmd, que é o meu "alias" para editar um arquivo no Visual Studio

@echo off
if [%1]==[] goto nofiles
start "" "c:\Program Files (x86)\Microsoft Visual Studio 
11.0\Common7\IDE\devenv.exe" /edit %1
goto end
:nofiles
start "" "C:\Program Files (x86)\Microsoft Visual Studio 
11.0\Common7\IDE\devenv.exe" "[PATH TO MY NORMAL SLN]"
:end

Que aciona o VS (neste caso, o VS2012 - mas ajuste a gosto) usando o meu projeto "normal" sem nenhum arquivo fornecido, mas, quando fornecido, o arquivo tentará se conectar a um VS em execução que abre o arquivo "dentro desse projeto" em vez de iniciar um nova instância do VS.

Para usar isso no bash, adiciono um nível extra de indireção, já que "vs Myfile" nem sempre funciona

alias vs='/usr/bin/run_visual_studio.sh'

Que ajusta os caminhos antes de chamar o vscmd

#!/bin/bash
cmd.exe /C 'c:\Windows\System32\vs.cmd' "`wslpath.sh -w -r $1`"

Então dessa maneira eu posso fazer

vs SomeFile.txt

Em um prompt de comando, no Power Shell ou no bash, ele é aberto no Visual Studio em execução para edição (o que evita que meu cérebro ruim tenha que lidar com comandos do VI ou algo parecido quando eu estiver editando no VS por horas).

Esta solução não é adequada, mas serve a propósitos em algumas ocasiões.

Primeiro, crie uma pasta e adicione-a ao caminho do sistema. Vá para o executável de qualquer programa para o qual você deseja criar um alias. Clique com o botão direito e envie para a área de trabalho (Criar atalho). Renomeie o atalho para qualquer nome alternativo que seja confortável. Agora, pegue o atalho e coloque na sua pasta.

No prompt de execução, você pode digitar o nome do atalho diretamente e abrir o programa para você. Mas, no prompt de comando, você precisa anexar .lnk e pressionar enter, o programa será aberto.

Naturalmente, eu não descansaria até ter a solução mais conveniente de todas. Combinando as muitas respostas e tópicos da vasta Internet, eis o que você pode ter.

• Carrega automaticamente com todas as instâncias de cmd
• Não requer palavra DOSKEY- chave para aliases

Observe que isso se baseia amplamente na resposta e nos comentários de Argyll ; leia-o definitivamente para entender os conceitos.

Como funciona?

1) crie um arquivo macro com aliases (ou um arquivo bat / cmd para também executar outras coisas)
2) registre-o no Registro para executar em cada instância do cmd
  - você também pode executá-lo via atalho apenas se desejar

Isso é tudo

;==============================================================================
;= This file is registered via registry to auto load with each instance of cmd.
;================================ general info ================================
;= https://stackoverflow.com/a/59978163/985454  -  how to set it up?
;= https://gist.github.com/postcog/5c8c13f7f66330b493b8  -  example doskey macrofile
;========================= loading with cmd shortcut ==========================
;= create a cmd link with the following target :
;= %comspec% /k "(doskey /macrofile=%userprofile%\cmd\aliases.mac)"

alias=subl %USERPROFILE%\cmd\aliases.mac
hosts=runas /noprofile /savecred /user:QWERTY-XPS9370\administrator "subl C:\Windows\System32\drivers\etc\hosts" > NUL

ls=ls --color=auto $*
ll=ls -l --color=auto $*
la=ls -la --color=auto $*
grep=grep --color

~=cd %USERPROFILE%
cdr=cd c:\repos
cdd=cd c:\repos\dixons
cds=cd c:\repos\stekkie
cdu=cd c:\repos\uplus
cduo=cd c:\repos\uplus\oxbridge-fe
cdus=cd c:\repos\uplus\stratus

;============================= :end ============================
;= rem ******************************************************************
;= rem * EOF - Don't remove the following line.  It clears out the ';'
;= rem * macro. We're using it because there is no support for comments
;= rem * in a DOSKEY macro file.
;= rem ******************************************************************
;=

Agora você tem duas opções:
a) registre apenas o macrofile
b) use um cmd/batarquivo comum para executar também comandos arbitrários
Renomeie o que você deseja Autorun.

  Autorun    REG_SZ    doskey /macrofile=%userprofile%\cmd\aliases.mac
  Autorun_    REG_SZ    %USERPROFILE%\cmd\env.cmd

Windows Registry Editor Version 5.00
[HKEY_CURRENT_USER\Software\Microsoft\Command Processor]
"Autorun"="doskey /macrofile=%userprofile%\\cmd\\aliases.mac"
"Autorun_"="%USERPROFILE%\\cmd\\env.cmd"

:: This file is registered via registry to auto load with each instance of cmd.
:: https://stackoverflow.com/a/59978163/985454

@echo off
doskey /macrofile=%userprofile%\cmd\aliases.mac

:: put other commands here

Desde que você já tem notepad++.exeno seu caminho. Crie um atalho nessa pasta chamada npe aponte-o para notepad++.exe.

Primeiro, você pode criar um arquivo chamado np.cmd e colocá-lo na pasta que está na lista de pesquisa PATH. Em seguida, edite o arquivo np.cmd como abaixo:

@echo off
notepad++.exe

Se você deseja ativar aliases por diretório / por projeto , tente o seguinte:

1. Primeiro, crie um arquivo em lotes que procurará um arquivo nomeado aliasesno diretório atual e inicialize aliases a partir dele, vamos chamá-lomake-aliases.cmd

   @echo off
   if not exist aliases goto:eof
   echo [Loading aliases...]
   for /f "tokens=1* delims=^=" %%i in (aliases) do (
      echo   %%i ^<^=^> %%j
      doskey %%i=%%j
   )
   doskey aliases=doskey /macros
   echo   --------------------
   echo   aliases ^=^> list  all
   echo   alt+F10 ^=^> clear all
   echo [Done]
   

2. Em seguida, crie aliasessempre que precisar, usando o seguinte formato:

   alias1 = command1
   alias2 = command2
   ...
   

   por exemplo:

   b = nmake
   c = nmake clean
   r = nmake rebuild
   

3. Em seguida, adicione o local da make-aliases.cmdsua %PATH%variável para torná-la em todo o sistema ou apenas mantê-la em um local conhecido.

4. Faça começar automaticamente com cmd.

   • Eu recomendaria definitivamente não usar HKEY_CURRENT_USER\Software\Microsoft\Command Processor\AutoRunisso, porque algumas ferramentas de desenvolvimento acionariam o script de execução automática várias vezes por sessão.

   • Se você usar ConEmu você poderia ir uma outra maneira e iniciar o script da tarefa de inicialização ( Settings> Startup> Tasks), por exemplo, eu criei uma entrada chamada {MSVC}:

     cmd.exe /k "vcvars64 && make-aliases",

     e, em seguida, registrei-o no menu de contexto do Explorer via Settings> Integration>com Command: {MSVC} -cur_console:n, para que agora eu possa clicar com o botão direito do mouse em uma pasta e iniciar um prompt de desenvolvedor do VS dentro dele com o meu aliasescarregado automaticamente, se eles estiverem nessa pasta.

     Sem o ConEmu, você pode apenas criar um atalho para cmd.exeo comando correspondente ou simplesmente executar make-aliasesmanualmente todas as vezes.

Caso você esqueça seus aliases, use a aliasesmacro e, se algo der errado, basta redefinir a sessão atual pressionando Alt+ F10, que é um comando interno do cmd.

O uso do doskey é a maneira correta de fazer isso, mas é redefinido quando a janela do prompt de comando é fechada. Você precisa adicionar essa linha a algo como .bashrc equivalente. Então eu fiz o seguinte:

1. Adicione "C: \ Arquivos de Programas (x86) \ Notepad ++" à variável de caminho do sistema
2. Faça uma cópia do bloco de notas ++. Exe (na mesma pasta, é claro) e renomeie-o para np.exe

Funciona muito bem!