Como soltar todas as tabelas em um banco de dados SQL Server?

Estou tentando escrever um script que esvaziará completamente um banco de dados do SQL Server. Isto é o que eu tenho até agora:

USE [dbname]
GO
EXEC sp_msforeachtable 'ALTER TABLE ? NOCHECK CONSTRAINT all'
EXEC sp_msforeachtable 'DELETE ?'

Quando o executo no Management Studio, recebo:

Comando (s) concluído (s) com sucesso.

mas quando eu atualizo a lista de tabelas, elas ainda estão lá. O que estou fazendo de errado?

Também não funciona para mim quando existem várias tabelas de chaves estrangeiras.
Encontrei o código que funciona e faz tudo o que você tenta (exclua todas as tabelas do seu banco de dados):

DECLARE @Sql NVARCHAR(500) DECLARE @Cursor CURSOR

SET @Cursor = CURSOR FAST_FORWARD FOR
SELECT DISTINCT sql = 'ALTER TABLE [' + tc2.TABLE_SCHEMA + '].[' +  tc2.TABLE_NAME + '] DROP [' + rc1.CONSTRAINT_NAME + '];'
FROM INFORMATION_SCHEMA.REFERENTIAL_CONSTRAINTS rc1
LEFT JOIN INFORMATION_SCHEMA.TABLE_CONSTRAINTS tc2 ON tc2.CONSTRAINT_NAME =rc1.CONSTRAINT_NAME

OPEN @Cursor FETCH NEXT FROM @Cursor INTO @Sql

WHILE (@@FETCH_STATUS = 0)
BEGIN
Exec sp_executesql @Sql
FETCH NEXT FROM @Cursor INTO @Sql
END

CLOSE @Cursor DEALLOCATE @Cursor
GO

EXEC sp_MSforeachtable 'DROP TABLE ?'
GO

Você pode encontrar o post aqui . É o post do Groker.

Você também pode excluir todas as tabelas do banco de dados usando apenas as ferramentas de interface do usuário MSSMS (sem usar o script SQL). Às vezes, esse caminho pode ser mais confortável (especialmente se for realizado ocasionalmente)

Eu faço isso passo a passo da seguinte maneira:

1. Selecione 'Tabelas' na árvore do banco de dados (Pesquisador de Objetos)
2. Pressione F7 para abrir a exibição Detalhes do Pesquisador de Objetos
3. Nesta visão, selecione as tabelas que precisam ser excluídas (neste caso, todas elas)
4. Continue pressionando Excluir até que todas as tabelas tenham sido excluídas (você a repete quantas vezes houver devido a restrições / dependências de teclas)

No SSMS:

• Clique com o botão direito do mouse no banco de dados
• Vá para "Tarefas"
• Clique em "Gerar scripts"
• Na seção "Escolher objetos", selecione "Script de banco de dados inteiro e todos os objetos de banco de dados"
• Na seção "Definir opções de script", clique no botão "Avançado"
• Em "Script DROP and CREATE" alterne "Script CREATE" para "Script DROP" e pressione OK
• Em seguida, salve em arquivo, área de transferência ou nova janela de consulta.
• Execute o script.

Agora, isso eliminará tudo, incluindo o banco de dados. Certifique-se de remover o código dos itens que não deseja que sejam descartados. Como alternativa, na seção "Escolher objetos", em vez de selecionar o script do banco de dados inteiro, basta selecionar os itens que você deseja remover.

deleteé usado para excluir linhas de uma tabela. Você deve usar em seu drop tablelugar.

EXEC sp_msforeachtable 'drop table [?]'

A resposta aceita não oferece suporte ao Azure. Ele usa um procedimento armazenado não documentado "sp_MSforeachtable". Se você receber um erro "o azure não pôde encontrar o procedimento armazenado 'sp_msforeachtable" ao executar ou simplesmente deseja evitar confiar em recursos não documentados (que podem ser removidos ou que sua funcionalidade foi alterada a qualquer momento), tente o abaixo.

Esta versão ignora a tabela de histórico de migração da estrutura da entidade "__MigrationHistory" e o "database_firewall_rules", que é uma tabela do Azure que você não terá permissão para excluir.

Levemente testado no Azure. Verifique se isso não tem efeitos indesejados no seu ambiente.

DECLARE @sql NVARCHAR(2000)

WHILE(EXISTS(SELECT 1 from INFORMATION_SCHEMA.TABLE_CONSTRAINTS WHERE CONSTRAINT_TYPE='FOREIGN KEY'))
BEGIN
    SELECT TOP 1 @sql=('ALTER TABLE ' + TABLE_SCHEMA + '.[' + TABLE_NAME + '] DROP CONSTRAINT [' + CONSTRAINT_NAME + ']')
    FROM INFORMATION_SCHEMA.TABLE_CONSTRAINTS
    WHERE CONSTRAINT_TYPE = 'FOREIGN KEY'
    EXEC(@sql)
    PRINT @sql
END

