Vim: mostra o índice de guias na linha de tabulação

Vamos dizer que eu abri file1.txt, file2.txt, file3a.txte file3b.txtde tal forma que o tabline (a coisa no topo) se parece com isso:

file1.txt  file2.txt  2 file3a.txt

(Observe como file3b.txt.está faltando porque é mostrado em uma divisão, na mesma guia que file3a.txt)

Para mover-se mais rapidamente entre as guias (com <Number>gt), gostaria que cada guia exibisse seu índice ao longo do nome do arquivo. Igual a:

1:<file1.txt>  2:<file2.txt>  3:<2 file3a.txt>

A formatação (as chaves angulares em particular) são opcionais; Eu só quero que o índice apareça lá (o 1:, 2:e assim por diante).

Nenhuma pista :h tab-page-commandsou google qualquer.

Você precisa olhar para:

:help 'tabline'
:help setting-tabline

E se você tiver "e" na configuração de 'guioptions':

:help 'guitablabel'

coloque isso no seu vimrc

" Rename tabs to show tab number.
" (Based on http://stackoverflow.com/questions/5927952/whats-implementation-of-vims-default-tabline-function)
if exists("+showtabline")
    function! MyTabLine()
        let s = ''
        let wn = ''
        let t = tabpagenr()
        let i = 1
        while i <= tabpagenr('$')
            let buflist = tabpagebuflist(i)
            let winnr = tabpagewinnr(i)
            let s .= '%' . i . 'T'
            let s .= (i == t ? '%1*' : '%2*')
            let s .= ' '
            let wn = tabpagewinnr(i,'$')

            let s .= '%#TabNum#'
            let s .= i
            " let s .= '%*'
            let s .= (i == t ? '%#TabLineSel#' : '%#TabLine#')
            let bufnr = buflist[winnr - 1]
            let file = bufname(bufnr)
            let buftype = getbufvar(bufnr, 'buftype')
            if buftype == 'nofile'
                if file =~ '\/.'
                    let file = substitute(file, '.*\/\ze.', '', '')
                endif
            else
                let file = fnamemodify(file, ':p:t')
            endif
            if file == ''
                let file = '[No Name]'
            endif
            let s .= ' ' . file . ' '
            let i = i + 1
        endwhile
        let s .= '%T%#TabLineFill#%='
        let s .= (tabpagenr('$') > 1 ? '%999XX' : 'X')
        return s
    endfunction
    set stal=2
    set tabline=%!MyTabLine()
    set showtabline=1
    highlight link TabNum Special
endif

Na página da wikia, você pode encontrar pelo menos dois (os que eu testei) que fornecem os índices de tabulação, e um deles produz o número de janelas dentro de cada buffer que têm edições.

Aqui está o resultado das minhas modificações na que produz a contagem de buffers editados, a alteração que fiz foi tornar o valor de destaque da contagem consistente com o restante da guia:

set tabline=%!MyTabLine()  " custom tab pages line
function MyTabLine()
        let s = '' " complete tabline goes here
        " loop through each tab page
        for t in range(tabpagenr('$'))
                " set highlight
                if t + 1 == tabpagenr()
                        let s .= '%#TabLineSel#'
                else
                        let s .= '%#TabLine#'
                endif
                " set the tab page number (for mouse clicks)
                let s .= '%' . (t + 1) . 'T'
                let s .= ' '
                " set page number string
                let s .= t + 1 . ' '
                " get buffer names and statuses
                let n = ''      "temp string for buffer names while we loop and check buftype
                let m = 0       " &modified counter
                let bc = len(tabpagebuflist(t + 1))     "counter to avoid last ' '
                " loop through each buffer in a tab
                for b in tabpagebuflist(t + 1)
                        " buffer types: quickfix gets a [Q], help gets [H]{base fname}
                        " others get 1dir/2dir/3dir/fname shortened to 1/2/3/fname
                        if getbufvar( b, "&buftype" ) == 'help'
                                let n .= '[H]' . fnamemodify( bufname(b), ':t:s/.txt$//' )
                        elseif getbufvar( b, "&buftype" ) == 'quickfix'
                                let n .= '[Q]'
                        else
                                let n .= pathshorten(bufname(b))
                        endif
                        " check and ++ tab's &modified count
                        if getbufvar( b, "&modified" )
                                let m += 1
                        endif
                        " no final ' ' added...formatting looks better done later
                        if bc > 1
                                let n .= ' '
                        endif
                        let bc -= 1
                endfor
                " add modified label [n+] where n pages in tab are modified
                if m > 0
                        let s .= '[' . m . '+]'
                endif
                " select the highlighting for the buffer names
                " my default highlighting only underlines the active tab
                " buffer names.
                if t + 1 == tabpagenr()
                        let s .= '%#TabLineSel#'
                else
                        let s .= '%#TabLine#'
                endif
                " add buffer names
                if n == ''
                        let s.= '[New]'
                else
                        let s .= n
                endif
                " switch to no underlining and add final space to buffer list
                let s .= ' '
        endfor
        " after the last tab fill with TabLineFill and reset tab page nr
        let s .= '%#TabLineFill#%T'
        " right-align the label to close the current tab page
        if tabpagenr('$') > 1
                let s .= '%=%#TabLineFill#%999Xclose'
        endif
        return s
endfunction

O plug - in tabline é um plug-in vim que implementa a funcionalidade solicitada e não explode seu vimrc. Simplesmente instale e reinicie o vim.

Para instalar:

cd /usr/share/vim/vimfiles/plugin/
wget https://raw.githubusercontent.com/mkitt/tabline.vim/master/plugin/tabline.vim

ou use um gerenciador de plugins.

Para o Vim baseado em GUI (Gvim no Linux, MacVim no Mac, etc), coloque isso em seu .gvimrc:

set guitablabel=%N:%M%t " Show tab numbers

Algumas dicas sobre como realmente usar os números exibidos:

• Ngtmudará para a guia N. Por exemplo, 3gtvai para a guia 3.
• :tabm2move a guia atual para aparecer após a guia 2.
  • Para mover esta guia para a primeira posição, use :tabm0
  • Para mover essa guia para a última posição, basta usar :tabm