Como verificar se um serviço está rodando via arquivo batch e iniciá-lo, caso não esteja rodando?

Quero escrever um arquivo em lote que execute as seguintes operações:

• Verifique se um serviço está em execução
  • Se estiver em execução, saia do lote
  • Se não estiver em execução, inicie o serviço

Os exemplos de código que pesquisei até agora não funcionaram, então decidi não publicá-los.

O início de um serviço é feito por:

net start "SERVICENAME"

1. Como posso verificar se um serviço está sendo executado e como fazer uma instrução if em um batchfile?
2. Estou um pouco confuso. Qual é o argumento que devo passar para o início da rede? O nome do serviço ou seu nome de exibição?

Para verificar o estado de um serviço, use sc query <SERVICE_NAME>. Para se bloqueia em arquivos de lote, verifique a documentação .

O código a seguir verificará o status do serviço MyServiceNamee o iniciará se ele não estiver em execução (o bloco if será executado se o serviço não estiver em execução):

for /F "tokens=3 delims=: " %%H in ('sc query "MyServiceName" ^| findstr "        STATE"') do (
  if /I "%%H" NEQ "RUNNING" (
   REM Put your code you want to execute here
   REM For example, the following line
   net start "MyServiceName"
  )
)

Explicação do que faz:

1. Consulta as propriedades do serviço.
2. Procura a linha que contém o texto "ESTADO"
3. Tokeniza essa linha e extrai o terceiro token, que contém o estado do serviço.
4. Testa o estado resultante em relação à string "RUNNING"

Quanto à sua segunda pergunta, o argumento que você deseja transmitir net starté o nome do serviço, não o nome de exibição.

Para alternar um serviço, use o seguinte;

NET START "Coordenador de transações distribuídas" || NET STOP "Coordenador de transações distribuídas"

Você pode usar o seguinte comando para ver se um serviço está sendo executado ou não:

sc query [ServiceName] | findstr /i "STATE"

Quando eu o executo para meu antivírus NOD32, recebo:

STATE                       : 4 RUNNING

Se fosse interrompido, eu obteria:

STATE                       : 1 STOPPED

Você pode usar isso em uma variável para determinar se você usa NET START ou não.

O nome do serviço deve ser o nome do serviço, não o nome de exibição.

Isso deve resolver:

FOR %%a IN (%Svcs%) DO (SC query %%a | FIND /i "RUNNING"
IF ERRORLEVEL 1 SC start %%a)

Versão independente do idioma.

@Echo Off
Set ServiceName=Jenkins


SC queryex "%ServiceName%"|Find "STATE"|Find /v "RUNNING">Nul&&(
    echo %ServiceName% not running 
    echo Start %ServiceName%

    Net start "%ServiceName%">nul||(
        Echo "%ServiceName%" wont start 
        exit /b 1
    )
    echo "%ServiceName%" started
    exit /b 0
)||(
    echo "%ServiceName%" working
    exit /b 0
)

Acabei de encontrar este tópico e gostaria de acrescentar à discussão se a pessoa não deseja usar um arquivo em lote para reiniciar serviços. No Windows, há uma opção se você acessar Serviços, propriedades do serviço e, em seguida, recuperação. Aqui você pode definir parâmetros para o serviço. Gostaria de reiniciar o serviço se o serviço parar. Além disso, você pode até mesmo fazer com que uma segunda tentativa de falha faça algo diferente, como reiniciar o computador.

Cuando se usar Windows en Español, el código debe quedar asi (ao usar Windows em espanhol, o código é):

for /F "tokens=3 delims=: " %%H in ('sc query MYSERVICE ^| findstr "        ESTADO"') do (
  if /I "%%H" NEQ "RUNNING" (
    REM Put your code you want to execute here
    REM For example, the following line
    net start MYSERVICE
  )
)

Reemplazar MYSERVICE con el nombre del servicio that se desea procesar. Puedes ver el nombre del servicio viendo las propiedades del servicio. (Substitua MYSERVICE pelo nome do serviço a ser processado. Você pode ver o nome do serviço nas propriedades do serviço.)

