Em uma planilha do Google: como posso contar as linhas de uma determinada área que possuem um valor? Todas as dicas que encontrei até agora levam a fórmulas que contam as linhas que possuem um conteúdo não vazio (incluindo a fórmula), mas uma célula com

=IF(1=2;"";"")  // Shows an empty cell

também é contado.

Qual é a solução para esta tarefa simples?

Faça outra coluna que determine se a célula referenciada está em branco usando a função "CountBlank". Em seguida, use count nos valores criados na nova coluna "CountBlank".

Acabei de usar =COUNTIF(Range, "<>")e contava células não vazias para mim.

=counta(range) 

• counta: "Retorna uma contagem do número de valores em um conjunto de dados"

  Nota: CountAconsidera ""ser um valor . Somente as células que estão em branco (pressione excluir em uma célula para esvaziá-la) não são contadas.

  Suporte do Google: https://support.google.com/docs/answer/3093991

• countblank: "Retorna o número de células vazias em um determinado intervalo"

  Nota: CountBlankconsidera as células em branco (pressione delete para apagar uma célula) e as células que possuem uma fórmula que retorna ""como células vazias .

  Suporte do Google: https://support.google.com/docs/answer/3093403

Se você possui um intervalo que inclui fórmulas que resultam em "", você pode modificar sua fórmula de

=counta(range)

para:

=Counta(range) - Countblank(range)

EDIT: a função é countblank, não countblanks, o último dará um erro.

Aqui está o que eu acredito ser a melhor solução até agora:

=CountIf(ArrayFormula(range<>""),TRUE)

Aqui está o porquê em 3 etapas fáceis

Etapa 1: Simples como torta - Adicionar coluna extra

A resposta do eniacAvenger produzirá a solução correta sem se preocupar com casos extremos , pois =A1<>""parece chegar ao valor correto de verdade / falsidade com base em como pensamos intuitivamente em células em branco, espaços em branco virgens ou espaços em branco criados.

Imagine que temos esses dados e queremos o Count of non-blank em B2:B6:

|   |      A      |   B   |    C    |
|---|-------------|-------|---------|
| 1 | Description | Value | B1<>""  |
| 2 | Text        | H     | TRUE    |
| 3 | Number      | 1     | TRUE    |
| 4 | IF -> ""    |       | FALSE   |
| 5 | IF -> Text  | h     | TRUE    |
| 6 | Blank       |       | FALSE   |

Se confiarmos na coluna C , poderíamos obter a contagem de valores em B assim:

=COUNTIF(C2:C6,True)

Etapa 2: use FormulaArraypara criar dinamicamente coluna extra

No entanto, o comentário de consideRatio é válido - se você precisar de uma coluna extra, geralmente poderá atingir o mesmo objetivo com o ArrayFormulaqual poderá criar uma coluna na memória sem ocupar espaço na folha.

Portanto, se queremos criar C dinamicamente, podemos usar uma fórmula de matriz como esta:

=ArrayFormula(B2:B6<>"")

Se simplesmente o colocarmos em C2, ele criaria a matriz vertical com um único toque da caneta:

|   |      A      |   B   |    C                     |
|---|-------------|-------|--------------------------|
| 1 | Description | Value | =ArrayFormula(B2:B6<>"") |
| 2 | Text        | H     | TRUE                     |
| 3 | Number      | 1     | TRUE                     |
| 4 | IF -> ""    |       | FALSE                    |
| 5 | IF -> Text  | h     | TRUE                     |
| 6 | Blank       |       | FALSE                    |

Etapa 3: contar valores na coluna dinâmica

Mas com isso resolvido, não precisamos mais da coluna para exibir apenas os valores.

ArrayFormulavai resolver para o seguinte intervalo: {True,True,False,True,False}.
CountIfapenas aceita qualquer intervalo e, neste caso, pode contar o número de valores True.

Portanto, podemos envolver CountIfos valores produzidos ArrayFormuladesta maneira:

=CountIf(ArrayFormula(B2:B6<>""),TRUE)

Leitura adicional

As outras soluções neste segmento são muito complexas ou falham em casos extremos que eu enumerei nesta folha de teste:

Planilha do Google - Teste CountA - Demo

Por que CountAfunciona da maneira vacilante, veja minha resposta aqui

Para mim, nenhuma das respostas funcionou para intervalos que incluem células virgens e células vazias com base em uma fórmula (por exemplo =IF(1=2;"";""))

O que resolveu para mim é isso:

=COUNTA(FILTER(range, range <> ""))

