Como colar sem sobrescrever o registro

Alguém conhece uma maneira de colar sobre uma área selecionada visualmente sem ter a seleção colocada no registro padrão?

Eu sei que posso resolver o problema sempre colando de um registro explícito. Mas é uma dor de cabeça digitar em "xpvez de apenasp

"{register}pnão funcionará como você descreve. Substituirá a seleção pelo conteúdo do cadastro. Em vez disso, você terá que fazer algo como:

" I haven't found how to hide this function (yet)
function! RestoreRegister()
  let @" = s:restore_reg
  return ''
endfunction

function! s:Repl()
    let s:restore_reg = @"
    return "p@=RestoreRegister()\<cr>"
endfunction

" NB: this supports "rp that replaces the selection by the contents of @r
vnoremap <silent> <expr> p <sid>Repl()

O que deve funcionar, contanto que você não use um plugin que tenha um vmap não nore para p, e que espere que um registro seja sobrescrito.

Este código está disponível como um script lá . Ingo Karkat também definiu um plugin para resolver o mesmo problema.

Eu não gosto do comportamento vim padrão de copiar todo o texto eliminado com d, D, cou Cpara o registro padrão.

Eu resolvi isso mapeando dpara "_d, cpara "_ce assim por diante.

Do meu .vimrc:

"These are to cancel the default behavior of d, D, c, C
"  to put the text they delete in the default register.
"  Note that this means e.g. "ad won't copy the text into
"  register a anymore.  You have to explicitly yank it.
nnoremap d "_d
vnoremap d "_d
nnoremap D "_D
vnoremap D "_D
nnoremap c "_c
vnoremap c "_c
nnoremap C "_C
vnoremap C "_C

Use o seguinte:

xnoremap p pgvy

isso selecionará novamente e puxará novamente qualquer texto colado no modo visual.

Editar: para que isso funcione, "xpvocê pode fazer:

xnoremap p pgv"@=v:register.'y'<cr>

v:register expande para o último nome de registro usado em um comando de modo normal.

Na tua .vimrc

xnoremap p "_dP

Eu encontrei isso em uma resposta em um tópico semelhante, mas a fonte original era http://vim.wikia.com/wiki/Replace_a_word_with_yanked_text . Ele menciona algumas desvantagens, mas funciona bem para mim.

A solução de Luc Hermitte funciona perfeitamente. Eu estava usando por cerca de uma semana ou assim. Então descobri uma solução do .vimrc de Steve Losh que funciona muito bem se o YankRing fizer parte da sua linha de plug-in / pacote:

function! YRRunAfterMaps()                                                                                                      
    " From Steve Losh, Preserve the yank post selection/put.    
    vnoremap p :<c-u>YRPaste 'p', 'v'<cr>gv:YRYankRange 'v'<cr> 
endfunction  

Experimente isso em seu ~/.vimrc:

xnoremap <expr> p 'pgv"'.v:register.'y'

• xnoremapsignifica que isso é apenas para Visualmodo, não Visual + Selectmodos.

• <expr>significa que {rhs}a xnoremap {lhs} {rhs}configuração é avaliada como uma expressão.

• Nesse caso, nossa expressão de 'pgv"'.v:register.'y'está usando .para concatenação.

• v:register é avaliado para o registro que está sendo usado durante o cumprimento do mapeamento.

O resultado de "xpavaliaria para pgv"xy, onde xestá o registro.

Fui ajudado por uma resposta a esta questão stackoverflow: Vim - mapeamento com um prefixo de registro opcional em conjunto com a resposta de Benoit nesta página

A função de Luc funcionou bem para mim depois que fiz uma alteração para suportar o fato de que tenho a área de transferência = conjunto sem nome:

function! RestoreRegister()
    let @" = s:restore_reg
    if &clipboard == "unnamed"
        let @* = s:restore_reg
    endif
    return ''
endfunction

Luc Hermitte fez o truque! Muito bom. Aqui está sua solução colocada em uma função de alternância, para que você possa alternar entre o comportamento normal e a colocação sem substituição de registro.

o comando, você alterna o comportamento

let s:putSwap = 1 
function TogglePutSwap()
    if s:putSwap
        vnoremap <silent> <expr> p <sid>Repl()
        let s:putSwap = 0 
        echo 'noreplace put'
    else
        vnoremap <silent> <expr> p p 
        let s:putSwap = 1 
        echo 'replace put'
    endif
    return
endfunction
noremap ,p :call TogglePutSwap()<cr>

programação de fita adesiva, mas funciona para mim:

nmap viwp viwpyiw
nmap vi'p vi'pyi'
nmap vi"p vi"pyi"
nmap vi(p vi(pyi(
nmap vi[p vi[pyi[
nmap vi<p vi<pyi<

experimentar -

:set guioptions-=a
:set guioptions-=A