Como altero o idioma de todos os slides do Powerpoint de uma só vez?

Embora esse segmento seja bastante antigo, a Microsoft não forneceu nenhuma solução que eu conheça. Sugiro outra abordagem para usuários de Mac: abra sua apresentação no Keynote, altere o idioma da ortografia e, possivelmente, edite toda a apresentação, depois exporte-a para o PowerPoint.

Para alterar o idioma de todo o PowerPoint facilmente, abra a guia Exibir e selecione a exibição Estrutura de tópicos .

Agora pressione

• Ctrl+ Apara selecionar tudo.
• Ferramentas → Idioma → Escolha o seu idioma para definir.

Da mesma forma, enquanto você seleciona tudo, pode alterar outras coisas, como fontes, cores etc. Embora, é claro, em muitos casos, isso seja melhor alterando o slide mestre, uma apresentação que teve muitos editores pode ter muitos conjuntos de formatação 'rígidos' que se desvia do mestre subjacente e precisa ser redefinido para ser consistente. Você também pode redefinir slides individuais para o estilo principal, mas isso também pode resultar na movimentação de espaços reservados, o que pode ser indesejável em algumas situações.

PowerPoint 2013

• Exibir → Esboço → selecione todos os slides (no menu esquerdo) via Ctrl+ A.
• Revisar → Idioma → Definir idioma de verificação ... → Escolha o seu idioma para definir.

Quanto a mim - era necessário reiniciar o PowerPoint . Provavelmente porque eu também mudei o Idioma de Edição :

• Revisar → Idioma → Definir idioma de revisão ... → Preferências de idioma → Escolha Editar idiomas .

Usando o Powerpoint 2010 , abri o menu Esboço -

Selecionou todo o texto (Ctrl + A), abriu o menu de idiomas e definiu meu idioma de prova

E funcionou!

O menu de idiomas está localizado na guia da faixa de opções Revisão (após a guia Apresentação de slides e não é visível na captura de tela).

As respostas existentes funcionam para o texto que está presente no esquema. Infelizmente, no meu caso, isso não cobriu uma parte significativa do texto, incluindo figuras, tabelas etc.

Essa macro resolveu o problema para mim:

 Sub ChangeProofingLanguageToEnglish()
    Dim j, k, m, scount, fcount, gcount As Integer
    scount = ActivePresentation.Slides.Count
    For j = 1 To scount
        fcount = ActivePresentation.Slides(j).Shapes.Count
        For k = 1 To fcount
            If ActivePresentation.Slides(j).Shapes(k).HasTextFrame Then
                ActivePresentation.Slides(j).Shapes(k) _
                .TextFrame.TextRange.LanguageID = msoLanguageIDEnglishUS
            End If
            If ActivePresentation.Slides(j).Shapes(k).Type = msoGroup Then
                gcount = ActivePresentation.Slides(j).Shapes(k).GroupItems.Count
                For m = 1 To gcount
                    If ActivePresentation.Slides(j).Shapes(k).GroupItems.Item(m).HasTextFrame Then
                    ActivePresentation.Slides(j).Shapes(k).GroupItems.Item(m) _
                    .TextFrame.TextRange.LanguageID = msoLanguageIDEnglishUS
            End If
                Next m
            End If
        Next k
    Next j
End Sub

O "msoLanguageIDEnglishUS" usado na macro acima pode ser substituído por qualquer idioma desejado. A lista completa de idiomas pode ser encontrada neste artigo

(O crédito é de Ganesh Kumar, que postou a macro original aqui . Adicionei suporte para o primeiro nível de agrupamento de formas. Para melhorá-lo, a macro pode ser recursiva para procurar grupos que contenham outros grupos etc.)

I melhorado a resposta de Inigo para fornecer uma versão recursiva que muda todos os itens para o idioma desejado.

Esta versão investigará recursivamente cada forma que é um tipo de grupo. Algumas experiências sugerem que msoGroupe msoSmartArtsão os tipos de grupo - fique à vontade para adicionar a essa lista se você encontrar outros tipos de formas que podem conter objetos de texto.

Sub ChangeProofingLanguageToEnglish()
    Dim j As Long, k As Long
    Dim languageID As MsoLanguageID

    'Set this to your preferred language
    languageID = msoLanguageIDEnglishUK

    For j = 1 To ActivePresentation.Slides.Count
        For k = 1 To ActivePresentation.Slides(j).Shapes.Count
            ChangeAllSubShapes ActivePresentation.Slides(j).Shapes(k), _
              languageID
        Next k
    Next j
End Sub


Sub ChangeAllSubShapes(targetShape As shape, languageID As MsoLanguageID)
    Dim i As Long

    If targetShape.HasTextFrame Then
        targetShape.TextFrame.TextRange.languageID = languageID
    End If

    Select Case targetShape.Type
        Case msoGroup, msoSmartArt
            For i = 1 To targetShape.GroupItems.Count
                ChangeAllSubShapes targetShape.GroupItems.Item(i), languageID
            Next i
    End Select
