Como escrever o script esperado para instalar o mariadb?

Ambiente: centos7 + mariadb5.5.64.
Deixe-me mostrar as informações de instalação na tela quando executar mysql_secure_installation.

# mysql_secure_installation

NOTE: RUNNING ALL PARTS OF THIS SCRIPT IS RECOMMENDED FOR ALL MariaDB
      SERVERS IN PRODUCTION USE!  PLEASE READ EACH STEP CAREFULLY!

In order to log into MariaDB to secure it, we'll need the current
password for the root user.  If you've just installed MariaDB, and
you haven't set the root password yet, the password will be blank,
so you should just press enter here.

Enter current password for root (enter for none): 
OK, successfully used password, moving on...

Setting the root password ensures that nobody can log into the MariaDB
root user without the proper authorisation.

Set root password? [Y/n] y
New password: 
Re-enter new password: 
Password updated successfully!
Reloading privilege tables..
 ... Success!


By default, a MariaDB installation has an anonymous user, allowing anyone
to log into MariaDB without having to have a user account created for
them.  This is intended only for testing, and to make the installation
go a bit smoother.  You should remove them before moving into a
production environment.

Remove anonymous users? [Y/n] y
 ... Success!

Normally, root should only be allowed to connect from 'localhost'.  This
ensures that someone cannot guess at the root password from the network.

Disallow root login remotely? [Y/n] y
 ... Success!

By default, MariaDB comes with a database named 'test' that anyone can
access.  This is also intended only for testing, and should be removed
before moving into a production environment.

Remove test database and access to it? [Y/n] y
 - Dropping test database...
 ... Success!
 - Removing privileges on test database...
 ... Success!

Reloading the privilege tables will ensure that all changes made so far
will take effect immediately.

Reload privilege tables now? [Y/n] y
 ... Success!

Cleaning up...

All done!  If you've completed all of the above steps, your MariaDB
installation should now be secure.

Thanks for using MariaDB!

Escrevo um script de automação para instalar o mariadb.

  vim secure.exp
  set timeout 60
  spawn mysql_secure_installation
  expect {
      "Enter current password for root (enter for none): " {send "\r";exp_continue}
      "Set root password? [Y/n] " {send "y\r";exp_continue}
      "New password:" {send "123456\r";exp_continue}
      "Re-enter new password:" {send "123456\r";exp_continue}
      "Remove anonymous users? [Y/n]" {send "y\r";exp_continue}
      "Disallow root login remotely? [Y/n]" {send "y\r";exp_continue}
      "Remove test database and access to it? [Y/n]" {send "y\r";exp_continue}
      "Reload privilege tables now? [Y/n]" {send "y\r";exp_continue}
  }

Para executar /usr/bin/expect secure.exp, me deparei com o erro:

spawn mysql_secure_installation
invalid command name "Y/n"
    while executing
"Y/n"
    invoked from within
"expect {
          "Enter current password for root (enter for none): " {send "\r";exp_continue}
          "Set root password? [Y/n] " {send "y\r";exp..."
    (file "secure.exp" line 3)

Não adianta escrever como abaixo:

  set timeout 60
  spawn mysql_secure_installation
  expect {
      "Enter current password for root (enter for none): " {send "\r";exp_continue}
      "Set root password? \\[Y/n] " {send "y\r";exp_continue}
      "New password:" {send "123456\r";exp_continue}
      "Re-enter new password:" {send "123456\r";exp_continue}
      "Remove anonymous users? \\[Y/n]" {send "y\r";exp_continue}
      "Disallow root login remotely? \\[Y/n]" {send "y\r";exp_continue}
      "Remove test database and access to it? \\[Y/n]" {send "y\r";exp_continue}
      "Reload privilege tables now? \\[Y/n]" {send "y\r";exp_continue}
  }

Mesmo erro:

invalid command name "Y/n"
    while executing
"Y/n"
    invoked from within
"expect {
      "Enter current password for root (enter for none): " {send "\r";exp_continue}
      "Set root password? \\[Y/n] " {send "y\r";exp_conti..."
    (file "secure.exp" line 3)

Como corrigir meu script exp então?

Esses scripts aguardam para receber saída opcional ( timeout -1significa "sem tempo limite") e podem diferenciar respostas diferentes, conforme exigido por yum installe mysql_secure_installation. Com #!/bin/expect -fcomo shebang, os scripts podem ser executados quando definidos chmod +x.

A) Para começar, mariadb_yum.exp(requer suou sudo):

#!/bin/expect -f
set timeout 30
if {[llength $argv] == 0} {
    send_user "Usage: mariadb_yum.exp \[linux sudo password\]\n"
    exit 1
}
set USERNAME "[exec whoami]"
set PASSWORD [lindex $argv 0];

# optionally, redirect output to log file (silent install)
# log_user 0
# log_file -a "/home/$USERNAME/mariadb_install.log"

spawn sudo yum -y install MariaDB-server
set yum_spawn_id $spawn_id

# On GCE it will never ask for a sudo password:
expect -ex "\[sudo\] password for $USERNAME: " {
   exp_send "$PASSWORD\r"
}

expect {
    # when the package was already installed
    -ex "Nothing to do" {
        send_user "package was already installed\n"
    }
    # when the package had been installed
    -ex "Complete!" {
        send_user "package had been installed\n"
    }
}

expect eof
close $yum_spawn_id
exit 0

B) E então mariadb_sec.exp(não requer sudo):

