Substituir guias por espaços no vim

Gostaria de converter tab em espaços no gVim. Eu adicionei a seguinte linha ao meu _vimrc:

set tabstop=2

Ele funciona para parar em dois espaços, mas ainda parece que uma tecla de tabulação foi inserida (tentei usar a tecla h para contar os espaços posteriormente).

Não tenho certeza do que devo fazer para que o gVim converta abas em espaços?

IIRC, algo como:

set tabstop=2 shiftwidth=2 expandtab

deve fazer o truque. Se você já possui guias, siga-o com um bom RE global para substituí-las por espaços duplos.

Depois que você tiver expandido a guia de acordo com as outras respostas, a maneira extremamente conveniente de converter arquivos existentes de acordo com as novas configurações é:

:retab

Ele funcionará no buffer atual.

Tentar

set expandtab

para abas suaves.

Para corrigir guias pré-existentes:

:%s/\t/  /g

Usei dois espaços, já que você já definiu seu tabstop para 2 espaços.

Isso funcionou para mim:

você pode ver as guias primeiro fazendo isso:

:set list

para tornar possível substituir guias, faça o seguinte:

:set expandtab

então

:retab

agora todas as guias foram substituídas por espaços. Você pode voltar à visualização normal como esta:

:set nolist

gg=G reindentará o arquivo inteiro e removerá a maioria, senão todas as guias que eu recebo dos arquivos dos colegas de trabalho.

Adicione as seguintes linhas ao seu arquivo .vimrc

set expandtab
set tabstop=4
set shiftwidth=4
map <F2> :retab <CR> :wq! <CR>

Abra um arquivo no vim e pressione F2. As guias serão convertidas em 4 espaços e o arquivo será salvo automaticamente.

Se você deseja manter o seu \tigual a 8 espaços, considere a configuração:

   set softtabstop=2 tabstop=8 shiftwidth=2

Isso fornecerá dois espaços por <TAB>impressora, mas \to código real ainda será exibido como 8 caracteres.

Isso funcionou para mim:

:set tabstop=2 shiftwidth=2 expandtab | retab

procure primeiro as guias no seu arquivo: / ^ I: set expandtab: retab

vai funcionar.

Este artigo possui um excelente script vimrc para manipular guias + espaços e converter entre eles.

Estes comandos são fornecidos:

Space2Tab Converta espaços em tabulações, apenas em recuos.

Tab2Space Converta guias em espaços, apenas em recuos.

RetabIndent Execute Space2Tab (se 'expandtab' estiver definido) ou Tab2Space (caso contrário).

Cada comando aceita um argumento que especifica o número de espaços em uma coluna da guia. Por padrão, a configuração 'tabstop' é usada.

Fonte: http://vim.wikia.com/wiki/Super_retab#Script

" Return indent (all whitespace at start of a line), converted from
" tabs to spaces if what = 1, or from spaces to tabs otherwise.
" When converting to tabs, result has no redundant spaces.
function! Indenting(indent, what, cols)
  let spccol = repeat(' ', a:cols)
  let result = substitute(a:indent, spccol, '\t', 'g')
  let result = substitute(result, ' \+\ze\t', '', 'g')
  if a:what == 1
    let result = substitute(result, '\t', spccol, 'g')
  endif
  return result
endfunction

" Convert whitespace used for indenting (before first non-whitespace).
" what = 0 (convert spaces to tabs), or 1 (convert tabs to spaces).
" cols = string with number of columns per tab, or empty to use 'tabstop'.
" The cursor position is restored, but the cursor will be in a different
" column when the number of characters in the indent of the line is changed.
function! IndentConvert(line1, line2, what, cols)
  let savepos = getpos('.')
  let cols = empty(a:cols) ? &tabstop : a:cols
  execute a:line1 . ',' . a:line2 . 's/^\s\+/\=Indenting(submatch(0), a:what, cols)/e'
  call histdel('search', -1)
  call setpos('.', savepos)
endfunction

command! -nargs=? -range=% Space2Tab call IndentConvert(<line1>,<line2>,0,<q-args>)
command! -nargs=? -range=% Tab2Space call IndentConvert(<line1>,<line2>,1,<q-args>)
command! -nargs=? -range=% RetabIndent call IndentConvert(<line1>,<line2>,&et,<q-args>)

Isso me ajudou um pouco mais do que as respostas aqui, quando fui procurar uma solução.

expandé um utilitário unix para converter abas em espaços. Se você não deseja setnada no vim, pode usar um comando shell do vim:

:!% expand -t8