Como determino se meu sistema é o Windows 10 usando a linha de comando? [duplicado]

Estou trabalhando com o InstallAnywhere, um programa antigo para criar instaladores. Gostaria de instalar um arquivo específico, apenas no caso do Windows XP e Windows Vista.

Devido às limitações do InstallAnywhere, isso não é possível. Só posso decidir excluir o arquivo depois que ele já estiver instalado, com base em uma regra.

Dentro dessa regra, posso verificar a plataforma na qual estou executando, o que me dá a possibilidade de verificar o Windows XP, Windows Vista, Windows 7, etc., mas não o Windows 10. Não posso dizer "Executar isso" ação quando o sistema não é XP ou Vista ", então preciso dizer" Execute esta ação em todas as plataformas que não sejam XP ou Vista ".

No entanto, eu posso iniciar comandos de linha de comando e pegar o resultado, então aqui está minha pergunta: existe um comando que eu possa usar para determinar se estou trabalhando em um sistema Windows 10?

Existe um comando para determinar se estou trabalhando em um sistema Windows 10?

Você pode usar wmic.

O comando a seguir retornará a versão do Windows.

wmic os get Caption | findstr /v Caption

Exemplo de saída:

F:\test>wmic os get Caption | findstr /v Caption
Microsoft Windows 7 Home Premium

Se você quiser um pouco mais de informações, poderá usar o seguinte arquivo em lotes (GetOS.cmd), que será recuperado e exibido:

• Versão do sistema operacional
• Versão principal do Service Pack
• Arquitetura (64 ou 32 bits)

@echo off
setlocal
setlocal enabledelayedexpansion
set _os=
set _sp=
rem use findstr to strip blank lines from wmic output
rem get OS
for /f "usebackq skip=1 tokens=3" %%i in (`wmic os get caption ^| findstr /r /v "^$"`) do (
  set "_os=%%i"
  )
rem get Service Pack
for /f "usebackq skip=1 tokens=*" %%i in (`wmic os get ServicePackMajorVersion ^| findstr /r /v "^$"`) do (
  set "_sp=%%i"
  )
rem get Architecture
for /f "usebackq skip=1 tokens=*" %%i in (`wmic OS get OSArchitecture ^| findstr /r /v "^$"`) do (
  set "_bits=%%i"
  )
echo Operating System Version: %_os%
echo Service Pack Major Version: %_sp%
echo Architecture: %_bits%
endlocal

A versão do sistema operacional é armazenada %_os, a versão principal do Service Pack é armazenada %_sp%e a arquitetura é armazenada em %_bits%.

Notas:

• Não completamente testado, pois não tenho todas as combinações de SO e Service Pack para testá-lo.

• O forcomando recupera apenas a 3ª parte (token) do sistema operacional. Isso funcionará para as versões da área de trabalho (se você quiser distinguir o Server 2008 de outras versões, precisará encontrar outra solução).

• %_osirá ser definido como um dos seguintes valores: Server, Vista, 7, 8, 8.1ou 10.

Exemplo de saída:

F:\test>GetOS
Operating System Version: 7
Service Pack Major Version: 1
Architecture: 64-bit

F:\test>

Leitura adicional

• Um índice AZ da linha de comando do Windows CMD - uma excelente referência para todos os itens relacionados à linha de comando do Windows.
• Findstr - Pesquisa por strings - Windows CMD - SS64.com
• For / f- Loop através da saída do comando - Windows CMD - SS64.com
• If - Executar condicionalmente o comando - Windows CMD - SS64.com
• WMIC - Gerenciamento do Windows - Windows CMD - SS64.com

Eu não posso acreditar neste longo e nenhum comando ver

C:\>ver

Microsoft Windows [Version 10.0.10586]

C:\>

Funciona em redirecionamentos para que você possa fazer

ver | find "Version 10."

Mas você normalmente deve escrever "para esta e todas as versões futuras" para melhor enumerar as versões anteriores.

Informação do sistema

recebe muitas informações úteis, como sistema operacional, tipo de sistema (32/64 bits) e por muito tempo:

Não tenho nenhuma experiência com o InstallAnywhere, mas há duas opções para ver qual sistema operacional está instalado usando uma linha de comando.

1. Usando o Cmd

   systeminfo.exe
   

   Usando o comando systeminfo.exe, você pode ver o resultado sob o campoOS Name . Isso pode lhe dar mais informações do que você precisa.

   Mais informações sobre este comando podem ser encontradas no Microsoft TechNet .

2. Powershell

   Como alternativa, você pode usar o seguinte script do Powershell, que retornará as informações exatas que você deseja.

   Get-CimInstance Win32_OperatingSystem | Select-Object  Caption | ForEach{ $_.Caption }