Como mostro os participantes obrigatórios na cópia impressa dos convites para reunião?

Imprimo cada reunião convidando meu chefe para reuniões. Ele gosta de ver quem é o organizador e quem são os participantes. Agora, no Outlook 2013, quando imprimo o convite da reunião, ele mostra apenas o nome do organizador e não os participantes necessários e os participantes opcionais. Existe uma função no Outlook 2013 que eu preciso ativar ou alterar?

quando imprimo o convite da reunião, só mostra o nome do organizador

e não os participantes obrigatórios e participantes opcionais.

O Outlook oferece apenas suporte limitado para isso. Você pode usar as seguintes soluções alternativas.

Criar uma lista de participantes da reunião e respostas

Este exemplo de código obtém os detalhes do compromisso e os participantes (juntamente com suas respostas) e os insere em um novo formulário de mensagem do Outlook, que você pode imprimir, enviar ou copiar os dados para uso em outros aplicativos.

Testado no Outlook 2007 e no Outlook 2010. Ele deve funcionar no Outlook 2000 e superior. Observe que o código acionará o prompt de segurança.

Testado no Outlook 2007 e no Outlook 2010. Ele deve funcionar no Outlook 2000 e superior. Observe que o código acionará o prompt de segurança.

Obter macro da lista de participantes da reunião

Para usar, abra o Editor VBA do Outlook pressionando Alt + F11. Clique com o botão direito do mouse no Projeto1 no painel esquerdo e escolha Inserir> Módulo. Copie este código e cole-o no módulo.

Obtenha a função GetCurrentItem do Outlook VBA: trabalhe com o item aberto ou o item selecionado e cole-o no final do módulo.

Em seguida, selecione ou abra uma reunião organizada e execute a macro para criar uma mensagem contendo os detalhes da reunião. As contagens totais de aceito, recusado, provisório e sem resposta são adicionadas à lista.

Sub GetAttendeeList()

Dim objApp As Outlook.Application
Dim objItem As Object
Dim objAttendees As Outlook.Recipients
Dim objAttendeeReq As String
Dim objAttendeeOpt As String
Dim objOrganizer As String
Dim dtStart As Date
Dim dtEnd As Date
Dim strSubject As String
Dim strLocation As String
Dim strNotes As String
Dim strMeetStatus As String
Dim strCopyData As String
Dim strCount  as String 

On Error Resume Next

Set objApp = CreateObject("Outlook.Application")
Set objItem = GetCurrentItem()
Set objAttendees = objItem.Recipients

On Error GoTo EndClean:

' Is it an appointment
If objItem.Class <> 26 Then
  MsgBox "This code only works with meetings."
  GoTo EndClean:
End If

' Get the data
dtStart = objItem.Start
dtEnd = objItem.End
strSubject = objItem.Subject
strLocation = objItem.Location
strNotes = objItem.Body
objOrganizer = objItem.Organizer
objAttendeeReq = ""
objAttendeeOpt = ""

' Get The Attendee List
For x = 1 To objAttendees.Count
   strMeetStatus = ""
   Select Case objAttendees(x).MeetingResponseStatus
     Case 0
       strMeetStatus = "No Response (or Organizer)"
       ino = ino + 1
     Case 1
       strMeetStatus = "Organizer"
       ino = ino + 1
     Case 2
       strMeetStatus = "Tentative"
       it = it + 1
     Case 3
       strMeetStatus = "Accepted"
       ia = ia + 1
     Case 4
       strMeetStatus = "Declined"
       ide = ide + 1
   End Selec

   If objAttendees(x).Type = olRequired Then
      objAttendeeReq = objAttendeeReq & objAttendees(x).Name & vbTab & strMeetStatus & vbCrLf
   Else
      objAttendeeOpt = objAttendeeOpt & objAttendees(x).Name & vbTab & strMeetStatus & vbCrLf
   End If
Next


 strCopyData = "Organizer: " & objOrganizer & vbCrLf & "Subject:  " & strSubject & vbCrLf & _
  "Location: " & strLocation & vbCrLf & "Start:    " & dtStart & vbCrLf & "End:     " & dtEnd & _
  vbCrLf & vbCrLf & "Required: " & vbCrLf & objAttendeeReq & vbCrLf & "Optional: " & _
  vbCrLf & objAttendeeOpt & vbCrLf & "NOTES " & vbCrLf & strNotes

 strCount = "Accepted: " & ia & vbCrLf & _
  "Declined: " & ide & vbCrLf & _
  "Tentative: " & it & vbCrLf & _
  "No response: " & ino

Set ListAttendees = Application.CreateItem(olMailItem)
  ListAttendees.Body = strCopyData & vbCrLf & strCount
  ListAttendees.Display

EndClean:
Set objApp = Nothing
Set objItem = Nothing
Set objAttendees = Nothing
End Sub

Fonte Criar uma lista de participantes da reunião e respostas

Copiando a lista de participantes com respostas

O Outlook 2010 e o Outlook 2013 permitem que você copie as informações do participante para uso direto em outro aplicativo. Para copiar as informações, abra a reunião, expanda o botão Rastreamento e escolha "Copiar status para a área de transferência". Agora você pode colar a lista de participantes em outro aplicativo.

Você pode copiar as respostas dos participantes no Outlook 2010 e no Outlook 2013 e colá-las em outro aplicativo.

Nota 1: A lista copiada é delimitada por tabulações e pode não ser adequada para uso diretamente no Word. Se você colar primeiro no Excel, copie do Excel e cole no Word, você terminará com uma tabela que pode ser formatada facilmente no Word.

Observação 2: se você quiser atualizar as respostas para que elas reflitam se elas realmente apareceram ou não, consulte Acompanhamento da reunião manual

Fonte Imprimir ou copiar a lista de participantes da reunião

Imprimindo a lista de participantes com respostas

O próprio Outlook não inclui as respostas dos participantes ao imprimir a reunião. Uma solução alternativa seria usar o método de cópia conforme descrito acima e imprimi-lo no aplicativo em que você colou a imagem ou a lista.

Esta solução alternativa acima pode não ser prática se você precisar fazer muito isso e uma imagem de captura de tela parecer totalmente fora do lugar quando usada em um relatório de reunião profissional.

Uma solução mais simplificada pode ser obtida ao usar um suplemento chamado Print de participantes da IMIBO . Com este add-in você pode…

- print directly the names of the people who have been invited to a meeting.
- print directly response status – Accepted, Declined, Tentative, None
- save/export report directly to Microsoft® Office Word
- save/export report directly to Microsoft® Office Excel
- save/export report as RTF file
- save/export report as Adobe PDF file
- save/export report as HTML file

Observe que o suplemento está disponível como software de avaliação e uma licença deve ser adquirida.

Fonte Imprimir ou copiar a lista de participantes da reunião