Comando para encontrar a interface de rede para IP

Com ipconfigposso mostrar a lista de adaptadores de rede e suas configurações, por exemplo, o endereço IP.

Estou procurando um comando reverso que exibe o nome do adaptador de rede para um determinado endereço IP.

Eu tentei filtrar a saída de ipconfigcom um comando como, ipconfig | find "192.168.2.4"mas o nome do adaptador se foi.

Minha saída de ipconfigé (a parte complicada parece que tenho vários endereços em um adaptador aqui):

Windows IP Configuration


Ethernet adapter Local Area Connection:

   Connection-specific DNS Suffix  . :
   Link-local IPv6 Address . . . . . : fe80::xxxx:xxxx:xxxx:xxxx%11
   IPv4 Address. . . . . . . . . . . : 192.168.2.4
   Subnet Mask . . . . . . . . . . . : 255.255.255.0
   IPv4 Address. . . . . . . . . . . : 192.168.178.20
   Subnet Mask . . . . . . . . . . . : 255.255.255.0
   Default Gateway . . . . . . . . . : 192.168.178.1
                                       192.168.2.1

Ethernet adapter VMware Network Adapter VMnet1:
...

Como exibir o nome de um adaptador de rede para um determinado endereço IP?

Esta solução é que não exige quaisquer comandos externos ( pcre2grep, sed, etc.).

Use o seguinte arquivo em lotes (getname.cmd):

@echo off
setlocal
setlocal enabledelayedexpansion
set "_adapter="
set "_ip="
for /f "tokens=1* delims=:" %%g in ('ipconfig /all') do (
  set "_tmp=%%~g"
  if "!_tmp:adapter=!"=="!_tmp!" (
    if not "!_tmp:IPv4 Address=!"=="!_tmp!" (
      for %%i in (%%~h) do (
      if not "%%~i"=="" set "_ip=%%~i"
      )
    set "_ip=!_ip:(Preferred)=!"
    if "!_ip!"=="%1" (
        @echo !_adapter!
      )
    )
  ) else (
    set "_ip="
    set "_adapter=!_tmp:*adapter =!"
  )
)
endlocal

Uso:

getname ipaddress

Exemplo:

F:\test>getname 192.168.42.78
Local Area Connection 2
F:\test>

Leitura adicional

• Um índice AZ da linha de comando do Windows CMD - uma excelente referência para todos os itens relacionados à linha de cmd do Windows.
• for / f - comando de loop em relação aos resultados de outro comando.
• ipconfig - Configurar IP (configuração do protocolo Internet)

Você pode usar este liner PS one:

$addr='192.168.2.4'; get-wmiobject Win32_NetworkAdapterConfiguration |? {$_.ipaddress -contains $addr} |select Description |% {$_.Description}

Para usá-lo diretamente da linha de comando:

powershell "$addr='192.168.2.4'; get-wmiobject Win32_NetworkAdapterConfiguration |? {$_.ipaddress -contains $addr} |select Description |% {$_.Description}"

ou se você quiser reutilizá-lo, coloque-o em um script e torne o endereço um parâmetro

Edit: para obter um nome como mostra em Win / Ipconfig:

$addr='192.168.2.4'; 
$netconf = get-wmiobject Win32_NetworkAdapterConfiguration |? {$_.ipaddress -contains $addr};
$netconf |% {$_.GetRelated("win32_NetworkAdapter")} | select NetConnectionID |%{$_.NetConnectionID}

(a atribuição a variáveis ​​intermediárias é apenas para torná-lo um pouco mais legível)

Estou procurando um comando reverso que exibe o nome do adaptador de rede para um determinado endereço IP.

Com base em tudo o que tentei, parece que você diz que precisa obter essas informações somente do endereço IP que você já especificou em seu exemplo.

PROMPT INTERATIVO PARA ENDEREÇO ​​IP PARA OBTER O NOME DA CONEXÃO DE REDE

(Use WMICe faça alguns FORciclos tokene delimanálises em lote para obter o nome da conexão de rede para um endereço IP especificado.)

