vimdiff: Salta para a próxima diferença dentro da linha?


35

vimdiffé muito útil para comparar arquivos. No entanto, costumo usá-lo em arquivos com linhas longas e relativamente poucas diferenças dentro das linhas.

O vimdiff destacará corretamente as diferenças dentro de uma linha (linha inteira rosa, caracteres diferentes em vermelho). Nesses casos, seria bom poder pular para a próxima diferença dentro da linha .

Você pode pular para a "próxima diferença" ( ]c), mas isso pulará para a próxima linha com uma diferença.

Existe uma maneira de ir para o próximo caractere diferente dentro da linha atual?

Respostas:


8

Eu vejo duas soluções:

  1. você precisaria testar o realce da sintaxe atual para pular para a parte vermelha da linha.
  2. você precisaria extrair a linha atual nos dois buffers e encontrar o primeiro caractere que difere para posicionar corretamente o cursor

Ambas as soluções precisam ser executadas após o] c e exigem scripts do vim.

EDIT: Aqui está um primeiro rascunho que parece funcionar:

nnoremap <expr> <silent> <F3>   (&diff ? "]c:call \<sid>NextDiff()\<cr>" : ":cn\<cr>")

function! s:GotoWinline(w_l)
  normal! H
  while winline() < a:w_l
    normal! j
  endwhile
  " todo: beware of cases where the window is too little
endfunction

" Better ]c, [c jump
function! s:NextDiff()
  if ! &diffopt =~ 'filler' | return | endif

  let ignore_blanks = &diffopt =~ 'iwhite'

  " Assert: called just after a ]c or a [c
  " Forces the cursos to be synchronized in all synced windows
  " let diff_l = line()
  try 
    let foldenable = &foldenable
    set nofoldenable

    let w_l = winline() " problematic with enabled lines (from diff...)
    " echomsg w_l.'|'.line('.').'|'.getline('.')

    let lines = {}
    windo if &diff | call <sid>GotoWinline(w_l) | let lines[winnr()]={'text':getline('.'), 'number':line('.')} | endif
  finally
    let &foldenable = foldenable
  endtry

  " echomsg string(lines)
  if len(lines) < 2 | return | endif

  let indices = repeat([0], len(lines))
  let tLines = values(lines)
  let found = 0
  " infinite loop on two empty texts...
  while ! found
    let c = ''
    let next_idx = []
    let i = 0
    while i != len(indices)
      let crt_line = tLines[i].text
      let n = indices[i]
      if len(crt_line) == n
    let found = 1
    break
      endif

      let c2 = (len(crt_line) == n) ? 'EOL' : crt_line[n]
      if empty(c) 
    let c = c2
      endif

      " checks match
      let n += 1
      if c =~ '\s'
    if (c2 != c) && (ignore_blanks && c2 !~ '\s')
      let found = 1
      break
    else " advance
      while ignore_blanks && (n == len(crt_line) || crt_line[n] =~ '\s')
        let n += 1
      endwhile
    endif
      else
    if c2 != c
      let found = 1
      break
    endif
      endif
      let next_idx += [n]

      let i += 1
    endwhile
    if found | break | endif

    let indices = next_idx
  endwhile

  " now goto the right column
  let windows = keys(lines)
  " Assert len(windows) == len(indices)
  let w = 0
  while w != len(windows)
    " echomsg 'W#'.windows[w].' -> :'(tLines[w].number).'normal! '.(indices[w]+1).'|'
    exe windows[w].'wincmd w'
    silent! exe (tLines[w].number).'normal! 0'.(indices[w]).'l'
    let w += 1
  endwhile
  " echomsg string(indices)
endfunction

Eu desisti disso, pois parece que não há uma maneira fácil de conseguir isso. Como sua resposta parece fazer o que eu queria, aceitarei isso como agradecimento.
sleske

2
Desde então, coloquei o código nesse script code.google.com/p/lh-vim/source/browse/misc/trunk/plugin/… (que faz algumas outras coisas) e, infelizmente, observou um loop infinito que ocorre de tempos em tempos. Acabarei por corrigir isso.
Luc Hermitte

12

Esta é uma solução fácil:

Você pode usar set wrap.

Isso criará problemas se a diferença fizer com que o texto seja quebrado em um número desigual de linhas.


1
Rápido e sujo, mas fez o trabalho para mim.
Mobius 25/05

2

Também não consigo descobrir como fazer isso vimdiff, mas você pode conferir wdiff. Mostra diferenças entre dois arquivos, uma palavra de cada vez.

Eu tive que compilá-lo da fonte:

curl http://ftp.gnu.org/gnu/wdiff/wdiff-1.2.1.tar.gz > wdiff-1.2.1.tar.gz
tar -xzvf wdiff-1.2.1.tar.gz
cd wdiff-1.2.1
./configure
make
make install

1

A julgar pela documentação, isso não pode ser feito.


2
Interessante. Onde você encontrou isso nos documentos? Não consegui encontrar nada lá.
sleske

1
No Vim eu digitei: #:help vimdiff
Nathan Fellman
Ao utilizar nosso site, você reconhece que leu e compreendeu nossa Política de Cookies e nossa Política de Privacidade.
Licensed under cc by-sa 3.0 with attribution required.