@echo off

color 1F


@sc query >%COMPUTERNAME%_START.TXT


find /I "AcPrfMgrSvc" %COMPUTERNAME%_START.TXT >nul

IF ERRORLEVEL 0 EXIT

IF ERRORLEVEL 1 NET START "AcPrfMgrSvc"

Para o servidor Windows 2012 abaixo é o que funcionou para mim. Substitua apenas "SERVICENAME" pelo nome do serviço real:

@ECHO OFF
SET SvcName=SERVICENAME

SC QUERYEX "%SvcName%" | FIND "STATE" | FIND /v "RUNNING" > NUL && (
    ECHO %SvcName% is not running 
    ECHO START %SvcName%

    NET START "%SvcName%" > NUL || (
        ECHO "%SvcName%" wont start 
        EXIT /B 1
    )
    ECHO "%SvcName%" is started
    EXIT /B 0
) || (
    ECHO "%SvcName%" is running
    EXIT /B 0
)

Eu também queria que um e-mail fosse enviado se o serviço fosse iniciado dessa forma, então adicionei um pouco ao código @Ic apenas pensei em postá-lo caso ajudasse alguém. Eu usei SendMail, mas existem outras opções de linha de comando. Como enviar um e-mail simples de um arquivo de lote do Windows?

set service=MyServiceName

for /F "tokens=3 delims=: " %%H in ('sc query %service% ^| findstr "        STATE"') do (
  if /I "%%H" NEQ "RUNNING" (

    net start %service%

    for /F "tokens=3 delims=: " %%H in ('sc query %service% ^| findstr "        STATE"') do (
      if /I "%%H" EQ "RUNNING" (
        SendMail /smtpserver localhost /to me@mydomain.com /from watchdog@mydomain.com /subject Service Autostart Notification /body Autostart on service %service% succeded.
      ) else (
        SendMail /smtpserver localhost /to me@mydomain.com /from watchdog@mydomain.com /subject Service Autostart Notification /body Autostart on service %service% failed.
      )
    )

  )
)

Iniciando o serviço usando o script Powershell. Você pode vincular isso ao agendador de tarefas e acioná-lo em intervalos ou conforme necessário. Crie-o como um arquivo PS1, ou seja, um arquivo com a extensão PS1 e, em seguida, deixe esse arquivo ser acionado a partir do agendador de tarefas.

Para iniciar o serviço de parada

no agendador de tarefas se você estiver usando no servidor use isso em argumentos

-noprofile -executionpolicy bypass -file "C: \ Service Restart Scripts \ StopService.PS1"

verifique executando o mesmo no cmd se funciona, deve funcionar no agendador de tarefas também

$Password = "Enter_Your_Password"
$UserAccount = "Enter_Your_AccountInfor"
$MachineName = "Enter_Your_Machine_Name"
$ServiceList = @("test.SocketService","test.WcfServices","testDesktopService","testService")
$PasswordSecure = $Password | ConvertTo-SecureString -AsPlainText -Force
$Credential = new-object -typename System.Management.Automation.PSCredential -argumentlist $UserAccount, $PasswordSecure 

$LogStartTime = Get-Date -Format "MM-dd-yyyy hh:mm:ss tt"
$FileDateTimeStamp = Get-Date -Format "MM-dd-yyyy_hh"
$LogFileName = "C:\Users\krakhil\Desktop\Powershell\Logs\StartService_$FileDateTimeStamp.txt" 


#code to start the service

"`n####################################################################" > $LogFileName
"####################################################################" >> $LogFileName
"######################  STARTING SERVICE  ##########################" >> $LogFileName

