Como converter std :: string em NSString?

Olá, estou tentando converter um padrão std::stringem um, NSStringmas não estou tendo muita sorte.

Posso converter com sucesso de um NSStringpara um std::stringcom o seguinte código

NSString *realm = @"Hollywood";
std::string REALM = [realm cStringUsingEncoding:[NSString defaultCStringEncoding]];

No entanto, recebo um erro de tempo de compilação quando tento o seguinte

NSString *errorMessage = [NSString stringWithCString:REALM encoding:[NSString defaultCStringEncoding]];

O erro que recebo é

Cannot convert 'std::string' to 'const char*' in argument passing

Estou faltando alguma coisa aqui?

Desde já, obrigado.

Obtenha a string C de std :: string para conversão:

NSString *errorMessage = [NSString stringWithCString:REALM.c_str() 
                                   encoding:[NSString defaultCStringEncoding]];

Em primeiro lugar, você tem que usar Objective-C ++ para que isso funcione no mínimo; maneira mais fácil de garantir que é renomear todos os seus*.m arquivos para*.mm

De longe, a maneira manual mais utilizável (não obsoleta) de std::stringinserir um C ++ em um NSStringé com:

std::string param; // <-- input
NSString* result = [NSString stringWithUTF8String:param.c_str()];
NSString* alternative = [[NSString alloc] initWithUTF8String:param.c_str()];

Isso funcionará na maioria dos casos - e se você não estiver fazendo uma detecção e conversão de codificação específica, o UTF-8 vai lhe dar um bom resultado por ter caracteres não latinos 'apenas funcionam'.

Se você estiver fazendo um aplicativo maior ou não for o único trabalhando nele, provavelmente desejará algo mais fácil de aplicar.

Adaptado dos arquivos da lista de discussão cocoa-dev

@interface NSString (cppstring_additions)
+(NSString*) stringWithwstring:(const std::wstring&)string;
+(NSString*) stringWithstring:(const std::string&)string;
-(std::wstring) getwstring;
-(std::string) getstring;
@end

@implementation NSString (cppstring_additions)

#if TARGET_RT_BIG_ENDIAN
const NSStringEncoding kEncoding_wchar_t = CFStringConvertEncodingToNSStringEncoding(kCFStringEncodingUTF32BE);
#else
const NSStringEncoding kEncoding_wchar_t = CFStringConvertEncodingToNSStringEncoding(kCFStringEncodingUTF32LE);
#endif

+(NSString*) stringWithwstring:(const std::wstring&)ws
{
    char* data = (char*)ws.data();
    unsigned size = ws.size() * sizeof(wchar_t);

    NSString* result = [[NSString alloc] initWithBytes:data length:size encoding:kEncoding_wchar_t];
    return result;
}
+(NSString*) stringWithstring:(const std::string&)s
{
    NSString* result = [[NSString alloc] initWithUTF8String:s.c_str()];
    return result;
}

-(std::wstring) getwstring
{
    NSData* asData = [self dataUsingEncoding:kEncoding_wchar_t];
    return std::wstring((wchar_t*)[asData bytes], [asData length] / sizeof(wchar_t));
}
-(std::string) getstring
{
    return [self UTF8String];
}

@end

Com isso instalado (e apropriadamente #imported) agora você pode:

NSString* result = [NSString stringWithstring:param];
string convertedBack = [result getstring];

E o mesmo para std::wstring, o que é mais do que útil.

NSString* mystring = [NSString stringWithUTF8String:stdstring.c_str()];

A Apple agora tem uma nova maneira pela qual desejam que você faça essa conversão. No XCode7, usei a opção Edit> Convert> To Modern Objective C Syntax ... para descobrir isso. Ele usa um símbolo @ abreviado.

std::string sCPPString = "Hello World!";
NSString *sAppleString = @(sCPPString.c_str());

Eu também descobri que:

NSString *nsString = [NSString stringWithFormat:@"%s",standardString];

Trabalha como um campeão.

Aqui está o snippet de código / exemplo:

string str_simple = "HELLO WORLD";

//string to NSString
NSString *stringinObjC = [NSString stringWithCString:str_simple.c_str()
                                encoding:[NSString defaultCStringEncoding]];            
NSLog(stringinObjC);