Resolvido usando uma solução que encontrei no Google por Yogi Anand: https://productforums.google.com/d/msg/docs/3qsR2m-1Xx8/sSU6Z6NYLOcJ

O exemplo abaixo conta o número de linhas não vazias no intervalo A3: C, lembre-se de atualizar os dois intervalos na fórmula com seu intervalo de interesse.

=ArrayFormula(SUM(SIGN(MMULT(LEN(A3:C), TRANSPOSE(SIGN(COLUMN(A3:C)))))))

Além disso, evite dependências circulares, isso acontecerá se, por exemplo, você contar o número de linhas não vazias em A: C e colocar essa fórmula na coluna A ou C.

É trabalho para mim:

=SUMPRODUCT(NOT(ISBLANK(F2:F)))

Contagem de todas as células não vazias de F2 até o final da coluna

Dado o intervalo A:A, eu sugiro:

=COUNTA(A:A)-(COUNTIF(A:A,"*")-COUNTIF(A:A,"?*"))

O problema é a contagem excessiva de COUNTA pelo número exato de células com cadeias de comprimento zero "" .

A solução é encontrar uma contagem exata dessas células. Isso pode ser encontrado procurando todas as células de texto e subtraindo todas as células de texto com pelo menos um caractere

• COUNTA (A: A): células com valor, incluindo "" mas excluindo células realmente vazias
• COUNTIF (A: A, "*"): células reconhecidas como texto, incluindo ""mas excluindo células realmente em branco
• COUNTIF (A: A, "? *"): Células reconhecidas como texto com pelo menos um caractere

Isso significa que o valor COUNTIF(A:A,"*")-COUNTIF(A:A,"?*")deve ser o número de células de texto menos o número de células de texto que possuem pelo menos um caractere, ou seja, a contagem de células contendo exatamente""

Uma solução mais simples que funciona para mim:

=COUNTIFS(A:A;"<>"&"")

Conta números, seqüências de caracteres, datas, etc. que não estão vazios

Tanto quanto posso ver, a maioria das soluções aqui conta o número de células não vazias, e não o número de linhas com células não vazias dentro.

Uma solução possível para a linha B3:E29é, por exemplo

=SUM(ArrayFormula(IF(B3:B29&C3:C29&D3:D29&E3:E29="";0;1)))

Aqui ArrayFormula(IF(B3:B29&C3:C29&D3:D29&E3:E29="";0;1))retorna uma coluna de 0(se a linha estiver vazia) e 1(mais).

Outro é dado na resposta de consideRatio .

Você pode definir uma função personalizada usando o Apps Apps (Ferramentas> Editor de scripts) chamado por exemplo numNonEmptyRows:

function numNonEmptyRows(range) {
  Logger.log("inside");
  Logger.log(range);
  if (range && range.constructor === Array) {
    return range.map(function(a){return a.join('')}).filter(Boolean).length
  }
  else {
    return range ? 1 : 0;
  }
}

E depois use-o em uma célula como esta =numNonEmptyRows(A23:C25)para contar o número de linhas não vazias no intervalo A23:C25;

No Planilhas Google, para contar o número de linhas que contêm pelo menos uma célula não vazia em um intervalo bidimensional :

=ARRAYFORMULA(
  SUM(
    N(
      MMULT(
        N(A1:C5<>""),
        TRANSPOSE(COLUMN(A1:C5)^0)
      )
      >0
    )
  )
)

Onde A1: C5 é o intervalo que você está verificando quanto a linhas não vazias.

A fórmula vem e é explicada no seguinte artigo da EXCELXOR - https://excelxor.com/2015/03/30/counting-rows-where-at-least-one-condition-is-met/

Uma maneira muito flexível de fazer esse tipo de coisa é usar o ARRAYFORMULA.

Como um exemplo, imagine que você deseja contar cadeias não vazias (campos de texto), você pode usar este código:

=ARRAYFORMULA(SUM(IF(Len(B3:B14)>0, 1, 0)))

O que acontece aqui é que "ArrayFormula" permite operar sobre um conjunto de valores. Usando a função SUM, você indica "ArrayFormula" para somar qualquer valor do conjunto. A cláusula "If" é usada apenas para verificar "vazio" ou "não vazio", 1 para não vazio e 0 caso contrário. "Len" retorna o comprimento dos diferentes campos de texto; é aí que você define o conjunto (intervalo) que deseja verificar. Finalmente, "ArrayFormula" somará 1 para cada campo dentro do conjunto (intervalo) no qual "len" retorna mais que 0.

Se você deseja verificar qualquer outra condição, basta modificar o primeiro argumento da cláusula IF.