Mover linha inteira para cima e para baixo no Vim

No Notepad ++, posso usar Ctrl+ Shift+ Up/ Downpara mover a linha atual para cima e para baixo. Existe um comando semelhante a isso no Vim? Eu olhei através de guias sem fim, mas não encontrei nada.

Se não houver, como vincular a ação a essa combinação de teclas?

Edit: A resposta de Mykola funciona para todas as linhas, exceto aquelas no início e no final do buffer. Mover a primeira linha para cima ou a linha inferior para baixo exclui a linha e, ao mover a linha inferior para cima, ele pula dois espaços inicialmente, como um peão! Alguém pode oferecer refinamentos?

Coloque o seguinte em seu .vimrc para fazer o trabalho

noremap <c-s-up> :call feedkeys( line('.')==1 ? '' : 'ddkP' )<CR>
noremap <c-s-down> ddp

Desaparecer da linha parece um bug do Vim. Eu coloquei um truque para evitá-lo. Provavelmente existe alguma solução mais precisa.

Atualizar

Existem muitas dificuldades inexplicáveis ​​em usar apenas as combinações do Vim. Estes são falta de linha e salto de linha extra.

Então, aqui está a solução de script que pode ser colocada dentro de .vimrc ou ~ / .vim / plugin / swap_lines.vim

function! s:swap_lines(n1, n2)
    let line1 = getline(a:n1)
    let line2 = getline(a:n2)
    call setline(a:n1, line2)
    call setline(a:n2, line1)
endfunction

function! s:swap_up()
    let n = line('.')
    if n == 1
        return
    endif

    call s:swap_lines(n, n - 1)
    exec n - 1
endfunction

function! s:swap_down()
    let n = line('.')
    if n == line('$')
        return
    endif

    call s:swap_lines(n, n + 1)
    exec n + 1
endfunction

noremap <silent> <c-s-up> :call <SID>swap_up()<CR>
noremap <silent> <c-s-down> :call <SID>swap_down()<CR>

Se eu quiser trocar uma linha pela linha acima, eu normalmente faço o seguinte

ddkP

Explicação

• O dd excluirá a linha e a adicionará ao registro padrão.
• k subirá uma linha (j desceria uma linha)
• P irá colar acima da linha atual

Supondo que o cursor esteja na linha que você deseja mover.

Mover para cima e para baixo: :mpara mover

:m +1 - desce uma linha

:m -2 - subir 1 linhas

(Observe que você pode substituir +1 por qualquer número, dependendo de quantas linhas você deseja movê-lo para cima ou para baixo, ou seja, +2 o moveria para baixo 2 linhas e -3 para 2 linhas)

Para ir para uma linha específica

:set number - exibir linhas numéricas (mais fácil de ver para onde você está indo)

:m 3 - mova a linha após a terceira linha (substitua 3 por qualquer linha que desejar)

Movendo várias linhas:

V(ie Shift- V) e mova o cursor para cima e para baixo para selecionar várias linhas no VIM

uma vez selecionado, pressione :e execute os comandos acima, m +1etc

Mover uma linha para cima: ddkP

Mover uma linha para baixo: ddp

Isso funcionou para mim:

http://vim.wikia.com/wiki/Moving_lines_up_or_down_in_a_file

BTW, se você deseja usar ALT + some_key e seu terminal (urxvt faz isso) se recusa a cumprir, você deve inserir algo como isso em seu arquivo .vimrc:

" For moving lines (^] is a special character; use <M-k> and <M-j> if it works)
nnoremap ^]k mz:m-2<CR>`z==
inoremap ^]j <Esc>:m+<CR>==gi
inoremap ^]k <Esc>:m-2<CR>==gi
vnoremap ^]j :m'>+<CR>gv=`<my`>mzgv`yo`z
nnoremap ^]j mz:m+<CR>`z==
vnoremap ^]k :m'<-2<CR>gv=`>my`<mzgv`yo`z

onde ^] é um único caractere que representa a chave ALT. Para inserir esse caractere, use C+v, Escno Vim ( C+q, Escno Windows).

adicione o seguinte ao arquivo ~ / .vimrc (verifique se você não tem mapeamento para n, m)

nmap n :m +1<CR>
nmap m :m -2<CR>

Agora, pressionar a ntecla moverá uma linha para baixo e mmoverá uma linha para cima.

No modo de comando, posicione o cursor na linha que você deseja mover para baixo e, em seguida,

ddp

Explicação: dd exclui a linha atual no buffer geral p a coloca de volta APÓS a posição do cursor ou, no caso de linhas inteiras, uma linha abaixo.

Há alguma confusão em relação aos comandos p e P em muitos documentos. Na realidade, p cola APÓS o cursor e P AT.

Basta adicionar este código ao .vimrc (ou .gvimrc)

nnoremap <A-j> :m+<CR>==
nnoremap <A-k> :m-2<CR>==
inoremap <A-j> <Esc>:m+<CR>==gi
inoremap <A-k> <Esc>:m-2<CR>==gi
vnoremap <A-j> :m'>+<CR>gv=gv
vnoremap <A-k> :m-2<CR>gv=gv

Exatamente o que você está procurando neste incrível plugin: https://github.com/vim-scripts/upAndDown

Uma solução simples é colocar em suas .vimrclinhas:

