É realmente irritante que o Excel (2003 e 2007) não mostre qual célula, linha ou coluna selecionada quando a janela não está em foco. Normalmente, quero me referir à célula ou linha atual enquanto estiver trabalhando em outro aplicativo.

Existe alguma solução alternativa ou correção que tornará a célula / linha destacada quando não estiver em foco? Eu sei que você pode copiar uma célula (Ctrl + C), mas é meio cansativo fazer isso sempre.

Eu acho que existe uma solução alternativa, mas realmente depende da sua situação!

Você pode criar uma macro que é acionada quando a seleção é alterada e simplesmente altera o plano de fundo de cada célula. Quando você 'sai' da célula, ela redefine o valor de segundo plano da linha para branco e, em seguida, seleciona a nova linha.

Eu adicionei isso ao meu Sheet1 na janela do Visual Basic.

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    Cells.Interior.ColorIndex = xlColorIndexNone
    ActiveCell.EntireRow.Interior.ColorIndex = 34
End Sub

Esta captura de tela foi tirada enquanto o aplicativo havia perdido o foco.

Isso pode ser irritante, mas você pode adicionar facilmente um botão que pode ativar ou desativar esse recurso!

Os negativos são (do alto da minha cabeça: ele removerá qualquer realce atual que você possui. Portanto, se você tiver realce em sua página (células coloridas), é melhor não usá-lo! Além disso, provavelmente será impresso com as linhas destacadas!

Você pode fazer algo assim se precisar. Embora possa ser específico da folha

Dim wasActive As String

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
If wasActive = Empty Then wasActive = "A1"
Range(wasActive).Interior.ColorIndex = "0"
ActiveCell.Interior.ColorIndex = "6"
wasActive = ActiveCell.Address
End Sub

Isso altera o que não está ativo de volta para branco e altera a célula ativa para amarelo. e ainda mostra quando a janela não está ativa. Não tenho certeza se essa é a melhor maneira, mas funciona

Aqui está uma modificação do código de @datatoo. Ele lê os valores anteriores para evitar a perda da cor de preenchimento atual. Ele também altera a cor do texto para destacar ainda mais. Eu o adicionei à planilha do Excel no editor de código (Alt-F11 do Excel).

Clique aqui para obter informações sobre como fazer um evento de alteração da planilha.

'VBA code for Excel to show active cell in worksheet when worksheet is out of focus

Dim wasActive As String
Dim originalFillColor As String
Dim originalTextColor As String

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    'Set up colors on load
    If wasActive = Empty Then
        wasActive = "A1"
        originalFillColor = Range(wasActive).Interior.Color
        originalTextColor = Range(wasActive).Font.Color
    End If

    'Reset previous cell to original color values; If statement prevents removal of grid lines by using "0" for clear fill color when white
    If originalFillColor = 16777215 Then
        Range(wasActive).Interior.ColorIndex = "0"
        Range(wasActive).Font.Color = originalTextColor
    Else
        Range(wasActive).Interior.Color = originalFillColor
        Range(wasActive).Font.Color = originalTextColor
    End If

    'Set new colors and change active cell to highlighted colors (black fill with white text)
    originalFillColor = ActiveCell.Interior.Color
    originalTextColor = ActiveCell.Font.Color
    wasActive = ActiveCell.Address
    ActiveCell.Interior.ColorIndex = "1"
    ActiveCell.Font.ColorIndex = "2"

End Sub

Use uma forma para destacar a seleção.

Nota: Funciona apenas ao alternar para outra janela do Excel. Como solução alternativa, você pode abrir uma janela vazia do Excel e alternar para esta janela antes de alternar para outro aplicativo para manter o destaque.

Basta adicionar isso ao seu código do ThisWorkbook (seu workBOOK, não o código da sua planilha). Isso funcionará para todas as planilhas da sua pasta de trabalho.

Private Sub Workbook_SheetActivate(ByVal Sh As Object)
    DeleteSelectionHighlight
End Sub
Private Sub Workbook_WindowActivate(ByVal Wn As Window)
    DeleteSelectionHighlight
End Sub
Private Sub Workbook_WindowDeactivate(ByVal Wn As Window)
  On Error Resume Next
    Dim shp As Shape
    Application.ScreenUpdating = False

    Set shp = ActiveSheet.Shapes("SelectionHighlight")
    If Err.Number <> 0 Then
        Set shp = ActiveSheet.Shapes.AddShape(msoShapeRectangle, 1, 1, 1, 1)
        With shp 'Format shape to your preference
            .Name = "SelectionHighlight"
            .Line.ForeColor.RGB = RGB(226, 0, 0) ' Border color
            .Line.Weight = 1.5
            .Line.DashStyle = msoLineSolid
            .Fill.Visible = msoFalse 'No background
            '.Fill.ForeColor.RGB = RGB(0, 153, 0) 'Background color
            '.Fill.Transparency = 0.95 'Background transparency
        End With
    End If

    Dim oldZoom As Integer
    oldZoom = Wn.Zoom
    Wn.Zoom = 100 'Set zoom at 100% to avoid positioning errors
    With shp
        .Top = Wn.Selection.Top   'Tweak the offset to fit your desired line weight
        .Left = Wn.Selection.Left 'Tweak the offset to fit your desired line weight
        .Height = Wn.Selection.Height
        .Width = Wn.Selection.Width
    End With
    Wn.Zoom = oldZoom 'Restore previous zoom
    Application.ScreenUpdating = True
End Sub

Private Sub DeleteSelectionHighlight()
  On Error Resume Next
  Dim shp As Shape
    Set shp = ActiveSheet.Shapes("SelectionHighlight")
    shp.Delete
End Sub

Você pode formatar a forma de acordo com sua preferência, ajustando o código.

As vantagens são:

• você não perde a formatação original quando o Excel trava ou há uma falha de energia
• Você não perde a formatação original ao usar CTRL + [de outra pasta de trabalho que altera a planilha ativa
• Você não perde o destaque ao fazer alterações na outra janela do Excel em comparação com a solução CTRL + C

No Excel 2003, o endereço da célula selecionado atualmente é mostrado no canto superior esquerdo. Embora a célula não esteja destacada, ela leva você para o meio do caminho.

não há solução permanente para esse problema.

uma solução alternativa (pode ser irritante em um momento) seria alterar o realce das células selecionadas enquanto elas são selecionadas e selecioná-las novamente para soltar a cor.

Coloque esse código no código da Planilha 1 e vá até sua planilha e selecione algumas células, selecione outras e selecione novamente as primeiras a soltar a cor

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    Dim cell As Range

    For Each cell In Target.Cells
        If cell.Interior.Color = RGB(60, 150, 230) Then
            cell.Interior.Pattern = xlNone
        Else
            cell.Interior.Color = RGB(60, 150, 230)
        End If
    Next
End Sub

Uma solução simples ^{_{que coloca uma cor de célula quando a seleção muda}}

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    Selection.Interior.ColorIndex = xlColorIndexNone
    Selection.Interior.Color = RGB(204, 204, 204)
End Sub

Uma solução complexa ^{_{que muda apenas a cor da célula quando o foco é perdido}}

Em um módulo padrão:

Option Explicit    
Public s As Range

Nas folhas que você deseja que funcione:

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    Set s = Selection
End Sub

Em ThisWorkbook:

Private Sub Workbook_Deactivate()
    If s Is Nothing Then
        Set s = Selection
        Exit Sub
    End If
    s.Interior.ColorIndex = xlColorIndexNone
    s.Interior.Color = RGB(204, 204, 204)

    ' This is optional formatting to make the cells look more like they're actually selected
    s.Borders.Color = RGB(130, 130, 130)
    s.BorderAround _
    Color:=RGB(30, 130, 37), Weight:=xlThick
End Sub

Private Sub Workbook_Activate()
    If s Is Nothing Then
        Set s = Selection
        Exit Sub
    End If
    s.Interior.ColorIndex = xlColorIndexNone
    s.Borders.ColorIndex = xlColorIndexNone
End Sub