Como definir o tamanho da fonte no Emacs?

Também quero salvar o tamanho da fonte no meu .emacsarquivo.

(set-face-attribute 'default nil :height 100)

O valor está em 1 / 10pt, portanto, 100 fornecerá 10pt etc.

No Emacswiki , o GNU Emacs 23 possui uma combinação de teclas embutida:

C-xC-+e C-xC--para aumentar ou diminuir o tamanho do texto do buffer

Pressione Shift e o primeiro botão do mouse. Você pode alterar o tamanho da fonte da seguinte maneira: Este site tem mais detalhes.

M-x customize-face RET defaultpermitirá que você defina a defaultface, na qual todas as outras faces se baseiam. Lá você pode definir o tamanho da fonte.

Aqui está o que está no meu .emacs. na verdade, o tema de cores definirá o básico, e minha configuração de rosto personalizada substituirá algumas coisas. o custom-set-faces é escrito pelo mecanismo de custom-face do emacs:

;; my colour theme is whateveryouwant :)
(require 'color-theme)
(color-theme-initialize)
(color-theme-whateveryouwant)

(custom-set-faces
  ;; custom-set-faces was added by Custom.
  ;; If you edit it by hand, you could mess it up, so be careful.
  ;; Your init file should contain only one such instance.
  ;; If there is more than one, they won't work right.
 '(default ((t (:stipple nil :background "white" :foreground "black" :inverse-video nil :box nil :strike-through nil :overline nil :underline nil :slant normal :weight normal :height 98 :width normal :foundry "unknown" :family "DejaVu Sans Mono"))))
 '(font-lock-comment-face ((t (:foreground "darkorange4"))))
 '(font-lock-function-name-face ((t (:foreground "navy"))))
 '(font-lock-keyword-face ((t (:foreground "red4"))))
 '(font-lock-type-face ((t (:foreground "black"))))
 '(linum ((t (:inherit shadow :background "gray95"))))
 '(mode-line ((t (nil nil nil nil :background "grey90" (:line-width -1 :color nil :style released-button) "black" :box nil :width condensed :foundry "unknown" :family "DejaVu Sans Mono")))))

Essa é outra solução simples. Funciona em 24 também

(set-default-font "Monaco 14")

Atalhos:

`C-+` increases font size
`C--` Decreases font size

Eu tenho o seguinte no meu .emacs:

(defun fontify-frame (frame)
  (set-frame-parameter frame 'font "Monospace-11"))

;; Fontify current frame
(fontify-frame nil)
;; Fontify any future frames
(push 'fontify-frame after-make-frame-functions) 

Você pode substituir qualquer fonte de sua escolha "Monospace-11". O conjunto de opções disponíveis é altamente dependente do sistema. Usar M-x set-default-fonte observar as conclusões da guia fornecerão algumas idéias. No meu sistema, com o Emacs 23 e anti-aliasing ativado, pode escolher fontes do sistema por nome, por exemplo, Monospace, Sans Serif, etc.

Abra o emacs no X11, vá para o menu Opções, selecione "definir fonte padrão ...", altere o tamanho da fonte. Selecione "salvar opções" no mesmo menu. Feito.

zoom.cfg e global-zoom.cfg fornecem ligações de alteração de tamanho de fonte (no EmacsWiki)

• C-- ou C-mousewheel-up: aumenta o tamanho da fonte.
• C- + ou C-mousewheel-down: diminui o tamanho da fonte.
• C-0 reverte o tamanho da fonte para o padrão.

Aqui está uma opção para redimensionar as alturas das fontes interativamente, um ponto de cada vez:

;; font sizes
(global-set-key (kbd "s-=")
                (lambda ()
                  (interactive)
                  (let ((old-face-attribute (face-attribute 'default :height)))
                    (set-face-attribute 'default nil :height (+ old-face-attribute 10)))))

(global-set-key (kbd "s--")
                (lambda ()
                  (interactive)
                  (let ((old-face-attribute (face-attribute 'default :height)))
                    (set-face-attribute 'default nil :height (- old-face-attribute 10)))))

Isso é preferível quando você deseja redimensionar o texto em todos os buffers. Não gosto de soluções usando text-scale-increasee, text-scale-decreasecomo os números de linha na sarjeta podem ser cortados depois.

O Firefox e outros programas permitem aumentar e diminuir o tamanho da fonte com C- + e C--. Eu configurei meu .emacs para ter a mesma capacidade adicionando estas linhas de código:

(global-set-key [C-kp-add] 'text-scale-increase)

(global-set-key [C-kp-subtract] 'text-scale-decrease)

Aquamacs :

(set-face-attribute 'default nil :font "Monaco-16" )

No Wiki do Emacs, altere globalmente a fonte padrão , ele diz que você pode usar um destes:

(set-face-attribute 'default nil :font FONT )

(set-frame-font FONT nil t)

Onde FONTé algo como "Monaco-16", por exemplo:

(set-face-attribute 'default nil :font "Monaco-16" )

Havia um parêntese de fechamento extra na primeira sugestão no wiki, o que causou um erro na inicialização. Finalmente notei o parêntese de fechamento extra e, posteriormente, corrigi a sugestão no wiki. Então as duas sugestões funcionaram para mim.

Tudo depende do que você quer dizer com alterar o tamanho da fonte. Esta seção do EmacsWiki fornece as melhores e mais completas informações. Distingue os vários casos (escala de texto, fonte do quadro, buffer / quadro, etc.): Alteração do tamanho da fonte .

No NTEmacs 23.1, o menu Opções possui a opção "Definir fonte padrão ...".

Se você está feliz com o console emacs (emacs -nw), as implementações modernas do vterm (como o gnome-terminal) tendem a ter melhor suporte a fontes. Além disso, se você se acostumar com isso, poderá usar o tmux e, assim, trabalhar com seu ambiente completo em servidores remotos se tornará possível, mesmo sem o X.

No AquaMacs CMD +e CMD -ajuste o tamanho da fonte para o buffer atual.

Eu uso o pacote hydra para controlar o aumento / diminuição da fonte pressionando f2 + + + +/ f2 - - - -, o que significa que pressione f2uma vez e depois use +/ -para controlar apenas e restaure o tamanho da fonte padrão f2 0. Como tenho teclado, também vinculo o teclado à configuração da fonte.

(defhydra hydra-zoom (global-map "<f2>")
  "zoom"
  ("<kp-add>" text-scale-increase "in")
  ("+" text-scale-increase "in")
  ("-" text-scale-decrease "out")
  ("<kp-subtract>" text-scale-decrease "out")
  ("0" (text-scale-set 0) "reset")
  ("<kp-0>" (text-scale-set 0) "reset"))

E a funcionalidade moderna de controle do mouse do editor suportada pelas combinações de teclas abaixo, pressione control + roda do mouse para aumentar / diminuir a fonte.

(global-set-key (kbd "<C-wheel-up>") 'text-scale-increase)
(global-set-key (kbd "<C-wheel-down>") 'text-scale-decrease)

Aqui está um trecho que permite especificar diretamente o tamanho da fonte global usando uma função interativa:

(defun set-font-size ()
    "Set the font size."
  (interactive)
  (set-face-attribute
   'default nil :height
   (string-to-number
    (read-string "Font size: " (number-to-string (face-attribute 'default :height nil))))))