Obter o nome da pasta atual por um comando do DOS?

É possível obter o nome da pasta atual (não o caminho do diretório atual) usando um comando do DOS? Se sim, como?

O mais próximo que cheguei foi isso, mas não o faz:

for /f "delims=\" %%a in ("%CD%") do set CURR=%%a
echo.DIR: %CURR%

nota: a tentativa acima foi eu tentando tokenizar a string e obter o último token definido como a variável CURR.

A maneira mais curta que encontrei:

for %I in (.) do echo %~nxI

ou dentro de um script .bat:

for %%I in (.) do echo %%~nxI

ou em .bat com Get value na variável

for %%I in (.) do set CurrDirName=%%~nxI
echo %CurrDirName%

Explicação: http://www.robvanderwoude.com/ntfor.php

nx significa apenas o nome e a extensão do arquivo

Se você quiser saber a localização atual do arquivo em lotes (e se o Windows não for uma versão muito antiga), digite for /?uma janela na 'caixa do DOS'. Rolar para baixo. Ler.

Você descobrirá que agora pode ler (de dentro do arquivo em lotes) estas variáveis:

%0      - as the name how this batchfile was called
%~d0    - as the drive letter where this batchfile is located ('\\' in case of share)
%~p0    - as path (without the drive letter) where this batchfile is located
%~n0    - as filename (without suffix) of this batchfile
%~x0    - as filename's suffix (without filename) of this batchfile
%~a0    - as this batchfile's file attributes
%~t0    - as this batchfile's date+time
%~z0    - as this batchfile's filesize
%~dpnx0 - as this batchfile's fully qualified path+filename
[... and then some more ...]

Isso funciona para muitos casos. Suponha que o batchfile seja chamado mytest.bat. Você pode chamá-lo de diferentes maneiras:

1. ..\..\to\mytest.bat ............................... (caminho relativo)
2. d:\path\to\mytest.bat........................... (caminho completo)
3. \\fileserver\sharename\mytest.bat... (caminho no compartilhamento remoto)

... e você sempre obterá o valor certo em suas variáveis.

Eu pessoalmente gostei da resposta do Toms, até que ela lutou com pontos nos nomes dos dir. Isso me deu uma dica:

for /f "delims=\" %%a in ("%cd%") do echo topmost dir: %%~nxa

A resposta de Tom é boa, mas se você tiver um nome de diretório com um ponto final (por exemplo, wxwidgets-2.9.4), apenas o nome completo será obtido. Portanto, isso produziria o wxwidgets-2.9, porque o .4 foi tratado como uma extensão (Sim, mesmo que seja um nome de diretório!).

Para obter o nome completo da saída, você deve adicionar a extensão até o final:

FOR %I IN (.) DO Echo %~nI%~xI

e no modo de arquivo em lote:

FOR %%I IN (.) DO Echo %%~nI%%~xI

Ou, é claro, defina uma variável no arquivo em lotes:

FOR %%I IN (.) DO SET CurrentD=%%~nI%%~xI

Uma outra maneira é:

set "MyPath=%~dpnx0" & call set "MyPath=%%MyPath:\%~nx0=%%" 
echo MyPath=%MyPath%  

trabalha com "." e espaços no nome do caminho

O que isso faz?

1. coloque o nome do arquivo inteiro (driveletter-path-filename-extension) no MyPathVar

2. remover nome do arquivo e extensão de MyPathvar

Também funciona com caminhos UNC. Se você precisar da barra invertida no final do caminho. Remova o \after MyPathno segundo comando set, por exemplo.

set "MyPath=%%MyPath:%~nx0=%%"

Você pode obter o diretório atual em uma variável. Uma linha:

set a=%cd%

Verificar com

echo %a%

simples

for %%d in ("%CD%") do echo %%~nxd

ou

set "sPath=."
for %%d in ("%sPath%") do set "sDirName=%%~nxd"

Cuidado com a barra invertida do final do caminho, pois não deve ser a barra invertida do fim.

Minha resposta neste tópico faz isso em 3 linhas simples:

@echo off
SET "CDIR=%~dp0"
:: for loop requires removing trailing backslash from %~dp0 output
SET "CDIR=%CDIR:~0,-1%"
FOR %%i IN ("%CDIR%") DO SET "PARENTFOLDERNAME=%%~nxi"
ECHO Parent folder: %PARENTFOLDERNAME%
ECHO Full path: %~dp0
pause>nul

Isso funciona para mim a partir de um arquivo em lotes. Retorna o nome do diretório de trabalho atual.

pushd %1 & for %%i in (.) do @echo %%~ni