End Sub

Com base nas respostas de Inigo, Duncan, Maria e DomDev, isso funciona para formas, tabelas, grupos, SmartArt, agora e no futuro:

Sub ChangeProofingLanguageToFrench()
    Dim j, k As Integer
    Dim languageID As MsoLanguageID

    'Set this to your preferred language
    languageID = msoLanguageIDFrench

    'Loop all the slides in the document, and change the language
    For j = 1 To ActivePresentation.Slides.Count
        For k = 1 To ActivePresentation.Slides(j).Shapes.Count
            ChangeAllSubShapes ActivePresentation.Slides(j).Shapes(k), languageID
        Next k
    Next j

    'Loop all the master slides, and change the language
    For j = 1 To ActivePresentation.SlideMaster.CustomLayouts.Count
        For k = 1 To ActivePresentation.SlideMaster.CustomLayouts(j).Shapes.Count
            ChangeAllSubShapes ActivePresentation.SlideMaster.CustomLayouts(j).Shapes(k), languageID
        Next k
    Next j

    'Change the default presentation language, so that all new slides respect the new language
    ActivePresentation.DefaultLanguageID = languageID
End Sub

Sub ChangeAllSubShapes(targetShape As Shape, languageID As MsoLanguageID)
    Dim i As Integer, r As Integer, c As Integer

    If targetShape.HasTextFrame Then
        targetShape.TextFrame.TextRange.languageID = languageID
    End If

    If targetShape.HasTable Then
        For r = 1 To targetShape.Table.Rows.Count
            For c = 1 To targetShape.Table.Columns.Count
                targetShape.Table.Cell(r, c).Shape.TextFrame.TextRange.languageID = languageID
            Next
        Next
    End If

    Select Case targetShape.Type
        Case msoGroup, msoSmartArt
            For i = 1 To targetShape.GroupItems.Count
                ChangeAllSubShapes targetShape.GroupItems.Item(i), languageID
            Next i
    End Select
End Sub

A versão do Duncan funciona bem para tudo, exceto tabelas. Encontrei outro código que parece funcionar também com tabelas: https://stackoverflow.com/questions/4735765/powerpoint-2007-set-language-on-tables-charts-etc-that-contains-text

Public Sub changeLanguage()
    On Error Resume Next
    Dim gi As GroupShapes '<-this was added. used below
    'lang = "English"
    lang = "Norwegian"
    'Determine language selected
    If lang = "English" Then
        lang = msoLanguageIDEnglishUK
    ElseIf lang = "Norwegian" Then
        lang = msoLanguageIDNorwegianBokmol
    End If
    'Set default language in application
    ActivePresentation.DefaultLanguageID = lang

    'Set language in each textbox in each slide
    For Each oSlide In ActivePresentation.Slides
        Dim oShape As Shape
        For Each oShape In oSlide.Shapes
            'Check first if it is a table
            If oShape.HasTable Then
                For r = 1 To oShape.Table.Rows.Count
                    For c = 1 To oShape.Table.Columns.Count
                    oShape.Table.Cell(r, c).Shape.TextFrame.TextRange.LanguageID = lang
                    Next
                Next
            Else
                Set gi = oShape.GroupItems
                'Check if it is a group of shapes
                If Not gi Is Nothing Then
                    If oShape.GroupItems.Count > 0 Then
                        For i = 0 To oShape.GroupItems.Count - 1
                            oShape.GroupItems(i).TextFrame.TextRange.LanguageID = lang
                        Next
                    End If
                'it's none of the above, it's just a simple shape, change the language ID
                Else
                    oShape.TextFrame.TextRange.LanguageID = lang
                End If
            End If
        Next
    Next End Sub

Além da resposta fornecida pela Mastergalen e dos comentários sobre o texto recém-digitado:

Se você perceber que esse idioma será alterado automaticamente sempre que você começar a digitar um novo texto (o que é muito irritante), você precisará alterar o idioma padrão atual do PowerPoint:

• verifique se a janela do PowerPoint é uma janela ativa
• no Windows Taskbar(sim, na verdade não está no PowerPoint), verifique se Language barestá visível,
  • se não for para Control Panel > Region and Language > Keyboards and Languages. Clique em Change keybords...Alternar para a Language barguia e marque a Docked in the taskbaropção. (este é do Win7, então pode ser um pouco diferente em outras versões).
• agora ação-chave - na Language barbarra de tarefas, clique no código do idioma e mude para EN (se você deseja atualmente usar o inglês no PowerPoint). A partir de agora, todo o novo texto do PowerPoint estará no idioma selecionado :-)
• se você quiser escrever no idioma original, basta alterá-lo novamente.

Fiz um suplemento em 2014 para mim mesmo, que ainda funciona bem no PowerPoint 2016. https://github.com/wobba/officeaddin/releases/tag/v1.0.1

Ele procura por idiomas usados ​​e permite que você mude de uma só vez, fazendo um loop.