Procurando por um valor no Excel, retornando sim ou não

8

Eu tenho uma pasta de trabalho, com duas planilhas separadas. Quero saber se os valores que aparecem na planilha B também aparecem na planilha A; nesse caso, desejo retornar um "SIM". Caso contrário, quero retornar um "NÃO".

(Exemplo: A planilha A é uma lista de livros em atraso. A planilha B é a biblioteca inteira).

Na planilha A, tenho o seguinte conjunto de dados:

     A
1  AB123CD
2  EF456GH
3  IJ789KL
4  MN1011OP

Na planilha B, tenho o seguinte conjunto de dados:

      A           Overdue 
1  AB123CD           ?
2  QR1516ST          ?
3  EF456GH           ?
4  GT0405RK          ?
5  IJ789KL           ?
6  MN1011OP          ?

Como estruturaria a função para procurar corretamente se os valores existem na Tabela A?

Venho brincando com uma combinação de if (), vlookup () e match (), mas nada parece funcionar para várias planilhas.

— Cole
fonte

18

Você poderia usar a seguinte função

=IFERROR(IF(MATCH(A1,Sheet1!$A:$A,0),"yes",),"no")

Começando de dentro para fora

Corresponder, procura na coluna A da planilha1 para ver se existe um valor que corresponda à célula A1 da planilha atual (planilha2). Se houver uma correspondência exata, ele retornará o número da linha.

A declaração if. Se a correspondência retornar algo (número 1 ou superior), isso será considerado verdadeiro e retornará "sim"

iferror. Se a correspondência não encontrar nada, ela retornará um erro. Iferror faz com que esse retorno seja o último "não"

— gtwebb
fonte

4

VLOOKUP deve funcionar ...

=IF(ISNA(VLOOKUP(A1,Sheet1!$A:$A,1,false)),"NO","YES")

Se nenhuma correspondência for encontrada, VLOOKUP retornará NA. Então, vemos se o resultado é ISNA? Em seguida, retorne NO caso contrário, SIM

— EkriirkE
fonte

0

Você também pode usar uma COUNTIFinstrução combinada com um IF:

=IF(COUNTIF(WorksheetA!$A:$A,WorksheetB!$A1)>0,"Yes","No")

Isso conta o número de vezes que o conteúdo da célula A1 é encontrado na coluna A da sua primeira planilha. Se o número for maior que 0, o item estará na lista e, portanto, retornamos um "Sim"; caso contrário, se COUNTIFretornar um 0, o item não foi encontrado e retornamos um "Não".

Uso COUNTIFdiariamente para identificar itens de uma lista e de outra (além de duplicatas).

— JG7
fonte