Atalho ou macro para alterar o tipo de fonte no Microsoft Outlook

Existe um atalho de teclado para alterar a fonte no Outlook no Windows? Eu tenho que alternar entre Calibri e Courier constantemente por razões técnicas e clicar na caixa de diálogo de fontes sempre fica muito entediante. Eu sei que posso usar Ctrl + Space para alterar qualquer coisa para a fonte padrão (Calibri).

Se não houver atalho, alguém poderia me ajudar a criar uma macro para alternar fontes? Eu imagino que posso atribuir qualquer atalho para uma macro?

(A resposta de techie007 não funcionou para mim no Outlook 2010)

Essa macro (adaptada de http://www.slipstick.com/developer/word-macro-apply-formatting-outlook-email/ ) faz:

Sub SetCodeFont()
    Dim objItem As Object
    Dim objInsp As Outlook.Inspector

    Dim objWord As Word.Application
    Dim objDoc As Word.Document
    Dim objSel As Word.Selection
    On Error Resume Next

    Set objItem = Application.ActiveInspector.CurrentItem
    If Not objItem Is Nothing Then
        If objItem.Class = olMail Then
            Set objInsp = objItem.GetInspector
            If objInsp.EditorType = olEditorWord Then
                Set objDoc = objInsp.WordEditor
                Set objWord = objDoc.Application
                Set objSel = objWord.Selection
                objSel.Font.Name = "Consolas"
            End If
        End If
    End If

    Set objItem = Nothing
    Set objWord = Nothing
    Set objSel = Nothing
    Set objInsp = Nothing
End Sub

Em seguida, no Editor do VBA, vá para Tools > Referencese selecione Microsoft Word 14.0 Object Library.

Agora, para criar um atalho de teclado para uma macro, adicione-o à barra de ferramentas de acesso rápido da seguinte maneira:

1. Abra uma nova mensagem de email
2. Clique na pequena seta suspensa na barra de ferramentas de acesso rápido (normalmente localizada na parte superior da janela) e selecione "Mais comandos ..."

3. A caixa de diálogo Opções do Outlook será aberta e selecione "Macros" no menu suspenso "Escolher comandos de:"

4. Selecione a macro SetCodeFont na lista e pressione "Adicionar >>"
5. O botão macro aparecerá agora na barra de ferramentas de acesso rápido

Para executar a macro, destaque algum texto no seu email e pressione Alt + <Num>onde <Num>está a posição da macro na Barra de Ferramentas de Acesso Rápido. Por exemplo, se a macro for o primeiro botão na barra de ferramentas, use Alt + 1para invocá-la.

Apenas FYI, esta é a sequência de teclas para focar o selector Fonte: Alt, H, F,F