WHILE(EXISTS(SELECT * from INFORMATION_SCHEMA.TABLES WHERE TABLE_NAME != '__MigrationHistory' AND TABLE_NAME != 'database_firewall_rules'))
BEGIN
    SELECT TOP 1 @sql=('DROP TABLE ' + TABLE_SCHEMA + '.[' + TABLE_NAME + ']')
    FROM INFORMATION_SCHEMA.TABLES
    WHERE TABLE_NAME != '__MigrationHistory' AND TABLE_NAME != 'database_firewall_rules'
    EXEC(@sql)
    PRINT @sql
END

Tirado de:

https://edspencer.me.uk/2013/02/25/drop-all-tables-in-a-sql-server-database-azure-friendly/

http://www.sqlservercentral.com/blogs/sqlservertips/2011/10/11/remove-all-foreign-keys/

/* Drop all Primary Key constraints */
DECLARE @name VARCHAR(128)
DECLARE @constraint VARCHAR(254)
DECLARE @SQL VARCHAR(254)

SELECT @name = (SELECT TOP 1 TABLE_NAME FROM INFORMATION_SCHEMA.TABLE_CONSTRAINTS WHERE constraint_catalog=DB_NAME() AND CONSTRAINT_TYPE = 'PRIMARY KEY' ORDER BY TABLE_NAME)

WHILE @name IS NOT NULL
BEGIN
    SELECT @constraint = (SELECT TOP 1 CONSTRAINT_NAME FROM INFORMATION_SCHEMA.TABLE_CONSTRAINTS WHERE constraint_catalog=DB_NAME() AND CONSTRAINT_TYPE = 'PRIMARY KEY' AND TABLE_NAME = @name ORDER BY CONSTRAINT_NAME)
    WHILE @constraint is not null
    BEGIN
        SELECT @SQL = 'ALTER TABLE [dbo].[' + RTRIM(@name) +'] DROP CONSTRAINT [' + RTRIM(@constraint)+']'
        EXEC (@SQL)
        PRINT 'Dropped PK Constraint: ' + @constraint + ' on ' + @name
        SELECT @constraint = (SELECT TOP 1 CONSTRAINT_NAME FROM INFORMATION_SCHEMA.TABLE_CONSTRAINTS WHERE constraint_catalog=DB_NAME() AND CONSTRAINT_TYPE = 'PRIMARY KEY' AND CONSTRAINT_NAME <> @constraint AND TABLE_NAME = @name ORDER BY CONSTRAINT_NAME)
    END
SELECT @name = (SELECT TOP 1 TABLE_NAME FROM INFORMATION_SCHEMA.TABLE_CONSTRAINTS WHERE constraint_catalog=DB_NAME() AND CONSTRAINT_TYPE = 'PRIMARY KEY' ORDER BY TABLE_NAME)
END
GO

/* Drop all tables */
DECLARE @name VARCHAR(128)
DECLARE @SQL VARCHAR(254)

SELECT @name = (SELECT TOP 1 [name] FROM sysobjects WHERE [type] = 'U' AND category = 0 ORDER BY [name])

WHILE @name IS NOT NULL
BEGIN
    SELECT @SQL = 'DROP TABLE [dbo].[' + RTRIM(@name) +']'
    EXEC (@SQL)
    PRINT 'Dropped Table: ' + @name
    SELECT @name = (SELECT TOP 1 [name] FROM sysobjects WHERE [type] = 'U' AND category = 0 AND [name] > @name ORDER BY [name])
END
GO

Você está quase certo, use:

EXEC sp_msforeachtable 'ALTER TABLE ? NOCHECK CONSTRAINT all'
EXEC sp_msforeachtable 'DROP TABLE ?'

mas na segunda linha, você pode precisar executar mais de uma vez até parar de receber erro:

Could not drop object 'dbo.table' because it is referenced by a FOREIGN KEY constraint.

Mensagem:

Command(s) completed successfully.

significa que todas as tabelas foram excluídas com sucesso.

Curto e grosso:

USE YOUR_DATABASE_NAME
-- Disable all referential integrity constraints
EXEC sp_MSforeachtable 'ALTER TABLE ? NOCHECK CONSTRAINT ALL'
GO

-- Drop all PKs and FKs
declare @sql nvarchar(max)
SELECT @sql = STUFF((SELECT '; ' + 'ALTER TABLE ' + Table_Name  +'  drop constraint ' + Constraint_Name  from Information_Schema.CONSTRAINT_TABLE_USAGE ORDER BY Constraint_Name FOR XML PATH('')),1,1,'')
EXECUTE (@sql)
GO

-- Drop all tables
EXEC sp_MSforeachtable 'DROP TABLE ?'
GO

O caminho do jejum é:

1. Novos diagramas de banco de dados
2. Adicionar toda a tabela
3. Ctrl + A para selecionar todos
4. Clique com o botão direito em "Remover do banco de dados"
5. Ctrl + S para salvar
6. Aproveitar

Parece que o comando deve estar sem o cobertor quadrado

EXEC sp_msforeachtable 'drop table ?'

Para mim, a maneira mais fácil:

--First delete all constraints

DECLARE @sql NVARCHAR(MAX);
SET @sql = N'';

