Criando um declarador personalizado

Digamos que eu use um certo conjunto de clichês regularmente:

class Foo {

  method abc($a: $b, $c, +@d) is pure {
    use Slang::Bar;
    …
  }

  method xyz($a: $b, $c, +@d) is pure {
    use Slang::Bar;
    …
  }

  method blarg($a: $b, $c, +@d) is pure {
    use Slang::Bar;
    …
  }

}

Prefiro dizer:

class Foo is/does Bar {
  bar  abc   { … }
  bar  xyz   { … }
  bar  blarg { … }
}

E em algum lugar em Bar, configure a declaração para bar (ou, como a própria classe Foo finalmente usará seu próprio declarador, ele poderá ir para outro lugar e não precisará ser extraído em um tipo separado). Como eu faria isso?

-1. Limitações (apenas para pacotes)

O método EXPORTHOW chama .set_how na atual $?LANGadicionando uma gíria à última.
Em seguida, adicione add_package_declarator ao MAIN $?LANGqual adiciona um package_declaratormétodo às suas ações e gramática. Acho que é a única "gíria dinâmica" (no World.nqp).

Se o que você deseja é substituir o rotina_declarador . Então você tem que escrever uma gíria que imita a corrente citada. Se você aceitar manter a palavra-chave method e criar a assinatura automática na classe, digamos de acordo com o nome do método, aqui está uma maneira:

Nota: Um pacote é um contêiner (pacote, gramática, módulo, função, know-how, enum, classe, subconjunto). Se você colocar o código dentro como um método, isso é executado (eu apenas tentei):

0. Descrição (EXPORTHOW)

Eu usaria EXPORTHOW não documentado e DECLAREem um módulo porque não encontrei um caminho com a Phaser . Aparentemente, é tarde demais, mesmo no início.

O exemplo que dou é decorar todos os métodos de uma classe (par BUILDALL).

1. Lib ( decorator.rakumod)

class DecoratedClassHOW is Metamodel::ClassHOW {
    method add_method(Mu $obj, $name, $code_obj) {
        sub wrapper ($obj, $a, $b) {
            say "Before $name";
            my $res = $code_obj($obj, $a, $b);
            say "After $name";
            return $res;
        }
        my $res = callwith($obj, $name, &wrapper);
        return $res;
    }
}

my module EXPORTHOW {
    package DECLARE {
        constant decorated = DecoratedClassHOW;
    }
}

2. Executável

use lib '.';
use decorator-lib;

decorated Foo {
  method abc($a, $b) {
      say "In abc: $a:$b";
  }
}

my $f = Foo.new;
$f.abc(1, 2);

3. Saída

Before BUILDALL
After BUILDALL
Before abc
In abc: 1:2
After abc

4. Fontes

• Grammar :: Depurador : exportando um símbolo (gramática) substituindo find_method e add_method
• E o NQPTraceHOW :: trace-on da npq : for $_.HOW.method_table($_)criando um novo hash substituindo o cache do método pelo (bem nomeado) nqp::setmethcache.
• Para automatizar a assinatura, toque com .signature
• Jnthn artigo na EXPORTHOW
• Então poste no EXPORTHOW impossível com função