Como evito que TStrings.SaveToFile crie uma linha final vazia?

Eu tenho um arquivo .\input.txtcomo este:

aaa
bbb
ccc

Se eu o ler TStrings.LoadFromFilee escrevê-lo novamente (mesmo sem aplicar nenhuma alteração) TStrings.SaveToFile, ele criará uma linha vazia no final do arquivo de saída.

var
  Lines : TStrings;
begin
  Lines := TStringList.Create;
  try
    Lines.LoadFromFile('.\input.txt');

    //...

    Lines.SaveToFile('.\output.txt');
  finally
    Lines.Free;
  end;
end;

O mesmo comportamento pode ser observado usando a TStrings.Textpropriedade que retornará uma string contendo uma linha vazia no final.

Para o Delphi 10.1 e mais recente, existe uma propriedade que TrailingLineBreakcontrola esse comportamento.

Quando a propriedade TrailingLineBreak for True (valor padrão), a propriedade Text conterá quebra de linha após a última linha. Quando for Falso, o valor do Texto não conterá quebra de linha após a última linha. Isso também pode ser controlado pela opção soTrailingLineBreak.

Para Delphi 10.1 (Berlin) ou mais recente, a melhor solução é descrita na resposta de Uwe.

Para versões mais antigas do Delphi, encontrei uma solução criando uma classe filho TStringListe substituindo a TStrings.GetTextStrfunção virtual, mas ficarei feliz em saber se existe uma solução melhor ou se alguém encontrou algo errado na minha solução.

Interface:

  uses
    Classes;

  type
    TMyStringList = class(TStringList)
    private
      FIncludeLastLineBreakInText : Boolean;
    protected
      function GetTextStr: string; override;
    public
      constructor Create(AIncludeLastLineBreakInText : Boolean = False); overload;
      property IncludeLastLineBreakInText : Boolean read FIncludeLastLineBreakInText write FIncludeLastLineBreakInText;
    end;

Implementação:

uses
  StrUtils;      

constructor TMyStringList.Create(AIncludeLastLineBreakInText : Boolean = False);
begin
  inherited Create;

  FIncludeLastLineBreakInText := AIncludeLastLineBreakInText;
end;

function TMyStringList.GetTextStr: string;
begin
  Result := inherited;

  if(not IncludeLastLineBreakInText) and EndsStr(LineBreak, Result)
  then SetLength(Result, Length(Result) - Length(LineBreak));
end;

Exemplo:

procedure TForm1.Button1Click(Sender: TObject);
var
  Lines : TStrings;
begin
  Lines := TMyStringList.Create();
  try
    Lines.LoadFromFile('.\input.txt');
    Lines.SaveToFile('.\output.txt');
  finally
    Lines.Free;
  end;
end;