Eu uso o git como um backup para o meu sistema Windows e tem sido incrivelmente útil. Na parte inferior da postagem, mostro os scripts que utilizo para configurar em um sistema Windows. O uso do git como backup para qualquer sistema oferece duas grandes vantagens:
- Ao contrário das soluções comerciais, muitas vezes usam seu próprio formato proprietário, seu backup está em um formato de código aberto amplamente suportado e muito bem documentado. Isso fornece controle total dos seus dados. É muito fácil ver quais arquivos foram alterados e quando. Se você deseja truncar seu histórico, também pode fazer isso. Deseja eliminar algo da sua história? Sem problemas. Obter uma versão do seu arquivo de volta é tão simples quanto qualquer comando git.
- Quantos espelhos quiser, e todos podem ter tempos de backup personalizados. Você obterá o seu espelho local, que não é sobrecarregado pelo tráfego lento da Internet e, assim, fornece (1) a capacidade de fazer backups mais frequentes ao longo do dia e (2) um tempo de restauração rápido. (Os backups frequentes são uma grande vantagem, porque eu acho que a maior parte do tempo que perco um documento é por erro do usuário. Por exemplo, seu filho sobrescreve acidentalmente um documento em que ele está trabalhando nas últimas 5 horas.) Mas você receberá seu espelho remoto, que oferece a vantagem da proteção de dados em caso de desastre ou roubo local. E suponha que você queira que o seu espelho remoto faça backup em um momento personalizado para economizar sua largura de banda da Internet? Sem problemas.
Conclusão: um backup do git oferece uma quantidade incrível de poder no controle de como seus backups acontecem.
Eu configurei isso no meu sistema Windows. O primeiro passo é criar o repositório git local onde você confirmará todos os seus dados locais. Eu recomendo usar um segundo disco rígido local, mas usar o mesmo disco rígido funcionará (mas é esperado que você o empurre para algum lugar remoto, ou você ferrou se o disco rígido morrer).
Você primeiro precisará instalar o cygwin (com rsync) e também instalar o git para Windows: http://git-scm.com/download/win
Em seguida, crie seu repositório git local (execute apenas uma vez):
init-repo.bat:
@echo off
REM SCRIPT PURPOSE: CREATE YOUR LOCAL GIT-REPO (RUN ONLY ONCE)
REM Set where the git repository will be stored
SET GBKUP_LOCAL_MIRROR_HOME=E:\backup\mirror
REM Create the backup git repo.
SET GIT_PARAMS=--git-dir=%GBKUP_LOCAL_MIRROR_HOME%\.git --work-tree=%GBKUP_LOCAL_MIRROR_HOME%
mkdir %GBKUP_LOCAL_MIRROR_HOME%
git %GIT_PARAMS% init
git %GIT_PARAMS% config core.autocrlf false
git %GIT_PARAMS% config core.ignorecase false
git %GIT_PARAMS% config core.fileMode false
git %GIT_PARAMS% config user.email backup@yourComputerName
git %GIT_PARAMS% config user.name backup
REM add a remote to the git repo. Make sure you have set myRemoteServer in ~/.ssh/config
REM The path on the remote server will vary. Our remote server is a Windows machine running cygwin+ssh.
REM For better security, you could install gitolite on the remote server, and forbid any non-fast-forward merges, and thus stop a malicious user from overwriting your backups.
git %GIT_PARAMS% remote add origin myRemoteServer:/cygdrive/c/backup/yourComputerName.git
REM treat all files as binary; so you don't have to worry about autocrlf changing your line endings
SET ATTRIBUTES_FILE=%GBKUP_LOCAL_MIRROR_HOME%\.git\info\attributes
echo.>> %ATTRIBUTES_FILE%
echo *.gbkuptest text>> %ATTRIBUTES_FILE%
echo * binary>> %ATTRIBUTES_FILE%
REM compression is often a waste of time with binary files
echo * -delta>> %ATTRIBUTES_FILE%
REM You may need to get rid of windows new lines. We use cygwin's tool
C:\cygwin64\bin\dos2unix %ATTRIBUTES_FILE%
Em seguida, temos nosso wrapper de script de backup, que será chamado regularmente pelo Windows Scheduler:
gbackup.vbs:
' A simple vbs wrapper to run your bat file in the background
Set oShell = CreateObject ("Wscript.Shell")
Dim strArgs
strArgs = "cmd /c C:\opt\gbackup\gbackup.bat"
oShell.Run strArgs, 0, false
Em seguida, temos o próprio script de backup que o wrapper chama:
gbackup.bat:
@echo off
REM Set where the git repository will be stored
SET GBKUP_LOCAL_MIRROR_HOME=E:\backup\mirror
REM the user which runs the scheduler
SET GBKUP_RUN_AS_USER=yourWindowsUserName
REM exclude file
SET GBKUP_EXCLUDE_FILE=/cygdrive/c/opt/gbackup/exclude-from.txt
SET GBKUP_TMP_GIT_DIR_NAME=git-renamed
for /f "delims=" %%i in ('C:\cygwin64\bin\cygpath %GBKUP_LOCAL_MIRROR_HOME%') do set GBKUP_LOCAL_MIRROR_CYGWIN=%%i
REM rename any .git directories as they were (see below command)
for /r %GBKUP_LOCAL_MIRROR_HOME% %%i in (%GBKUP_TMP_GIT_DIR_NAME%) do ren "%%i" ".git" 2> nul
SET RSYNC_CMD_BASE=C:\cygwin64\bin\rsync -ahv --progress --delete --exclude-from %GBKUP_EXCLUDE_FILE%
REM rsync all needed directories to local mirror
%RSYNC_CMD_BASE% /cygdrive/c/dev %GBKUP_LOCAL_MIRROR_CYGWIN%
%RSYNC_CMD_BASE% /cygdrive/c/Users/asmith %GBKUP_LOCAL_MIRROR_CYGWIN%
%RSYNC_CMD_BASE% /cygdrive/c/Users/bsmith %GBKUP_LOCAL_MIRROR_CYGWIN%
cacls %GBKUP_LOCAL_MIRROR_HOME% /t /e /p %GBKUP_RUN_AS_USER%:f
REM rename any .git directories as git will ignore the entire directory, except the main one
for /r %GBKUP_LOCAL_MIRROR_HOME% %%i in (.git) do ren "%%i" "%GBKUP_TMP_GIT_DIR_NAME%" 2> nul
ren %GBKUP_LOCAL_MIRROR_HOME%\%GBKUP_TMP_GIT_DIR_NAME% .git
REM finally commit to git
SET GIT_PARAMS=--git-dir=%GBKUP_LOCAL_MIRROR_HOME%\.git --work-tree=%GBKUP_LOCAL_MIRROR_HOME%
SET BKUP_LOG_FILE=%TMP%\git-backup.log
SET TO_LOG=1^>^> %BKUP_LOG_FILE% 2^>^&1
echo ===========================BACKUP START=========================== %TO_LOG%
For /f "tokens=2-4 delims=/ " %%a in ('date /t') do (set mydate=%%c-%%a-%%b)
For /f "tokens=1-2 delims=/:" %%a in ('time /t') do (set mytime=%%a%%b)
echo %mydate%_%mytime% %TO_LOG%
echo updating git index, committing, and then pushing to remote %TO_LOG%
REM Caution: The --ignore-errors directive tells git to continue even if it can't access a file.
git %GIT_PARAMS% add -Av --ignore-errors %TO_LOG%
git %GIT_PARAMS% commit -m "backup" %TO_LOG%
git %GIT_PARAMS% push -vv --progress origin master %TO_LOG%
echo ===========================BACKUP END=========================== %TO_LOG%
Temos o arquivo exclude-from.txt, onde colocamos todos os arquivos para ignorar:
exclude-from.txt:
target/
logs/
AppData/
Downloads/
trash/
temp/
.idea/
.m2/
.IntelliJIdea14/
OLD/
Searches/
Videos/
NTUSER.DAT*
ntuser.dat*
Você precisará ir a qualquer repositório remoto e executar um 'git init --bare' neles. Você pode testar o script executando o script de backup. Supondo que tudo funcione, vá para o Windows Scheduler e aponte um backup de hora em hora para o arquivo vbs. Depois disso, você terá um histórico do git do seu computador a cada hora. É extremamente conveniente - todos os usuários excluem acidentalmente uma seção de texto e perdem isso? Basta verificar o seu repositório git.