Crie um link simbólico no Mac OS X Finder

Existe uma maneira de obter a mesma funcionalidade que o comando unix ln -sno Mac OS X Finder (OS 10.5)? Quero poder criar links simbólicos enquanto estiver trabalhando nas janelas do Finder sem abrir o Terminal.

Observe que o Make Aliascomando no Finder não é o que eu quero, porque esses aliases não podem ser navegados no Terminal (mas os links criados com ln -spodem ser navegados pelo Terminal e pelo Finder).

Que tal criar links simbólicos no Finder via AppleScript ?

Aqui está o script mais relevante nesse link:

on run
    open {choose file with prompt "Choose a file to create a symbolic link:" without invisibles}
end run

on open the_files
    repeat with i from 1 to (count the_files)
        try
            set posix_path to POSIX path of (item i of the_files)
            if posix_path ends with "/" then set posix_path to text 1 thru -2 of posix_path
            do shell script "ln -s " & quoted form of posix_path & " " & quoted form of (posix_path & ".sym")
        end try
    end repeat
end open

Basta colá-lo no AppleScript Editor e salve-o como um aplicativo . Em seguida, você pode arrastá-lo sobre a barra de ferramentas do localizador ou vinculá-lo à estação .

O SymbolicLinker fará exatamente o que você está procurando, e é grátis.

Um AppleScript no link fornecido pelo usuário nuc respondeu à minha pergunta. Aqui está o texto da maçã reproduzido caso o link desapareça.

Eu preferi o roteiro dado pelo comentarista jonn8n, que também foi reproduzido como artigo da Macworld .

on run
    open {choose file with prompt ¬
        "Choose a file to create a symbolic link:" without invisibles}
end run
on open the_files
    repeat with i from 1 to (count the_files)
        try
            set posix_path to POSIX path of (item i of the_files)
            if posix_path ends with "/" then set posix_path to ¬
                text 1 thru -2 of posix_path
            do shell script "ln -s " & quoted form of posix_path ¬
                & " " & quoted form of (posix_path & ".sym")
        end try
    end repeat
end open

Salvei isso como um aplicativo usando o Script Editor e arrastei o aplicativo para a barra lateral do Finder, para que agora eu possa criar links simbólicos arrastando arquivos ou pastas para o ícone do aplicativo.

O Path Finder adiciona isso ao seu Finder e adiciona muito mais recursos.

Use Automator.app para criar um serviço que executa um script bash. Isso é mais simples que o AppleScript e mais confiável do que instalar software de terceiros.

for f in "$@"
do
    ln -s "$f" "$f.symlink"
done

Em seguida, você pode acessar o comando Criar link simbólico no menu Serviços :

O resultado:

Uma possível melhoria nesse script seria alterar o manipulador de execução para usar os arquivos atualmente selecionados no Finder, da seguinte maneira:

on run
    tell application "Finder" to set sel to selection
    open sel
end run
on open the_files
    repeat with i from 1 to (count the_files)
        try
            set posix_path to POSIX path of (item i of the_files as alias)
            if posix_path ends with "/" then set posix_path to ¬
                text 1 thru -2 of posix_path
            try
                do shell script "ln -s " & quoted form of posix_path ¬
                    & " " & quoted form of (posix_path & ".sym")
            on error
                try
                    do shell script "ln -s " & quoted form of posix_path ¬
                        & " " & quoted form of (posix_path & ".sym") with administrator privileges

                end try
            end try
        end try
    end repeat
end open

Você também pode editar [application] /Contents/Info.plist para adicionar

<key>LSUIElement</key>
<true/>

Pouco antes do último </dict>. Isso significa que o aplicativo será executado em segundo plano e não virá para a frente quando você clicar nele.

Além disso, no Snow Leopard, onde o SymbolicLinker não funciona, você pode criar um Serviço com o Automator para executar o comando Terminal ou o AppleScript para criar um link simbólico.

Mais um AS:

tell application "Finder"
    repeat with f in (get selection)
        set p to POSIX path of (f as text)
        set p2 to POSIX path of (desktop as text) & name of f
        do shell script "ln -s " & quoted form of p & " " & quoted form of p2
    end repeat
end tell

Tente procurar aqui: http://www.techiecorner.com/528/how-to-create-shortcut-in-mac-os-x/

Isso já está embutido no OSX se você pressionar a tecla Control quando clicar em algo.