SELECT @sql = @sql + N'
ALTER TABLE ' + QUOTENAME(s.name) + N'.'
+ QUOTENAME(t.name) + N' DROP CONSTRAINT '
+ QUOTENAME(c.name) + ';'
FROM sys.objects AS c
INNER JOIN sys.tables AS t
ON c.parent_object_id = t.[object_id]
INNER JOIN sys.schemas AS s 
ON t.[schema_id] = s.[schema_id]
WHERE c.[type] IN ('D','C','F','PK','UQ')
ORDER BY c.[type];

EXEC sys.sp_executesql @sql;

-- Then drop all tables

exec sp_MSforeachtable 'DROP TABLE ?'

Spot on !!

Você pode usar a consulta abaixo para remover todas as tabelas do banco de dados

EXEC sp_MSforeachtable @ command1 = "DROP TABLE?"

Feliz codificação!

Que tal descartar o banco de dados inteiro e criá-lo novamente? Isso funciona para mim.

DROP DATABASE mydb;
CREATE DATABASE mydb;

Sei que agora é uma publicação antiga, mas tentei todas as respostas aqui em vários bancos de dados e descobri que todas elas funcionam às vezes, mas não o tempo todo, para várias peculiaridades (só posso assumir) do SQL Server.

Eventualmente, eu vim com isso. Eu testei isso em todos os lugares (em geral) que posso e funciona (sem nenhum procedimento de armazenamento oculto).

Para observação principalmente no SQL Server 2014. (mas a maioria das outras versões que tentei também parece funcionar bem).

Eu tentei enquanto loops e nulos etc etc, cursores e várias outras formas, mas eles sempre parecem falhar em alguns bancos de dados, mas não em outros, sem motivo óbvio.

Obter uma contagem e usá-la para iterar sempre parece funcionar em tudo que eu testei.

USE [****YOUR_DATABASE****]
GO

SET ANSI_NULLS ON
GO

SET QUOTED_IDENTIFIER ON
GO

-- Drop all referential integrity constraints --
-- Drop all Primary Key constraints.          --

DECLARE @sql  NVARCHAR(296)
DECLARE @table_name VARCHAR(128)

DECLARE @constraint_name VARCHAR(128)
SET @constraint_name = ''

DECLARE @row_number INT

SELECT @row_number = Count(*) FROM INFORMATION_SCHEMA.REFERENTIAL_CONSTRAINTS rc1
LEFT JOIN INFORMATION_SCHEMA.TABLE_CONSTRAINTS tc2 ON tc2.CONSTRAINT_NAME = rc1.CONSTRAINT_NAME

WHILE @row_number > 0
BEGIN
    BEGIN
        SELECT TOP 1 @table_name = tc2.TABLE_NAME, @constraint_name = rc1.CONSTRAINT_NAME FROM INFORMATION_SCHEMA.REFERENTIAL_CONSTRAINTS rc1
        LEFT JOIN INFORMATION_SCHEMA.TABLE_CONSTRAINTS tc2 ON tc2.CONSTRAINT_NAME = rc1.CONSTRAINT_NAME
        AND rc1.CONSTRAINT_NAME > @constraint_name
        ORDER BY rc1.CONSTRAINT_NAME
        SELECT @sql = 'ALTER TABLE [dbo].[' + RTRIM(@table_name) +'] DROP CONSTRAINT [' + RTRIM(@constraint_name)+']'
        EXEC (@sql)
        PRINT 'Dropped Constraint: ' + @constraint_name + ' on ' + @table_name
        SET @row_number = @row_number - 1
    END
END
GO

-- Drop all tables --

DECLARE @sql  NVARCHAR(156)
DECLARE @name VARCHAR(128)
SET @name = ''

DECLARE @row_number INT

SELECT @row_number = Count(*) FROM sysobjects WHERE [type] = 'U' AND category = 0

WHILE @row_number > 0
BEGIN
    SELECT @name = (SELECT TOP 1 [name] FROM sysobjects WHERE [type] = 'U' AND category = 0 AND [name] > @name ORDER BY [name])
    SELECT @sql = 'DROP TABLE [dbo].[' + RTRIM(@name) +']'
    EXEC (@sql)
    PRINT 'Dropped Table: ' + @name
    SET @row_number = @row_number - 1
END
GO

Para tabelas temporais , é um pouco mais complicado, pois pode haver algumas chaves estrangeiras e também a exceção:

Drop table operation failed on table XXX because it is not a supported operation on system-versioned temporal tables

O que você pode usar é:

-- Disable constraints (foreign keys)
EXEC sp_MSForEachTable 'ALTER TABLE ? NOCHECK CONSTRAINT ALL'
GO

-- Disable system versioning (temporial tables)
EXEC sp_MSForEachTable '
 IF OBJECTPROPERTY(object_id(''?''), ''TableTemporalType'') = 2
  ALTER TABLE ? SET (SYSTEM_VERSIONING = OFF)
'
GO

-- Removing tables
EXEC sp_MSForEachTable 'DROP TABLE ?'
GO