(O valor do resultado ecoará em uma janela de comando e em uma janela de caixa de mensagem. É tudo script em lote, mas cria dinamicamente algumas funções de script VBS para simplificar o processo para qualquer pessoa que precise.)

@ECHO ON

:SetTempFiles
SET tmpIPaddr=%tmp%\~tmpipaddress.vbs
SET tmpNetConName1=%tmp%\~tmpNetConName1.txt
SET tmpNetConName2=%tmp%\~tmpNetConName2.txt
SET tmpBatFile=%tmp%\~tmpBatch.cmd
SET tmpVBNetCon=%tmp%\~tmpVBNetCon.vbs

IF EXIST "%tmpIPaddr%" DEL /F /Q "%tmpIPaddr%"
IF EXIST "%tmpNetConName1%" DEL /Q /F "%tmpNetConName1%"
IF EXIST "%tmpNetConName2%" DEL /Q /F "%tmpNetConName2%"
IF EXIST "%tmpBatFile%" DEL /Q /F "%tmpBatFile%"
IF EXIST "%tmpVBNetCon%" DEL /Q /F "%tmpVBNetCon%"

:InputBox
SET msgboxTitle=IP ADDRESS
SET msgboxLine1=Enter the IP address to get its Windows connection name
>"%tmpIPaddr%" ECHO wsh.echo inputbox("%msgboxLine1%","%msgboxTitle%")
FOR /F "tokens=*" %%N IN ('cscript //nologo "%tmpIPaddr%"') DO CALL :setvariables %%N
GOTO EOF

