Com base no que eu li, se os que postaram disseram netshque não funcionam a partir das 7 e acima, isso está incorreto. Agora, se for estritamente sobre " netsh routing", acho que você pode estar certo, mas isso funciona - estou prestes a mostrar o conteúdo de um arquivo em lotes que criei para o Windows 8.1. Em vez de obter os comentários e informações usuais, tentarei ajudar aqueles com todas as informações.
Primeiro, você precisa garantir que a conexão que você compartilhará esteja configurada para realmente compartilhar a conexão. Este link aqui deve ajudar você a:
http://windows.microsoft.com/en-us/windows/set-internet-connection-sharing#1TC=windows-7
Para abrir Conexões de Rede, clique no botão Iniciar Imagem do botão Iniciar e, em seguida, clique em Painel de Controle. Na caixa de pesquisa, digite adaptador e, em Central de Rede e Compartilhamento, clique em Exibir conexões de rede.
Clique com o botão direito do mouse na conexão que você deseja compartilhar e, em seguida, clique em Propriedades. É necessária permissão do administrador Se você for solicitado com uma senha ou confirmação de administrador, digite a senha ou forneça a confirmação.
Clique na guia Compartilhamento e marque a caixa de seleção Permitir que outros usuários da rede se conectem através da conexão com a Internet deste computador.
Depois de seguir as etapas acima para configurar o ICS no computador host, faça as seguintes alterações em todos os outros computadores (mas não no computador host).
Para abrir Opções da Internet, clique no botão Iniciar Imagem do botão Iniciar, clique em Painel de Controle, clique em Rede e Internet e, em seguida, clique em Opções da Internet.
Clique na guia Conexões e, em seguida, clique em Nunca discar uma conexão.
Clique em Configurações da LAN.
Na caixa de diálogo Configurações da rede local (LAN), em Configuração automática, desmarque as caixas de seleção Detectar automaticamente as configurações e Usar script de configuração automática.
Em servidor proxy, limpe a caixa de seleção Usar um servidor proxy para sua LAN e, em seguida, clique em OK.
Que eu saiba, acho que isso deve funcionar para o Windows 7 e 8.
Agora, como o tópico era sobre uma solução de linha de comando, este é o conteúdo do arquivo em lotes de como eu configuro um adaptador sem fio virtual e pronto para uso.
Depois de criada, talvez você precise usar as instruções acima e verifique se está compartilhando a conexão de origem com o adaptador virtual recém-criado que será visto pelos seus dispositivos sem fio.
Arquivo .bat de compartilhamento de conexão:
@echo off
set _my_datetime=%date%_%time%
set _my_datetime=%_my_datetime: =_%
set _my_datetime=%_my_datetime::=%
set _my_datetime=%_my_datetime:/=_%
set _my_datetime=%_my_datetime:.=_%
cd\
if NOT EXIST "C:\TEMP\switch.txt" (
GOTO :START
) ELSE (
GOTO :STOP
)
:START
REM Create Temp File for On and Off switch.
ECHO WOOHOO >"C:\TEMP\switch.txt"
REM -- Output everything that is happening into a file called wifi.txt.
REM -- Start out with a timestamp at the top to show when it was done.
REM -- All 'netsh' commands are for setting up the SSID and starting the sharing.
REM -- I stop and start when starting the service just for prosperity.
echo _%_my_datetime% >"C:\TEMP\wifi.txt"
netsh wlan set hostednetwork mode=allow ssid=ITWORKS key=111222333 >> "C:\TEMP\wifi.txt"
netsh wlan stop hostednetwork >>"C:\TEMP\wifi.txt"
netsh wlan start hostednetwork >>"C:\TEMP\wifi.txt"
echo MSGBOX "Wifi Sharing Started!" > %temp%\TEMPmessage.vbs
call %temp%\TEMPmessage.vbs
del %temp%\TEMPmessage.vbs /f /q
GOTO :END
REM -- This will turn ICS off and give a prompt via VBS that you're turned off.
REM -- I timestamp when the service is turned off in the output file.
REM -- I delete the switch file to let the code know to turn it on when
REM -- when fired off again. Tempmessage is the msgbox used to show the service
REM -- has been turned off. Same for the msgbox above when it's on.
:STOP
echo OFF AT _%_my_datetime% >>"C:\TEMP\wifi.txt"
netsh wlan stop hostednetwork >>"C:\TEMP\wifi.txt"
DEL /Q "C:\TEMP\switch.txt"
echo MSGBOX "Wifi Sharing Stopped!" > %temp%\TEMPmessage.vbs
call %temp%\TEMPmessage.vbs
del %temp%\TEMPmessage.vbs /f /q
:END
Ficarei feliz em responder perguntas sobre isso, porque haverá algumas situações únicas e gostaria de ajudar, pois tive que juntar o que encontrei acima.
Mas, para trazer isso à perspectiva, isso funciona no Windows 8.1 usando uma conexão Ethernet em um laptop, compartilhando sua conexão com o adaptador virtual. Pode funcionar tão bem se você estiver tentando compartilhar uma conexão sem fio de origem.