nmap <C-UP> :m-2<CR>  
nmap <C-DOWN> :m+1<CR>

Coloquei o seguinte no final do meu arquivo .vimrc:

noremap H ddkkp
noremap N ddp

Então agora 'H' e 'N' movem a linha atual para cima e para baixo, respectivamente.

Aqui está uma versão simplificada, para MacVim, usando os exemplos de artigos da Wikia (veja o link do comentário de gun ).

" Move selection up/down (add =gv to reindent after move)
:vmap <D-S-Up> :m-2<CR>gv
:vmap <D-S-Down> :m'>+<CR>gv

Estou usando apenas a variante de seleção de bloco, porque basta Shift-V para selecionar a linha atual e, opcionalmente, cursor para cima / baixo para selecionar mais algumas linhas.

De acordo com os atalhos acima, pressionar Cmd-Shift-Up / Down alternará a seleção de bloco para cima / baixo. "D" é a tecla Command no MacVim; para Windows, tente "C" (Controle) ou "A" (Alt) (por exemplo, <CAf> seria Control Alt f).

O artigo da Wikia adiciona "= gv" a eles, que tem o efeito de ajustar o recuo do bloco após a movimentação, com base no texto ao redor. Isso é confuso, então eu o removi e adicionei atalhos para recuar rapidamente a seleção.

" Indent selection left/right (Cmd Shift Left/Right is used for Tab switching)
:vmap <D-A-Left> <gv
:vmap <D-A-Right> >gv

Lembre-se, o mesmo pode ser feito com << e >>, mas a seleção seria perdida; portanto, esses atalhos acima permitem recuar várias vezes e ainda mover o bloco porque a seleção é mantida.

Meu MacVim está configurado para alternar as guias com Cmd-Shift-Esquerda / Direita, então usei Cmd-Alt-Esquerda / Direita.

Aqui está a alternância de guias para o MacVim (insira .gvimrc com o restante acima):

:macm Window.Select\ Previous\ Tab key=<D-S-Left>
:macm Window.Select\ Next\ Tab key=<D-S-Right>

plugin do vim unimpaired.vim [e and] e

Quando você bate comando :help moveem vim, aqui está o resultado:

:[range]m[ove] {address} *:m* *:mo* *:move* *E134* Move the lines given by [range] to below the line given by {address}.

Por exemplo: Mova a linha atual uma linha para baixo => :m+1 .

Por exemplo: Mova a linha com o número 100 abaixo da linha com o número 80 => :100 m 80 .

Por exemplo: Mova a linha com o número 100 abaixo da linha com o número 200 => :100 m 200 .

Por exemplo: Mova as linhas com o número dentro de [100, 120] abaixo da linha com o número 200 => :100,120 m 200 .

Aqui está uma solução que funciona na minha máquina : MacBook Pro executando o VIM 8.1

Esses comandos não excluirão suas linhas na parte superior ou inferior do seu buffer.

Usar os símbolos reais que Alt-J e Alt-K emitem é uma solução alternativa para que seus códigos-chave não sejam mapeados corretamente no meu ambiente.

Jogue isso no .vimrc antigo e veja se funciona para você.

" Maps Alt-J and Alt-K to macros for moving lines up and down
" Works for modes: Normal, Insert and Visual
nnoremap ∆ :m .+1<CR>==
nnoremap ˚ :m .-2<CR>==
inoremap ∆ <Esc>:m .+1<CR>==gi
inoremap ˚ <Esc>:m .-2<CR>==gi
vnoremap ∆ :m '>+1<CR>gv=gv
vnoremap ˚ :m '<-2<CR>gv=gv

Para mim, ddkkpfiz (em vez de ddkPcom um P maiúsculo, que também funcionaria).

: m. + 1 ou: m.-2 faria se você estivesse movendo uma única linha. Aqui está o meu script para mover várias linhas. No modo visual, Alt-up / Alt-down move as linhas que contêm a seleção visual para cima / baixo em uma linha. No modo de inserção ou modo normal, Alt-up / Alt-down moverá a linha atual se nenhum prefixo de contagem for fornecido. Se houver um prefixo de contagem, Alt-up / Alt-down moverá muitas linhas a partir da linha atual para cima / baixo em uma linha.

function! MoveLines(offset) range
    let l:col = virtcol('.')
    let l:offset = str2nr(a:offset)
    exe 'silent! :' . a:firstline . ',' . a:lastline . 'm'
        \ . (l:offset > 0 ? a:lastline + l:offset : a:firstline + l:offset)
    exe 'normal ' . l:col . '|'
endf

imap <silent> <M-up> <C-O>:call MoveLines('-2')<CR>
imap <silent> <M-down> <C-O>:call MoveLines('+1')<CR>
nmap <silent> <M-up> :call MoveLines('-2')<CR>
nmap <silent> <M-down> :call MoveLines('+1')<CR>
vmap <silent> <M-up> :call MoveLines('-2')<CR>gv
vmap <silent> <M-down> :call MoveLines('+1')<CR>gv

Caso você queira fazer isso em várias linhas que correspondam a uma pesquisa específica:

• Para cima: :g/Your query/ normal ddpou:g/Your query/ m -1
• para baixo :g/Your query/ normal ddpou:g/Your query/ m +1