No Outlook2010, existe uma maneira de exibir os lembretes de adiamento no momento?

Existe alguma maneira no Outlook 2010 de exibir uma lista de itens que estão suspensos no momento? Por exemplo, digamos que, duas semanas antes, defina um lembrete para aparecer na sexta-feira para um importante almoço na segunda-feira seguinte (gosto de ser lembrado das tarefas de segunda-feira antes do fim de semana). Quando o lembrete aparece na sexta-feira, suspiro por três dias para que apareça novamente antes do almoço na segunda-feira. Então a segunda-feira rola e minha memória fica confusa e estou um pouco paranóica por ter acidentalmente descartado o lembrete na sexta-feira em vez de adiar corretamente. Ainda consigo ver o compromisso original em minha agenda, mas preciso garantir que o lembrete seja exibido quando espero, para que eu não perca a reunião.

Existe alguma maneira no Outlook 2010 de exibir uma lista dos lembretes que estão suspensos no momento? Isso também seria útil nos casos em que eu concluo uma tarefa cujo lembrete eu tinha adiado até mais tarde e agora quero puxar o lembrete adiado e cancelá-lo.

Sub SnoozedReminders()

' http://www.jpsoftwaretech.com/check-your-outlook-reminders-in-vba/

Dim MyReminder As Outlook.Reminder
Dim MyReminders As Outlook.Reminders
Dim Report As String
Dim i As Long

Set MyReminders = Outlook.Reminders

i = 0

For Each MyReminder In MyReminders

    If HasReminderFired(MyReminder) = True Then
        i = i + 1
        Report = Report & i & ": " & MyReminder.Caption & vbCr & _
            "     Snoozed to " & MyReminder.NextReminderDate & vbCr & vbCr
    End If

Next MyReminder

CreateReportAsEmail "Snoozed Items", Report

End Sub


Function HasReminderFired(rmndr As Outlook.Reminder) As Boolean
    HasReminderFired = (rmndr.OriginalReminderDate <> rmndr.NextReminderDate)
End Function


' VBA SubRoutine which displays a report inside an email
' Programming by Greg Thatcher, http://www.GregThatcher.com

Public Sub CreateReportAsEmail(Title As String, Report As String)

    On Error GoTo On_Error

    Dim Session As Outlook.Namespace
    Dim mail As MailItem
    Dim MyAddress As AddressEntry
    Dim Inbox As Outlook.folder 

    Set Session = Application.Session
    Set Inbox = Session.GetDefaultFolder(olFolderInbox)
    Set mail = Inbox.items.Add("IPM.Mail")

    mail.Subject = Title
    mail.Body = Report

    mail.Save
    mail.Display

Exiting:
    Set Session = Nothing
    Set Inbox = Nothing
    Set mail = Nothing
    Exit Sub

On_Error:
    MsgBox "error=" & Err.Number & " " & Err.Description
    Resume Exiting

End Sub

Se você não estiver familiarizado com o VBA, consulte a página de explicação do Slipstick . Você encontrará informações sobre:

• configurações de segurança macro;
• onde colocar o código (você pode usar um módulo regular com Inserir | Módulo); e
• como criar um botão.

De acordo com esta postagem do fórum Exibir itens adiados , não é possível ver uma lista de itens adiados. A postagem sugere que você poderá ver uma quantidade limitada de informações úteis criando uma exibição personalizada que exibe alguns dos campos de lembrete.

Tente clicar na guia Calendário, selecione Exibir e alterar exibição. Depois selecione Lista. Isso parece mostrar uma lista de todos os lembretes.