#!/bin/expect -f
set timeout 1
if {[llength $argv] == 0} {
    send_user "Usage: mariadb_sec.exp \[mysql root password\]\n"
    exit 1
}
set PASSWORD [lindex $argv 0];

spawn mysql_secure_installation
set mysql_spawn_id $spawn_id

# optionally, redirect output to log file (silent install)
# log_user 0
# log_file -a "/home/[exec whoami]/mariadb_install.log"

# when there is no password set, this probably should be "\r"
expect -ex "Enter current password for root (enter for none): "
exp_send "$PASSWORD\r"

expect {
    # await an eventual error message
    -ex "ERROR 1045" {
        send_user "\nMariaDB > An invalid root password had been provided.\n"
        close $mysql_spawn_id
        exit 1
    }
    # when there is a root password set
    -ex "Change the root password? \[Y/n\] " {
        exp_send "n\r"
    }
    # when there is no root password set (could not test this branch).
    -ex "Set root password? \[Y/n\] " {
        exp_send "Y\r"
        expect -ex "New password: "
        exp_send "$PASSWORD\r"
        expect -ex "Re-enter new password: "
        exp_send "$PASSWORD\r"
    }
}
expect -ex "Remove anonymous users? \[Y/n\] "
exp_send "Y\r"
expect -ex "Disallow root login remotely? \[Y/n\] "
exp_send "Y\r"
expect -ex "Remove test database and access to it? \[Y/n\] "
exp_send "Y\r"
expect -ex "Reload privilege tables now? \[Y/n\] "
exp_send "Y\r"

expect eof
close $mysql_spawn_id
exit 0

Para fins de depuração - ou para validar a resposta, é possível executar expectcom o nível de log strace 4. Provavelmente, é tão respeitável quanto uma fonte pode obter, quando se trata de escrever expectscripts, pois exibe bem o que está acontecendo e o mais importante, em que ordem as coisas acontecem:

expect -c "strace 4" ./mariadb_yum.exp [linux sudo password]
expect -c "strace 4" ./mariadb_sec.exp [mysql root password]

É set exp_internal 1possível usar instruções para obter saída para a correspondência de regex.

Uma possível fonte de confusão pode ser: onde se geram os processos - como se pode gerar vários processos em vários hosts, por exemplo. sshlocalmente e depois yume mysql_secure_installationremotamente. Adicionado $spawn_idao script; a closechamada inferior pode ser redundante, pois já é EOF(apenas para mostrar como spawn& closeprocessos):

Thanks for using MariaDB!
 1  close $mysql_spawn_id
 1  exit 0
 2  rename _close.pre_expect close

Conclusão: O mariadb_sec.expscript provavelmente poderia ser melhorado ainda mais, por exemplo. quando, inicialmente, não envia nenhuma senha e vê o que acontece - envia a senha ERROR 1045(quando uma senha já havia sido definida anteriormente). Pode-se economizar presumir que é preciso definir a senha quando o servidor acabou de ser instalado (exceto que yum reinstallfornece o mesmo resultado). Apenas não tinha um contêiner em branco do CentOS para testar todos os casos. A menos que seja executado em um rootshell, seria necessário passar os dois tipos de senhas em um script para automatizar isso da instalação até a pós-instalação.

Provavelmente vale a pena notar que, no GCE, sudonão pediria uma senha; de fato, existem pequenas diferenças baseadas no ambiente, pois essas imagens de contêiner do CentOS se comportam de maneira diferente. Nesse caso (como não há sudetecção de imagem de contêiner ou local), o mariadb_yum.expscript pode ficar travado por 30segundos e continuar.

As fontes mais respeitáveis ​​que posso oferecer são o expectmanual, escrito por Don Libes @ NIST e o manual TCL / TK expect, juntamente com o projeto SourceForge, chamado por coincidência expect.

Não são usados ​​colchetes quadrados apenas para substituição de comando, mas também são especiais para padrões glob .

Você pode usar o -exactcomutador enquanto escapa os colchetes entre aspas:

spawn mysql_secure_installation
expect {
    ...
    -exact "Set root password? \[Y/n\] " {send "y\r";exp_continue}
    ...
}

Ou use chaves em vez de aspas:

spawn mysql_secure_installation
expect {
    ...
    {Set root password? \[Y/n\] } {send "y\r";exp_continue}
    ...
}

Para sua informação, você pode gerar o script esperado usando autoexpect:

autoexpect ./mysql_secure_installation

Isso irá gerar um script esperado chamado script.expem seu diretório de trabalho atual.