Exportar uma planilha do Excel para um arquivo de texto de largura fixa?

O Excel tem a funcionalidade de importar arquivos de texto de largura fixa, onde apresenta uma caixa de diálogo que permite escolher onde o início e o fim dos campos são colocados nas colunas.

Também possui funcionalidade em que, dada uma planilha existente, você pode exportar para um arquivo de texto de largura fixa?

Em caso afirmativo, como faço para acessar isso? Eu tentei usar Salvar como e escolher Arquivo de texto, mas parece salvar apenas como delimitado por tabulações, o que não me ajuda.

Este é o Excel 2003, se for o caso.

Eu acho que o mais próximo que você pode obter da funcionalidade nativa do Excel é Salvar como | Texto formatado (delimitado por espaço) (* .prn) . Ele determinará automaticamente as larguras e inserirá espaços para preencher essa largura conforme necessário.

Além disso, você precisa ter uma macro ou outro suplemento que permita fazer mais.

Se você possui o Office Professional, pode abrir seu arquivo do Excel no Access e, em seguida, Exportar do Access. O Access permitirá especificar um layout de largura fixa para o arquivo exportado e fornece controles extremamente granulares para especificar essas larguras.

Uau, eu mesmo ia fazer essa pergunta, mas já foi feita. Toda saída da área de transferência do Excel é tabdelimitada por padrão. Isso é meio irritante para a saída de texto simples "real" quando você tem uma fonte de largura fixa, mas não necessariamente o suporte ao delimitador de tabulação.

De qualquer forma, eu encontrei e modifiquei uma pequena macro do Excel que copiará a região atualmente selecionada como uma tabela ASCII de colunas de largura fixa simples - da seguinte maneira:

187712 201 37 0,18   
2525 580 149 0,25   
136829 137 43 0,31   

Aqui está o código da macro. Para usá-lo, ative a guia Desenvolvedor nas Opções do Excel, se você estiver usando o Excel 2007 ou posterior.

Sub CopySelectionToClipboardAsText()

   ' requires a reference to "Windows Forms 2.0 Object Library"
   ' add it via Tools / References; if it does not appear in the list
   ' manually add it as the path C:\Windows\System32\FM20.dll

    Dim r As Long, c As Long
    Dim selectedrows As Integer, selectedcols As Integer

    Dim arr
    arr = ActiveSheet.UsedRange
    selectedrows = UBound(arr, 1)
    selectedcols = UBound(arr, 2)

    Dim temp As Integer
    Dim cellsize As Integer
    cellsize = 0
    For c = 1 To selectedcols
        temp = Len(CStr(Cells(1, c)))
        If temp > cellsize Then
            cellsize = temp
        End If
    Next c
    cellsize = cellsize + 1

    Dim line As String
    Dim output As String

    For r = 1 To selectedrows
        line = Space(selectedcols * cellsize)
        For c = 1 To selectedcols
            Mid(line, c * cellsize - cellsize + 1, cellsize) = Cells(r, c)
        Next c
        output = output + line + Chr(13) + Chr(10)
    Next r

    Dim MyData As MSForms.DataObject
    Set MyData = New DataObject
    MyData.SetText output
    MyData.PutInClipboard

    MsgBox "The current selection was formatted and copied to the clipboard"

End Sub

Primeiro, formate seus dados como Courier New (ou alguma outra fonte de largura fixa). Salve como .prn e você obterá uma largura fixa verdadeira.

Expandindo a resposta de Jeff Atwood, uma vez que não me permitia comentar lá:

Modifiquei sua macro para definir a largura da coluna para a célula mais larga nessa coluna e ter cada coluna sua própria largura. Sua macro encontrou apenas a célula mais larga na primeira linha e depois definiu a largura de todas as colunas.

Sub CopySelectionToClipboardAsText()

   ' requires a reference to "Windows Forms 2.0 Object Library"
   ' add it via Tools / References; if it does not appear in the list
   ' manually add it as the path C:\Windows\System32\FM20.dll

    Dim r As Long, c As Long, linesize As Long
    Dim selectedrows As Integer, selectedcols As Integer

    Dim arr
    arr = ActiveSheet.UsedRange
    selectedrows = UBound(arr, 1)
    selectedcols = UBound(arr, 2)
    ReDim CellSizes(1 To selectedcols, 2) As Integer

    Dim temp As Integer
    Dim cellsize As Integer
    linesize = 0
    For c = 1 To selectedcols
        cellsize = 0
        For r = 1 To selectedrows
            temp = Len(CStr(Cells(r, c)))
            If temp > cellsize Then
                cellsize = temp
            End If
        Next
        CellSizes(c, 0) = cellsize + 1
        CellSizes(c, 1) = linesize
        linesize = linesize + cellsize + 1
    Next c

    Dim line As String
    Dim output As String

    For r = 1 To selectedrows
        line = Space(linesize)
        For c = 1 To selectedcols
            Mid(line, CellSizes(c, 1) + 1, CellSizes(c, 0)) = Cells(r, c)
        Next c
        output = output + line + Chr(13) + Chr(10)
    Next r

    Dim MyData As MSForms.DataObject
    Set MyData = New DataObject
    MyData.SetText output
    MyData.PutInClipboard

    MsgBox "The current selection was formatted and copied to the clipboard"

End Sub

Este é um assassino para mim. Tem algumas opções também.

http://www.sensefulsolutions.com/2010/10/format-text-as-table.html

Funciona com o Access fora da caixa: https://support.office.com/en-ie/article/export-data-to-a-text-file-f72dfc38-a8a0-4c5b-8c2c-bf2950814140#bmsteps com isso Como eu o manusei de maneira fácil e rápida - melhor do que com o Excel. No meu caso, foi uma conversão da tabela.