for($i=0;$i -le 3; $i++)
{
"`n`n" >> $LogFileName
$ServiceName = $ServiceList[$i]
"$LogStartTime => Service Name: $ServiceName" >> $LogFileName

Write-Output "`n####################################"
Write-Output "Starting Service - " $ServiceList[$i]

"$LogStartTime => Starting Service: $ServiceName" >> $LogFileName
Start-Service $ServiceList[$i]

$ServiceState = Get-Service | Where-Object {$_.Name -eq $ServiceList[$i]}

if($ServiceState.Status -eq "Running")
{
"$LogStartTime => Started Service Successfully: $ServiceName" >> $LogFileName
Write-Host "`n Service " $ServiceList[$i] " Started Successfully"
}
else
{
"$LogStartTime => Unable to Stop Service: $ServiceName" >> $LogFileName
Write-Output "`n Service didn't Start. Current State is - "
Write-Host $ServiceState.Status
}
}

#code to stop the service

"`n####################################################################" > $LogFileName
"####################################################################" >> $LogFileName
"######################  STOPPING SERVICE  ##########################" >> $LogFileName

for($i=0;$i -le 3; $i++)
{
"`n`n" >> $LogFileName
$ServiceName = $ServiceList[$i]
"$LogStartTime => Service Name: $ServiceName" >> $LogFileName

Write-Output "`n####################################"
Write-Output "Stopping Service - " $ServiceList[$i]

"$LogStartTime => Stopping Service: $ServiceName" >> $LogFileName
Stop-Service $ServiceList[$i]

$ServiceState = Get-Service | Where-Object {$_.Name -eq $ServiceList[$i]}

if($ServiceState.Status -eq "Stopped")
{
"$LogStartTime => Stopped Service Successfully: $ServiceName" >> $LogFileName
Write-Host "`n Service " $ServiceList[$i] " Stopped Successfully"
}
else
{
"$LogStartTime => Unable to Stop Service: $ServiceName" >> $LogFileName
Write-Output "`nService didn't Stop. Current State is - "
Write-Host $ServiceState.Status
}
}

@Echo off

Set ServiceName=wampapache64

SC queryex "%ServiceName%"|Find "STATE"|Find /v "RUNNING">Nul&&(

echo %ServiceName% not running
echo  

Net start "%ServiceName%"


    SC queryex "%ServiceName%"|Find "STATE"|Find /v "RUNNING">Nul&&(
        Echo "%ServiceName%" wont start
    )
        echo "%ServiceName%" started

)||(
    echo "%ServiceName%" was working and stopping
    echo  

    Net stop "%ServiceName%"

)


pause

Relacionado com a resposta de @DanielSerrano, recentemente fui pouco por localização do sc.execomando, nomeadamente em espanhol. Minha proposta é apontar a linha e o token que contém o estado de serviço numérico e interpretá-lo, que deve ser muito mais robusto:

@echo off

rem TODO: change to the desired service name
set TARGET_SERVICE=w32time

set SERVICE_STATE=
rem Surgically target third line, as some locales (such as Spanish) translated the utility's output
for /F "skip=3 tokens=3" %%i in ('""%windir%\system32\sc.exe" query "%TARGET_SERVICE%" 2>nul"') do (
  if not defined SERVICE_STATE set SERVICE_STATE=%%i
)
rem Process result
if not defined SERVICE_STATE (
  echo ERROR: could not obtain service state!
) else (
  rem NOTE: values correspond to "SERVICE_STATUS.dwCurrentState"
  rem https://msdn.microsoft.com/en-us/library/windows/desktop/ms685996(v=vs.85).aspx
  if not %SERVICE_STATE%==4 (
    echo WARNING: service is not running
    rem TODO: perform desired operation
    rem net start "%TARGET_SERVICE%"
  ) else (
    echo INFORMATION: service is running
  )
)

Testado com:

• Windows XP (32 bits) Inglês
• Windows 10 (32 bits) espanhol
• Windows 10 (64 bits) Inglês

Talvez uma maneira muito mais simples? Apenas adicionando à lista de respostas aqui:

@for /f "tokens=1,* delims=: " %%a in ('sc queryex state=Inactive') do net start "%%b"