:setvariables
SET IPAddress=%~1
FOR /F "USEBACKQ TOKENS=3 DELIMS=," %%A IN (`"WMIC NICCONFIG GET IPADDRESS,MACADDRESS /FORMAT:CSV | FIND /I "%IPAddress%""`) DO (SET MACAddress=%%~A)
FOR /F "USEBACKQ TOKENS=3 DELIMS=," %%B IN (`"WMIC NIC GET MACADDRESS,NETCONNECTIONID /FORMAT:CSV | FIND /I "%MACAddress%""`) DO ECHO(%%~B>>"%tmpNetConName1%"

::: Parse Empty Lines
FINDSTR "." "%tmpNetConName1%">"%tmpNetConName2%"

::: Build Dynamic Batch with ECHO'd Network Connection Value
FOR /F "tokens=*" %%C IN (%tmpNetConName2%) DO ECHO ECHO %%~C>>"%tmpBatFile%"
IF NOT EXIST "%tmpBatFile%" GOTO :NullExit
START "" "%tmpBatFile%"

::: Build Dynamic VBS with Message Box Network Connection Value
FOR /F "tokens=*" %%C IN (%tmpNetConName2%) DO (SET vbNetconName=%%~C)
ECHO msgbox "%vbNetconName%",0,"%vbNetconName%">"%tmpVBNetCon%"
START /B "" "%tmpVBNetCon%"
EXIT /B

:NullExit
ECHO msgbox "Cannot find MAC Address, check to confirm IP Address was correct.",0,"Invalid IP">"%tmpVBNetCon%"
START /B "" "%tmpVBNetCon%"
EXIT /B

ALL ONE-LINERS

WINDOWS NATIVOS SOMENTE COM REDE TODAS AS INTERFACES (TODOS OS ENDEREÇOS IPv4)

NETSH INT IP SHOW CONFIG | FINDSTR /R "Configuration for interface.* Address.*[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*"

WINDOWS NATIVOS SOMENTE COM IPCONFIG TODAS AS INTERFACES (TODOS OS ENDEREÇOS IPv4)

IPCONFIG | FINDSTR /R "Ethernet* Address.*[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*"

USANDO PCRE2GREP (por @SalvoF)

ENDEREÇO ​​IP ÚNICO ESPECIFICADO

netsh interface ipv4 show address | pcre2grep -B2 "192\.168\.2\.4" | FIND /V "DHCP"

ENCONTRE TODOS OS ENDEREÇOS IP

netsh interface ip show config | pcre2grep -B2 ^(?:[0-9]{1,3}\.){3}[0-9]{1,3}$ | FIND /V "DHCP" | FIND /V "Gate" | FIND /V "Metric" | FIND /V "Subnet"

ENCONTRE TODOS OS ENDEREÇOS IP (Regex limpo (por @SalvoF))

netsh interface ip show config | pcre2grep "^[A-Z]|IP.*([0-9]{1,3}(\.|)){4}"

Observe que o que pcre2grepeu tentei é por @SalvoF, [+1]como ele sugeriu, mas usar o .... FIND /Vpara remover a linha acima contém DHCPo resultado desejado, conforme descrito. Eu usei NETSHe não IPCONFIGtambém.

Para ser mais preciso, seguindo o exemplo do OP, eu usaria sed, que pode ser encontrado na \usr\local\wbinpasta deste arquivo compactado (projeto UnxUtils).

ipconfig | sed -rn "/^[A-Z]/h;/192.168.2.4/{g;s/.* adapter (.*):/\1/p;}"

-nsuprime linhas não correspondentes; o primeiro padrão encontra qualquer linha que comece com letra maiúscula e a hcoloca em espera; a segunda correspondência está no número IP desejado: nesse momento, o nome da interface de retenção de linha é chamado ( g), o texto inicial extra é retirado ( s) e impresso ( p).

Apenas para constar, aqui está outra solução em lote, que explora a expansão atrasada da %ERRORLEVEL%variável do sistema:

@echo off
setlocal EnableDelayedExpansion
for /f "delims=" %%L in ('ipconfig') do (
    echo %%L | findstr /r "^[A-Z]" 1>NUL
    if !errorlevel! == 0 set "_int=%%L"
    echo %%L | findstr /c:%1 1>NUL
    if !errorlevel! == 0 (
       set "_int=!_int::=!"
       echo !_int:* adapter =!
       goto:eof
    )
)

Pode ser invocado desta maneira: find_int.cmd 192.168.1.100

Obrigado pelo esforço de todos. Parece que existem vários obstáculos:

• o número de endereços IP atribuídos a um adaptador
• o idioma do sistema operacional

Todo o -Bxmaterial Regex parece quebrar facilmente, então procurei por algo que pudesse me implementar e criei o seguinte programa C #, que usa o endereço IP como parâmetro ( IP2Adapter <IP>):

using System;
using System.Net.NetworkInformation;
using System.Net.Sockets;

namespace IP2Adapter
{
    class Program
    {
        static void Main(string[] args)
        {
            var adapters = NetworkInterface.GetAllNetworkInterfaces();
            foreach (var adapter in adapters)
            {
                var ipProps = adapter.GetIPProperties();
                foreach (var ip in ipProps.UnicastAddresses)
                {
                    if ((adapter.OperationalStatus == OperationalStatus.Up)
                        && (ip.Address.AddressFamily == AddressFamily.InterNetwork))
                    {
                        if (ip.Address.ToString() == args[0])
                        Console.Out.WriteLine(adapter.Name);
                    }
                }
            }
        }
    }
}

No Windows 10 Powershell, isso pode ser alcançado com o seguinte:

Get-NetIPAddress -IPAddress '192.168.2.4' | %{$_.InterfaceAlias};

Isso dará um resultado como Wi-Fi.

Onde você pode substituir InterfaceAliasqualquer outra propriedade do objeto.

Para obter todas as propriedades, simplesmente omitir os tubos, e execute: Get-NetIPAddress -IPAddress '192.168.2.4'.

Propriedades relacionadas com outro adaptador de rede (tal como Descrição) normalmente podem ser consultados com base em InterfaceAliasou InterfaceIndex, por exemplo .:

Get-NetAdapter -InterfaceAlias Wi-Fi | %{$_.InterfaceDescription};

Que lhe dará algo como: Intel(R) Dual Band Wireless-AC 8265.

Leia mais sobre os documentos: https://docs.microsoft.com/en-us/powershell/module/nettcpip/get-netipaddress?view=win10-ps