Como posso gerar UTF-8 do Perl?

Estou tentando escrever um script Perl usando o pragma "utf8" e estou obtendo resultados inesperados. Estou usando o Mac OS X 10.5 (Leopard) e estou editando com o TextMate. Todas as minhas configurações para meu editor e sistema operacional são padronizadas para gravar arquivos no formato utf-8.

No entanto, ao inserir o seguinte em um arquivo de texto, salvá-lo como ".pl" e executá-lo, recebo o amigável "diamante com um ponto de interrogação" no lugar dos caracteres não ASCII.

#!/usr/bin/env perl -w

use strict;
use utf8;

my $str = 'Çirçös';
print( "$str\n" );

Alguma ideia do que estou fazendo de errado? Espero obter 'Çirçös' na saída, mas recebo ' ir s' em vez disso.

use utf8;não ativa a saída Unicode - permite que você digite Unicode em seu programa. Adicione isto ao programa, antes de sua print()declaração:

binmode(STDOUT, ":utf8");

Veja se isso ajuda. Isso deve produzir STDOUTsaída em UTF-8 em vez de ASCII comum.

Você pode usar o pragma aberto .

Por exemplo. abaixo define STDOUT, STDIN e STDERR para usar UTF-8 ....

use open qw/:std :utf8/;

TMTOWTDI , escolheu o método que melhor se adapta ao seu trabalho. Eu uso o método do ambiente, então não preciso pensar sobre isso.

No meio ambiente :

export PERL_UNICODE=SDL

na linha de comando :

perl -CSDL -le 'print "\x{1815}"';

ou com binmode :

binmode(STDOUT, ":utf8");          #treat as if it is UTF-8
binmode(STDIN, ":encoding(utf8)"); #actually check if it is UTF-8

ou com PerlIO :

open my $fh, ">:utf8", $filename
    or die "could not open $filename: $!\n";

open my $fh, "<:encoding(utf-8)", $filename
    or die "could not open $filename: $!\n";

ou com o pragma aberto :

use open ":encoding(utf8)";
use open IN => ":encoding(utf8)", OUT => ":utf8";

Você também quer dizer que as strings em seu código são utf-8. Consulte Por que o Perl moderno evita UTF-8 por padrão? . Portanto, defina não só, PERL_UNICODE=SDALmas também PERL5OPT=-Mutf8.

Obrigado, finalmente consegui uma solução para não colocar utf8 :: encode em todo o código. Para sintetizar e completar para outros casos, como escrever e ler arquivos em utf8 e também trabalhar com LoadFile de um arquivo YAML em utf8

use utf8;
use open ':encoding(utf8)';
binmode(STDOUT, ":utf8");

open(FH, ">test.txt"); 
print FH "something éá";

use YAML qw(LoadFile Dump);
my $PUBS = LoadFile("cache.yaml");
my $f = "2917";
my $ref = $PUBS->{$f};
print "$f \"".$ref->{name}."\" ". $ref->{primary_uri}." ";

onde cache.yaml é:

---
2917:
  id: 2917
  name: Semanário
  primary_uri: 2917.xml

faça no seu shell: $ env | grep LANG

Isso provavelmente mostrará que seu shell não está usando uma localidade utf-8.